[SOLVED] How to "Zero-fill right shift" ?

[FireFox]

Hi,

I'm wondering how to make a zero-fill right shift in autoit as far as the BitShift function has no parameter for this.

Here is an example in javascript : https://developer.mozilla.org/en-US/docs/Javascript/Reference/Operators/Bitwise_Operators#>>>_(Zero-fill_right_shift)

Thanks for anyhelp,

Br, FireFox.

Edited February 20, 2013 by FireFox

[czardas]

Perhaps something like this:

For $i = 0 To 32
    ConsoleWrite(LogicalBitShift(0x80000000 ,$i) & @LF)
Next

Func LogicalBitShift($dVal, $iShift)
    If $iShift > 0 And BitAND($dVal, 0x80000000) = 0x80000000 Then
        $dVal = BitShift($dVal, 1)
        $dVal = BitXor($dVal, 0x80000000)
        $iShift -= 1
    EndIf
    Return BitShift($dVal, $iShift)
EndFunc

Edited February 19, 2013 by czardas

[FireFox]

ohhhhhhhhh yeah !

Thanks again

[czardas]

No problem. You might want to add some error checks for the input parameters, I also think the function should be renamed to BitLogicalShift().

[guinness]

Nice snippet czardas

[UEZ]

This is a equivalent to the LogicalBitShift() function:

For $i = 0 To 32
   ConsoleWrite(Int(-1 * 0x80000000 / (2^$i)) & @LF)
Next

Br,

UEZ

Edited February 20, 2013 by UEZ

[czardas]

This is a equivalent to the LogicalBitShift() function:

For $i = 0 To 32
Ceiling(-1 * 0x80000000 / (2^$i))
Next

Br,

UEZ

I'm getting totally different results:

Local $dVar = 0xFFFFFFFF

For $i = 0 To 32
    ConsoleWrite(BitLogicalShift($dVar ,$i) & @LF)
    ConsoleWrite(Ceiling(-1 * $dVar / (2^$i)) & @LF)
Next

Func BitLogicalShift($dVal, $iShift)
    If $iShift > 0 And BitAND($dVal, 0x80000000) = 0x80000000 Then
        $dVal = BitShift($dVal, 1)
        $dVal = BitXor($dVal, 0x80000000)
        $iShift -= 1
    EndIf
    Return BitShift($dVal, $iShift)
EndFunc

BTW, I changed the function name to a better one, but there is a problem. I'm trying to figure it out.

Edited February 20, 2013 by czardas

[UEZ]

Well, calculating this way is limited to 0x80000000.

Local $dVar = 0x80000000

For $i = 0 To 32
    ConsoleWrite(BitLogicalShift($dVar, $i) & " / " & Equivalent($dVar, $i) & @LF)
Next

Func Equivalent($dVar, $i)
    If Hex($dVar) > Hex(0x80000000) Then Return SetError(0, 0, -1)
    Local $j = 1
    If Hex($dVar) = Hex(0x80000000) Then $j *= -1
    Return Int($j * $dVar / (2^$i))
EndFunc

Func BitLogicalShift($dVal, $iShift)
    If $iShift > 0 And BitAND($dVal, 0x80000000) = 0x80000000 Then
        $dVal = BitShift($dVal, 1)
        $dVal = BitXor($dVal, 0x80000000)
        $iShift -= 1
    EndIf
    Return BitShift($dVal, $iShift)
EndFunc

Br,

UEZ

Edited February 20, 2013 by UEZ

[czardas]

Well, it has to work on any 32 bit integer. I have just realized that my method is faulty, because it isn't a true logical shift. The results of the first example fooled me into thinking it was working. It's actually completely broken.

Edit

I think I know a way to fix it.

Edited February 20, 2013 by czardas

[czardas]

I was thinking way too deep about this, The solution is very simple indeed. I have added error checks to force strict input parameters, rather unlike the arithmetic bitwise functions which don't seem to balk at anything.

Local $dVar = 0x00010000

For $i = 21 To -20 Step -1
    ConsoleWrite(BitLogicalShift($dVar ,$i) & @LF)
Next

Func BitLogicalShift($dVal, $iShift)
    If Not IsInt($dVal) Or Not IsInt($iShift) Then Return SetError(1, 0, "")

    If $iShift > 31 Or $iShift < -31 Then
        $dVal = 0 ; Out of range shift values always return zero.
    ElseIf $iShift > 0 And BitAND($dVal, 0x80000000) = 0x80000000 Then
        $dVal = BitXor(BitShift($dVal, 1), 0x80000000)
        $iShift -= 1
    EndIf

    Return BitShift($dVal, $iShift)
EndFunc

Now the bit sequence can be shifted out of range in either direction. With the earlier version, the binary was looping back on itself with shift values greater than 31. That was not the intention.

Edited February 21, 2013 by czardas

[FireFox]

Thank you, it's fine for my needs