WMI Query. How to get data from object?

[minimen456]

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$strComputer = "localhost"
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\ROOT\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT DeviceID,FreeSpace FROM Win32_LogicalDisk WHERE DeviceID = 'C:'", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

How can I get data(FreeSpace) from $colItems object? Can I do it without using loop?

[ripdad]

Did you try this... (click on it)

$val = DriveSpaceFree("c:\")

Here is a working code-piece:

Local $objWMI = ObjGet('winmgmts:root\cimv2')
Local $objClass = $objWMI.ExecQuery('SELECT * FROM Win32_LogicalDisk Where DeviceID="C:"')

Local $string = ''

For $objItem In $objClass
    $string &= 'DeviceID = ' & $objItem.DeviceID & @CRLF
    $string &= 'FreeSpace = ' & $objItem.FreeSpace & @CRLF
    ExitLoop
Next

MsgBox(0, '', $string)

There are ways to do it without a loop, but I wouldn't recommend it. Too many things can go wrong.

[water]

Did you have a look at the tool in the Example Scripts section of the forum. It generates AutoIt code for you to query WMI.

[UEZ]

Try this:

$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & '\root\cimv2:Win32_LogicalDisk="C:"')
MsgBox(0, "TEST", "Free Diskspace on C: " & $objWMI.FreeSpace & " bytes / " & Round($objWMI.FreeSpace / 1024^2) & " mb")

Br,

UEZ