Running app when screen is unlocked

[grimmlock]

Good Morning,

I copied a script from here and was able to get it so that when the screen is unlocked it displays a message, however what I would like to have happen is only the display a message once, but keep the script running at all times, and then every time the workstation is unlocked display a message.

Here is what I have so far.

Global Const $DESKTOP_SWITCHDESKTOP = 0x100

While 1

If _CheckLocked() = 0 Then
msgbox(0, "", "Test")
EndIf


WEnd


Func _CheckLocked()
$hLockedDLL = DllOpen("user32.dll")
$hDesktop = DllCall($hLockedDLL, "int", "OpenDesktop", "str", "Default", "int", 0, "int", 0, "int", $DESKTOP_SWITCHDESKTOP)
$ret = DllCall($hLockedDLL, "int", "SwitchDesktop", "int", $hDesktop[0])
DllCall($hLockedDLL, "int", "CloseDesktop", "int", $hDesktop[0])

If $ret[0] = 0 Then
$iLocked = 1
ElseIf $ret[0] = 1 Then
$iLocked = 0
EndIf

DllClose($hLockedDLL)

If $iLocked Then
Return 1
Else
Return 0
EndIf

EndFunc

Thanks,

Grimm

[guinness]

The code could do with updating, but what is the real problem, because isn't that happening now?

[grimmlock]

The problem is that it is loops. when I close the message box (and the PC is unlocked) is simply reopens the msgbox. What I want is have it so that msgbox only pops up once every time the computer is unlocked, not repeatedly.

Thanks

Grimm

[guinness]

Read the comments and only provided part of the code as I'm not keen on re-distributing functions like the one above.

#include <Constants.au3>

Global Const $DESKTOP_SWITCHDESKTOP = 0x100

Local $fDisplayMsg = False, $fLockedState = False

While 1
    ; Get the lock state, boolean value (True or False.)
    $fLockedState = (_CheckLocked() = 1)

    ; If the workstation is locked, then set a variable to True so as to show a message box when we come back out of the locked state.
    If $fLockedState And $fDisplayMsg = False Then $fDisplayMsg = True

    ; If the system isn't locked and the variable to show the message box is True, then we must have come out of a locked state.
    If $fLockedState = False And $fDisplayMsg Then
        $fDisplayMsg = False ; Reset the variable to False so as not to display the message box the next time we go back around the tight loop.
        MsgBox($MB_SYSTEMMODAL, '', 'Workstation unlocked.')
    EndIf
    Sleep(10) ; To reduce CPU ticks.
WEnd

[grimmlock]

Wow thank you so much for the help and the explaination. That was and is very helpful

Thanks,

Grimm

[guinness]

Wow thank you so much for the help and the explaination. That was and is very helpful

Thanks,

Grimm

You're very welcome. Get used to excessive use of comments in the foreseeable future. -_0