Statics instead of Globals.

[MvGulik]

Playing around a bit with this idea.

Note: Needs at least AutoIt version 3.3.9.0 (#1257: Fix bugs in Static array handling)

expandcollapse popup

Func My_Statics($sName, $vData = '')

    ;; parameter checkups
    If 1 Then ;; ...
        If Not IsString($sName) Then Return SetError(2) ;; name -> string only.
        If Not $sName Then Return SetError(3) ;; name -> no empty string.
        ;If StringInStr($sName, ' ') then Return SetError(4) ;; block spaces in names. ... etc
        ;; not checking for additional odd name cases. (presuming general valid variable name cases.)
        ;; note: name string are not case-sensitive in this case.
    EndIf

    Local Enum $_ind_ ;; array index field. (make global when warranted.)

    Local Static $asNames[1] = [0]
    Local Static $avData[1] = [0]
    Local $iSize = $asNames[$_ind_]

    Local $out = ''
    Local $err = 0

    If @NumParams > 1 Then
        ;; data input mode.
        Do ;; used as name-found bailout point.

            For $i = 1 To $iSize
                If $asNames[$i] = $sName Then
                    $avData[$i] = $vData
                    ExitLoop 2
                EndIf
            Next

            ;; Name not found. Add new name entry.
            $iSize += 1
            ReDim $asNames[1 + $iSize]
            ReDim $avData[1 + $iSize]
            ;
            $asNames[$_ind_] = $iSize
            $avData[$_ind_] = $iSize
            ;
            $asNames[$iSize] = $sName
            $avData[$iSize] = $vData
        Until 1

    Else ;; recall
        $err = 1
        For $i = 1 To $asNames[$_ind_]
            If $asNames[$i] = $sName Then
                $out = $avData[$i]
                $err = 0
                ExitLoop
            EndIf
        Next
    EndIf

    Return SetError($err, 0, $out)
EndFunc

(Only tested with strings and a array. But seems ok so far.)

Error 1 (+empty string): Name not found, recall mode only.

Error 2+3: Name parameter hickup.

- Fixed missing constant.

Edited February 20, 2013 by MvGulik

[guinness]

MvGulik,

Nice I could be of some inspiration, but the code is using a variable that is undeclared and could you provide a small example for those who may not quite understand how to use. Thanks.

[MvGulik]

+ Fixed missing constant.

Will see about some example code later.

(Like guinness example better than my own.)

"__CODEBOX_0__" ... bye bye backup. Not working for spaces anyway.

(temp)

#4 - Usage code example for this function. (guinness)

#10 - Smaller function code example. (JohnOne)

#11 + #12 - Optional v3.3.8.1 workaround for resizing a Static array. (wraithdu)

#19 - Dictionary use example(v1). (JohnOne)

#22 - Dictionary use example(v2). (JohnOne)

(move up)

Edited February 21, 2013 by MvGulik

[guinness]

OK, I will do instead.

#include <Constants.au3>

Example()
SomeFunc()

MsgBox($MB_SYSTEMMODAL, '', My_Statics('iValue'))

Func Example()
    My_Statics('vVar', 'This is a variant variable.')
    My_Statics('sString', 'Some string containing whitespace')
    My_Statics('iValue', 42)
EndFunc   ;==>Example

Func SomeFunc()
    MsgBox($MB_SYSTEMMODAL, '', My_Statics('sString'))
EndFunc   ;==>SomeFunc

[JohnOne]

Aren't statics just globals behind a curtain?

[BrewManNH]

Statics are just not forgotten once the function ends, they're not accessible anywhere else in the script like a global would be.

[guinness]

Aren't statics just globals behind a curtain?

Kind of.

https://en.wikipedia.org/wiki/Local_variable#Static_local_variables

[JohnOne]

Statics are just not forgotten once the function ends, they're not accessible anywhere else in the script like a global would be.

Indeed, that's the curtain.

This is a good Idea, and might be the closest thing you can come to a struct emulation (besides a dllstruct)

[guinness]

Ha, I thought I would have received some backlash for this idea.

[JohnOne]

I don't see why, here is a silly little example of what I mean

Enum $sName, $iAge, $ftHeight, $lbWeight

MsgBox(0,"Name",Struct($sName,0))
MsgBox(0,"Age",Struct($iAge,0))
MsgBox(0,"Height",Struct($ftHeight,0))
MsgBox(0,"Weight",Struct($lbWeight,0))

MsgBox(0,"Age",Struct($iAge,64)) ; next year
MsgBox(0,"Height",Struct($ftHeight))
MsgBox(0,"Weight",Struct($lbWeight,156)) ; fat bastard


Func Struct($iIndax = 0, $Value = 0)
    ;0-name
    ;1-age
    ;2-height
    ;3-weight
    Static $int[4] = ["Harry",63,5.11,150]
    If $Value Then $int[$iIndax] = $Value
    Return $int[$iIndax]
EndFunc

Edited February 21, 2013 by JohnOne

[guinness]

I tried a workaround for 'redimming' a Static array for those who want to use v3.3.8.1 still. Turns out you can't create a local copy and the re-assign back to the Static variable, AutoIt somehow keeps a record that this is an array and not a string.

[wraithdu]

My old workaround was to create a function to take the static as ByRef and redim it there.

[guinness]

I didn't think that would be possible. Thanks.

Edited February 21, 2013 by guinness

[Bowmore]

Some nice lateral thinking going on here with using Static Variables. In my opinion though this just avoid the use of Global Variables by obfuscation. Local Static variables in AutoIt should only be used for persistent storage between repeated calls to a single function. If a situation calls fore a variable value in several different parts of an application then use a Global. Globals are not bad, but should only be used when necessary and with a distinctive naming convention so that it is obvious they have Global scope.

[czardas]

Thinking about this is indeed interesting. It is possible to store all static variables in one function with a read/write option. I think it should be very easy. I'm sure you could do much more than this. This is a nice idea from guinness.

Edited February 21, 2013 by czardas

[JohnOne]

Some nice lateral thinking going on here with using Static Variables. In my opinion though this just avoid the use of Global Variables by obfuscation. Local Static variables in AutoIt should only be used for persistent storage between repeated calls to a single function. If a situation calls fore a variable value in several different parts of an application then use a Global. Globals are not bad, but should only be used when necessary and with a distinctive naming convention so that it is obvious they have Global scope.

Quite, but the static variables in for example the code I posted are available anywhere in the script, just by calling function with desired index.

[guinness]

I'm wondering just how easier it would be to manage code like this and what are the speed implications in doing so?

[czardas]

The concept needs testing. I think it will be a bit slower than using globals. I could be wrong though.

[JohnOne]

Here is another Struct emulation example, exploiting the fact that objects seem also to obey Static.

Struct()

MsgBox(0, "Name", Struct("name"))
MsgBox(0, "Age", Struct("age"))
MsgBox(0, "Height", Struct("height"))
MsgBox(0, "Weight", Struct("weight"))

Func Struct($key = "")
    Static $created = 0
    Static $oDictionary = ObjCreate("Scripting.Dictionary")
    If Not $created Then
        $oDictionary.ADD("name", "Harry")
        $oDictionary.ADD("age", 63)
        $oDictionary.ADD("height", 5.11)
        $oDictionary.ADD("weight", 150)
        $created = 1
    EndIf

    If $key Then
        Return $oDictionary.Item($key)
    EndIf
EndFunc   ;==>Struct

[BrewManNH]

I'm going to go with what Bowmore said, this isn't doing anything other than creating a new name for a Global variable with almost none of the benefits of globals, and more work being done just to make the script harder to follow.

I'll stick with Global/Local and use Static for what it's meant for, inside a function so you don't have to use a Global to remember a value from one run of it to the next.