Regular expression, strip quoted string literals

[guinness]

Just wondering if there is another approach to replacing quoted string literals in an AutoIt Script file.

#include <Constants.au3>

Local $sData = FileRead(@ScriptFullPath)

; Strip double/single quote strings. Topic: http://stackoverflow.com/questions/4462646/how-can-i-remove-quoted-string-literals-from-a-string-in-c
$sData = StringRegExpReplace($sData, "([""'])(?:(?!\1).)*\1(\h*)", "''\2") ; Modified by guinness.
MsgBox($MB_SYSTEMMODAL, '', $sData)

[PhoenixXL]

Almost the same

#include <Constants.au3>

Local $sData = FileRead(@ScriptFullPath)

$sData = StringRegExpReplace($sData, "([""']).*?\1", "")
MsgBox($MB_SYSTEMMODAL, '', $sData)

Have a look

Check the function to strip the Comments and Strings

Regards

Edited February 21, 2013 by PhoenixXL

[guinness]

How did I miss that post? Thanks for that.

[czardas]

I wrote this a while ago. It seems to work. I haven't looked closely at your RegExp versions, but perhaps the code is worth posting.

expandcollapse popup

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __StripOutStrings
; Description ...: Removes all strings wrapped in quotes from the code.
; Syntax.........: __StripOutStrings(ByRef $sCodeStr)
; Parameters ....: $sCodeStr - The string to alter.
; Return values .: [ByRef] the string after removing all strings wrapped in quotes
; Author ........: czardas
; Modified.......:
; Remarks .......:
; Related .......: None
; Link ..........:
; Example .......: No
; ===============================================================================================================================

Func __StripOutStrings(ByRef $sCodeStr)
    Local $foo, $bar, $iStart, $iEnd, $aQuot

    While 1
        $foo = StringInStr($sCodeStr, '"') ; Double quote
        $bar = StringInStr($sCodeStr, "'") ; Single quote
        If $foo = 0 And $bar = 0 Then ExitLoop
        If $foo > $bar And $bar > 0 Then
            $iStart = $bar
            $sQuot = "'"
        Else
            $iStart = $foo
            $sQuot = '"'
        EndIf

        $iEnd = StringInStr($sCodeStr, $sQuot, 0, 2)
        If $iEnd = 0 Then ; Error Code???
            $sCodeStr = StringLeft($sCodeStr, $iStart -1)
        Else
            $sCodeStr = StringLeft($sCodeStr, $iStart -1) & " " & StringRight($sCodeStr, StringLen($sCodeStr) - $iEnd)
        EndIf
    WEnd
EndFunc ;==> __StripOutStrings

[guinness]

Thanks czardas. I did come across that snippet in a post you referenced earlier and that's what gave me the idea.

Edited February 21, 2013 by guinness

[czardas]

Thanks czardas. I did come across that snippet in a post you referenced earlier and that's what gave me the idea.

The regexp approach looks better, I'll probably change it. I'll get around to testing these later. Thanks for looking at my referenced post.

Edited February 21, 2013 by czardas

[SaeidN]

How to do this in an array? I mean removing single and double quotes from strings in an array.

And also how to remove all characters after a dash (-) in strings of an array?

Edited September 12, 2022 by SaeidN

[mikell]

1 hour ago, SaeidN said:

How to do this in an array?

Use a For/Next loop

1 hour ago, SaeidN said:

how to remove all characters after a dash (-)

Use this

StringRegExpReplace($string, '-.*', "")

BTW this thread is nearly 10 years old, you could have created a new one ...