StdoutRead freezes

[VAN0]

Hello.

I've tried search the forum and found few topic with the same issues, but none of them have working solution for me.

I have the following code:

Local $line = ""
Local $foo = Run(@ComSpec & " /c powercfg -list", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
   $line &= StdoutRead($foo)
   If @error Then ExitLoop
WEnd

If I put this in a loop, after a while it freezes in the infinite loop because StdoutRead doesn't through @error

I'm not quiet understand how this piece of code actually works and the only workaround solution I can think of is instead of creating infinite loop, use counter to let say 10000 loops, but this will fail on super fast computers I guess:

$i = 10000
Local $line = ""
Local $foo = Run(@ComSpec & " /c powercfg -list", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Do
    $line &= StdoutRead($foo)
    If @error Then ExitLoop
    $p = ProcessExists($foo)
    If Not $p Then $i -= 1
Until Not $i

The second code works for me so far, but is there a "proper" way handle this issue when StdoutRead indefinitely waiting for output?

Thank you.

P.S.

suggested using sleep() would affect on script performance, so I'd rather avoid it too.

Edited February 10, 2013 by VAN0

[JohnOne]

Not quite an expert on this but does the window close after operation?

If so

While ProcessExists($foo)
   $line &= StdoutRead($foo)
   If @error Then ExitLoop
WEnd

or

While ProcessExists($foo)
   Sleep(10)
WEnd
$line = StdoutRead($foo)

[guinness]

Here's how I would do it.

; Example 1
Local $sOutput = ''
While 1
    $sOutput &= StdoutRead($iPID) ; Read the standard output stream.
    If @error Then ; This will exit the loop if the process doesn't exists.
        ExitLoop
    EndIf
WEnd

; Example 2
ProcessWaitClose($iPID) ; Wait for the process to close.
Local $sOutput = StdoutRead($iPID) ; Read the standard output stream.

[garbb]

I had the same problem of stdoutread() hanging up intermittently in my script. I made it run in a loop and usually it would only run a few hundred times before stdoutread() would freeze. This is the best I could come up with: 

Local $foo = Run(@ComSpec & " /c dir foo.bar", "C:\", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD + $RUN_CREATE_NEW_CONSOLE)
Do
until NOT ProcessExists($foo)
Local $line = StdoutRead($foo)
StdioClose($foo)
ConsoleWrite("STDOUT read:"&' "'&$line&'"'&@CR)

It seems to run forever without freezing. For some reason if you use "ProcessWaitClose($foo)" it will make the script much slower that if you use "Do

until NOT ProcessExists($foo)" even though I would think that they are doing the exact same thing.

Also don't forget to use StdioClose($foo) or you will probably have a memory leak. (I definitely did)

I know that this is an old thread but I happened across it when searching for a solution to my problem and so hopefully someone else will in the future.

[VAN0]

9 years later this topic is still relevant.

using ProcessWaitClose() as per help file absolutely murders performance of the script (it's 1:10 ratio difference)

But with ProcessExists() performance slightly drops, but no freezes.

So, my current working work around:

Local $line = ""
Local $foo = Run(@ComSpec & " /c powercfg -list", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
   $line &= StdoutRead($foo)
   If @error Or Not ProcessExists($iPID) Then ExitLoop
WEnd
$line &= StdoutRead($foo)

P.S.

If I remove the last line, for some reason sometimes I get no data read at all ...

[AndrewG]

It's easier to get the output after the command finishes.

https://www.autoitscript.com/forum/topic/203959-autoit-sometimes-freezes-when-polling-stdoutread/?do=findComment&comment=1464904

You stated that you have tried ProcessWaitClose(), but not shown is where you placed ProcessWaitClose() in your example. I could assume where, but that is not wise. So...

The following works for me; returns quickly, does not freeze. Does this work for you?

#Include <AutoItConstants.au3>

Local $line = ""
Local $foo = Run(@ComSpec & " /c powercfg -list", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
   $line &= StdoutRead($foo)
   If @error Then ExitLoop
   ProcessWaitClose($foo)
WEnd
ConsoleWrite($line & @CRLF)

 

Edited September 15 by AndrewG

[Nine]

As per help file of ProcessWaitClose :

Quote

The process is polled approximately every 250 milliseconds.

If 250 ms is too long for you then simply use this :

#include <Constants.au3>

Local $hTimer = TimerInit()
Local $iPID = Run(@ComSpec & " /c powercfg -list", "", @SW_HIDE, $STDERR_MERGED)

While ProcessExists($iPID)
WEnd
Local $line = StdoutRead($iPID)

ConsoleWrite(TimerDiff($hTimer) & @CRLF)
ConsoleWrite($line & @CRLF)

42ms instead of 295ms with ProcessWaitClose

Edited September 15 by Nine

[VAN0]

@Nine

That actually even better. Thank you!

So, how does the sdout buffer work? Does it remains in memory until it's read even after application process is gone? What if it's megabytes or even gigabytes of data?

[Nine]

I don't think it is allowed to write to console more than 64k, although I haven't check recently on new OS.  Anyway this rhetorical question, you can try by yourself.