Multiple value under one variable declare?

[lolipop]

Hi,

Is there anyway to declare a single variable with multiple value under it? Something like the example code;

$ext=386, 3g2, acl, aac
$var=RegRead("HKEY_CLASSES_ROOT\." & $ext, "")

What I want to achieve is to have RegRead read the key HKEY_CLASSES_ROOT.386 one time, follow by HKEY_CLASSES_ROOT.3g2 one time, follow by HKEY_CLASSES_ROOT.aac one time, etc...

The reason is I have near to 100 of such value and I don't want to declare them 100 times. Any help is much appreaciated. Thanks.

Edited February 7, 2013 by lolipop

[water]

I would do it with a two-dimensional array:

#include <Array.au3>
Global $aReg[4][2] = [["386"],["3g2"],["acl"],["aac"]]
For $iIndex = 0 To UBound($aReg, 1) - 1
    $aReg[$iIndex][1] = RegRead("HKEY_CLASSES_ROOT\." & $aReg[$iIndex][0], "")
Next
_ArrayDisplay($aReg)

This creates an array with the key you want to read in the first element and the read value in the second.

[PhoenixXL]

If it is in a sequence RegEnumKey will help

[lolipop]

Hi PhoenixXL, thanks for the reply. No it's not in sequence.

[lolipop]

Water, thanks for the headup. Let me take some time to digest your example. Not really that good in understanding array but at first glance it seems to be what I'm looking for. Thanks so much.

Edited February 7, 2013 by lolipop

[water]

If you need more information on how arrays work there is a very good tutorial in the wiki.

[lolipop]

Sure, thanks for the helpful link.

[guinness]

I would second the array, but for ease would use Enum to structure the code like below.

#include <Constants.au3>

Example()

Func Example()
    ; Create variables in Local scope and enumerate through the variables. Default is to start from 0.
    Local Enum $eCat, $eDog, $eMouse, $eHamster ; $eHamster is equal to the value 3, not 4.

    ; Create an array in Local scope with 4 elements.
    Local $aAnimalNames[4]

    ; Assign each array element with the name of the respective animal. For example the name of the cat is Jasper.
    $aAnimalNames[$eCat] = 'Jasper' ; $eCat is equal to 0, similar to using $aAnimalNames[0]
    $aAnimalNames[$eDog] = 'Beethoven' ; $eDog is equal to 1, similar to using $aAnimalNames[1]
    $aAnimalNames[$eMouse] = 'Pinky' ; $eMouse is equal to 2, similar to using $aAnimalNames[2]
    $aAnimalNames[$eHamster] = 'Fidget' ; $eHamster is equal to 3, similar to using $aAnimalNames[3]

    ; Display the values of the array.
    MsgBox($MB_SYSTEMMODAL, '', '$aAnimalNames[$eCat] = ' & $aAnimalNames[$eCat] & @CRLF & _
            '$aAnimalNames[$eDog] = ' & $aAnimalNames[$eDog] & @CRLF & _
            '$aAnimalNames[$eMouse] = ' & $aAnimalNames[$eMouse] & @CRLF & _
            '$aAnimalNames[$eHamster] = ' & $aAnimalNames[$eHamster] & @CRLF)

    ; Sometimes using this approach for accessing an element is more practical than using a numerical value, due to the fact changing the index value of
    ; the enum constant has no affect on it's position in the array. Therefore changing the location of $eCat in the array is as simple as changing the order
    ; it appears in the initial declaration e.g.

    ; Local Enum $eDog, $eMouse, $eCat, $eHamster

    ; Now $eCat is the 2nd element in the array. If you were using numerical values, you would have to manually change all references of $aAnimalNames[0] to
    ; $aAnimalNames[2], as well as for the other elements which have now shifted.
EndFunc   ;==>Example

[water]

I think that gets too complex for a user who is not very firm with arrays.

[guinness]

Well I did add comments to explain.

[water]

I've seen them

But I wouldn't start with one of the most complex examples to explain to a user who just gets his feet wet on the subject.