_PathSplitEx

DXRW4E · January 22, 2013

#include-once

; #UDF# =======================================================================================================================
; Title .........: PathSplitEx
; AutoIt Version : 3.3.8.1
; Language ......: English
; Description ...: Splits a path into the drive, directory, file name and file extension parts
; Author(s) .....: DXRW4E
; Notes .........:
; ===============================================================================================================================

; #CURRENT# =====================================================================================================================
; _PathSplitEx
; _PathSplitParentDir
; _FileExistsEx
; ===============================================================================================================================


; #FUNCTION# ====================================================================================================================
; Name...........: _PathSplitEx
; Description ...: Splits a path into the drive, directory, file name and file extension parts. An empty string is set if a part is missing.
; Syntax.........: _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
; Parameters ....: $sFilePath  - The path to be split (Can contain a UNC server or drive letter)
;                 $sDrive    - String to hold the drive
;                 $sDir    - String to hold the directory
;                 $sFileName  - String to hold the file name
;                 $sExtension - String to hold the file extension
; Return values .: Success - Returns an array with 5 elements where 0 = original path 1 = drive, 2 = directory, 3 = filename, 4 = extension
; Author ........: DXRW4E
; Modified.......:
; Remarks .......: This function does not take a command line string. It works on paths, not paths with arguments.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
    $sFilePath = StringRegExp($sFilePath, "^((?:\\\\\?\\)*(\\\\[^\?\/\\]+|[A-Za-z]:)?(.*[\/\\])?((?:[^\.\/\\]|(?(?=\.[^\/\\]*\.)\.))*)?([^\/\\]*))$", 1)
    $sDrive = $sFilePath[1]
    $sDir = StringRegExpReplace($sFilePath[2], "[\/\\]+\h*", "\" & StringLeft($sFilePath[2], 1))
    $sFileName = $sFilePath[3]
    $sExtension = $sFilePath[4]
    Return $sFilePath
EndFunc


; #FUNCTION# ====================================================================================================================
; Name...........: _PathSplitParentDir
; Description ...: Splits a path into the drive, directory, file name and file extension parts. An empty string is set if a part is missing.
; Syntax.........: _PathSplit($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sParentDir, ByRef $sFileName, ByRef $sExtension)
; Parameters ....: $sFilePath  - The path to be split (Can contain a UNC server or drive letter)
;                 $sDrive    - String to hold the drive
;                 $sDir    - String to hold the directory
;                 $sParentDir - String to hold the parent directory
;                 $sFileName  - String to hold the file name
;                 $sExtension - String to hold the file extension
; Return values .: Success - Returns an array with 6 elements where 0 = original path 1 = drive, 2 = directory, 3 = parentdir, 4 = filename, 5 = extension
; Author ........: DXRW4E
; Modified.......:
; Remarks .......: This function does not take a command line string. It works on paths, not paths with arguments.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _PathSplitParentDir($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sParentDir, ByRef $sFileName, ByRef $sExtension)
    $sFilePath = StringRegExp($sFilePath & " ", "^((?:\\\\\?\\)*(\\\\[^\?\/\\]+|[A-Za-z]:)?(.*?[\/\\]+)?([^\/\\]*[\/\\])?[\/\\]*((?:[^\.\/\\]|(?(?=\.[^\/\\]*\.)\.))*)?([^\/\\]*))$", 1)
    $sDrive = $sFilePath[1]
    $sFilePath[2] = StringRegExpReplace($sFilePath[2], "[\/\\]+\h*", "\" & StringLeft($sFilePath[2], 1))
    $sDir = $sFilePath[2]
    $sParentDir = $sFilePath[3]
    $sFileName = $sFilePath[4]
    $sExtension = $sFilePath[5]
    Return $sFilePath
EndFunc


; #FUNCTION# ====================================================================================================================
; Name...........: _FileExistsEx
; Description ...: Get New Files Name
; Syntax.........: _FileExistsEx(ByRef $sFilePath[, $iFileExists])
; Parameters ....: $sFilePath   - The Fullpath file
;                 $iFileExists - Optional
; Author ........: DXRW4E
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _FileExistsEx(ByRef $sFilePath, $iFileExists = 0)
    While FileExists($sFilePath)
        $iFileExists += 1
        $sFilePath = StringRegExpReplace($sFilePath & " ", "( - \(\d+\))?(\.[^\.\\]*)?(\h)$", " - (" & $iFileExists & ")$2")
    WEnd
EndFunc

_PathSplitEx.au3

Edited January 25, 2013 by DXRW4E

guinness · January 23, 2013

Very nice DXRW4E. I'm wondering if this should replace the current _PathSplit? I will have to consult my fellow peers.

DXRW4E · January 23, 2013

Hi guinness, Thank You

Update, now return so

#include <_PathSplitEx.au3>

Local $sDrive = '', $sDir = '', $sParentDir = '', $sFileName = '', $sExtension = ''
Local $t, $Path = 'C:\\\\Program Files\\Chat Tools\\\Skype\\\\SkypeGUI.exe'
;$Path = 'C:\Program Files\Chat Tools\Skype\SkypeGUI'
;$Path = '\\?\C:\Program Files\Chat Tools\Skype\SkypeGUI.exe'
$aPathSplit = _PathSplitEx($Path, $sDrive, $sDir, $sParentDir, $sFileName, $sExtension)

;~ [0]|C:\\\\Program Files\\Chat Tools\\\Skype\\\\SkypeGUI.exe
;~ [1]|C:
;~ [2]|\Program Files\\Chat Tools\
;~ [3]|Skype\
;~ [4]|SkypeGUI
;~ [5]|.exe
;~ [6]|

Ciao.

DXRW4E · January 23, 2013

Ok, updated again, now (also repairs) return regular string path, example

#include <_PathSplitEx.au3>

Local $sDrive = '', $sDir = '', $sParentDir = '', $sFileName = '', $sExtension = ''
Local $t, $Path = 'C:\\\///\Program Files///\\Chat Tools\/\/\Skype\//SkypeGUI.exe'
;$Path = 'C:\Program Files\Chat Tools\Skype\SkypeGUI'
;$Path = '\\?\C:\Program Files\Chat Tools\Skype\SkypeGUI.exe'

;; $aPathSplit = _PathSplitEx($Path, $sDrive, $sDir, $sParentDir, $sFileName, $sExtension)
; Edit
$aPathSplit = _PathSplitParentDir($Path, $sDrive, $sDir, $sParentDir, $sFileName, $sExtension)

;~ [0]|C:\\\///\Program Files///\\Chat Tools\/\/\Skype\//SkypeGUI.exe
;~ [1]|C:
;~ [2]|\Program Files\Chat Tools\
;~ [3]|Skype\
;~ [4]|SkypeGUI
;~ [5]|.exe
;~ [6]|

Ciao a tutti.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

Thanks. I'm only interested in _Path_Split not _PathSplitEx as this was created solely for TheSaint and others who may find it useful.

DXRW4E · January 23, 2013

Hi guinness, (sorry for my english) to tell the truth, the (name of) _PathSplitEx been added for you, because it would be more correct to call the _Path_Split in _PathSplitEx (since _PathSplitEx also repairs the path), and _PathSplitEx in _PathSplitParentDir

Ok already done, the first post has been updated

or use the

#include <_PathSplitEx.au3>

Local $sDrive = '', $sDir = '', $sFileName = '', $sExtension = ''
Local $t, $Path = 'C:\\\///\Program Files///\\Chat Tools\/\/\Skype\//SkypeGUI.exe'
;$Path = 'C:\Program Files\Chat Tools\Skype\SkypeGUI'
;$Path = '\\?\C:\Program Files\Chat Tools\Skype\SkypeGUI.exe'
$aPathSplit = _PathSplitEx($Path, $sDrive, $sDir, $sFileName, $sExtension)

;~ [0]|C:\\\///\Program Files///\\Chat Tools\/\/\Skype\//SkypeGUI.exe
;~ [1]|C:
;~ [2]|\\\///\Program Files///\\Chat Tools\/\/\Skype\//
;~ [3]|SkypeGUI
;~ [4]|.exe
;~ [5]|


;;$sDIR = \Program Files\Chat Tools\Skype\


; #FUNCTION# ====================================================================================================================
; Name...........: _PathSplitEx
; Description ...: Splits a path into the drive, directory, file name and file extension parts. An empty string is set if a part is missing.
; Syntax.........: _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
; Parameters ....: $sFilePath  - The path to be split (Can contain a UNC server or drive letter)
;                $sDrive    - String to hold the drive
;                $sDir    - String to hold the directory
;                $sFileName  - String to hold the file name
;                $sExtension - String to hold the file extension
; Return values .: Success - Returns an array with 6 elements where 0 = original path 1 = drive, 2 = directory, 3 = parentdir, 4 = filename;;, 5 = original path size
; Author ........: DXRW4E
; Modified.......:
; Remarks .......: This function does not take a command line string. It works on paths, not paths with arguments.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
    ;;;;$sFilePath = StringRegExp($sFilePath & " ", "^(?:\\\\\?\\)*(((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?[\/\\]*([\/\\].*?[\/\\])[\/\\]*?([^\.\/\\]*)?(\.[^\.\/\\]*)?)(\h)$", 1)
    $sFilePath = StringRegExp($sFilePath & " ", "^(?:\\\\\?\\)*(((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?([\/\\].*[\/\\])?([^\.\/\\]*)?(\.[^\.\/\\]*)?)(\h)$", 1)
    $sDrive = $sFilePath[1]
    $sDir = StringRegExpReplace($sFilePath[2], "[\/\\]+", "\" & StringLeft($sFilePath[2], 1))
    $sFileName = $sFilePath[3]
    $sExtension = $sFilePath[4]
    ;;$sFilePath[5] = StringLen($sFilePath[0])
    Return $sFilePath
EndFunc

so in array, remains the original string, and return $sDIR regular string

Ciao.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

DXRW4E,

You have to stop that, you're English is good 0_- and so far I've understood everything you've said.

I meant that if you make an update to _PathSplitEx that this change reflects in _Path_Split, as this is the function I'm keen on using. The names can remain the same or you can leave it with the current _PathSplitEx and _PathSplitParentDir.

guinness · January 23, 2013

Try C:ExampleFile.txt

#include <Array.au3>
#include <File.au3>

Local Const $sFilePath = 'C:\ExampleFile.txt'
Local $sDrive = '', $sDir = '', $sFileName = '', $sExtension = ''
Local $aArray = _PathSplit($sFilePath, $sDrive, $sDir, $sFileName, $sExtension)
Print1DArray($aArray)

Local $aArray = _PathSplitEx($sFilePath, $sDrive, $sDir, $sFileName, $sExtension)
Print1DArray($aArray)

Func Print1DArray(ByRef Const $aArray, $iStart = Default, $iEnd = Default, $sDelim = Default)
    If $iEnd = Default Then $iEnd = UBound($aArray) - 1
    If $iStart = Default Then $iStart = 0
    If $sDelim = Default Then $sDelim = @CRLF
    Local $iIndex = 0
    For $i = $iStart To $iEnd
        ConsoleWrite('[' & $iIndex & '] ' & $aArray[$i] & @CRLF)
        $iIndex += 1
    Next
    ConsoleWrite(@CRLF)
EndFunc   ;==>Print1DArray

Also the SRE is returning 6 rows for the array, remove (h) at the end.

DXRW4E · January 23, 2013

without the "(h)" in the end of the pattern, will be almost imposibile to do all this, however (first post already updated) enabled the full path size in 6 rows

Ciao.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

without the "(h)" in the end of the pattern, will be almost imposibile to do all this, however (first post already updated) enabled the full path size in 6 rows

Ciao.

Shame as this will be a 'script breaking change' if it replaced the current _PathSplit. But why not use this >> (?:h)

Edit: What is wrong with this >>

StringRegExp($sFilePath , "^((?:\\\\\?\\)*((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?(.*[\/\\])?([^\.\/\\]*)?(\.[^\.\/\\]*)?)$", 1)

Edited January 23, 2013 by guinness

DXRW4E · January 23, 2013

Shame as this will be a 'script breaking change' if it replaced the current _PathSplit. But why not use this >> (?:h)

just use ReDim in the end, and all will be OK

; #FUNCTION# ====================================================================================================================
; Name...........: _PathSplitEx
; Description ...: Splits a path into the drive, directory, file name and file extension parts. An empty string is set if a part is missing.
; Syntax.........: _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
; Parameters ....: $sFilePath - The path to be split (Can contain a UNC server or drive letter)
;                $sDrive     - String to hold the drive
;                $sDir   - String to hold the directory
;                $sFileName - String to hold the file name
;                $sExtension - String to hold the file extension
; Return values .: Success - Returns an array with 6 elements where 0 = original path 1 = drive, 2 = directory, 3 = parentdir, 4 = filename;;, 5 = original path size
; Author ........: DXRW4E
; Modified.......:
; Remarks .......: This function does not take a command line string. It works on paths, not paths with arguments.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _PathSplitEx($sFilePath, ByRef $sDrive, ByRef $sDir, ByRef $sFileName, ByRef $sExtension)
;;;;$sFilePath = StringRegExp($sFilePath & " ", "^(?:\\\\\?\\)*(((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?[\/\\]*([\/\\].*?[\/\\])[\/\\]*?([^\.\/\\]*)?(\.[^\.\/\\]*)?)(\h)$", 1)
$sFilePath = StringRegExp($sFilePath & " ", "^((?:\\\\\?\\)*((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?(.*[\/\\])?([^\.\/\\]*)?(\.[^\.\/\\]*)?)(\h)$", 1)
$sDrive = $sFilePath[1]
$sDir = StringRegExpReplace($sFilePath[2], "[\/\\]+", "\" & StringLeft($sFilePath[2], 1))
$sFileName = $sFilePath[3]
$sExtension = $sFilePath[4]
ReDim $sFilePath[5]
Return $sFilePath
EndFunc

Edit: What is wrong with this >>

StringRegExp($sFilePath , "^((?:\\\\\?\\)*((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?(.*[\/\\])?([^\.\/\\]*)?(\.[^\.\/\\]*)?)$", 1)

there was a Bug in the previous release in "([/].*[/])?" (if the path had only a "" like 'C:ExampleFile.txt' = error)

; this is Ok
StringRegExp($sFilePath , "^((?:\\\\\?\\)*((?(?=\\\\)\\\\[^\/\\]+|[A-Za-z]:))?(.*[\/\\])?([^\.\/\\]*)?(\.[^\.\/\\]*)?)(\h)$", 1)

edit, sorry

the point is that "(group)?" is ignored non captured (rules of regex) if not after another valid group (x) or (h) ect ect, so is the (h) which forces the capture of all the previous "(group)?", we need in this case only to read properly file with non extension

Ciao.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

I would rather stay away from using ReDim if possible. I can't understand why you do it the way you do in _PathSplitEx, I understand in the other function.

DXRW4E · January 23, 2013

concrete example

#include <Array.au3>
Local $sFilePath = 'C:\Program Files\Chat Tools\Skype\SkypeGUI'
$sFilePath = StringRegExp($sFilePath, "([^\.\/\\]*)?(\.[^\.\/\\]*)?$", 1)
;or
$sFilePath = StringRegExp($sFilePath & " ", "([^\.\/\\]*)?(\.[^\.\/\\]*)?(?:\h)$", 1)
_ArrayDisplay($sFilePath)

;;[0]|SkypeGUI

#include <Array.au3>
Local $sFilePath = 'C:\Program Files\Chat Tools\Skype\SkypeGUI'
$sFilePath = StringRegExp($sFilePath & " ", "([^\.\/\\]*)?(\.[^\.\/\\]*)?(\h)$", 1)
_ArrayDisplay($sFilePath)

;[0]|SkypeGUI
;[1]|
;[2]|

this I mean here

Ciao.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

OK, I get your point. I will leave the current _PathSplit as it is.

DXRW4E · January 23, 2013

Ok, you're right, my bad, I was obsessed with the StringRegExpReplace in the _FileExistsEx(), instead StringRegExp is everything more simple ect ect, that's already done, now everything seems OK, first post already updated again (hope is the last time )

Ciao.

Edited January 23, 2013 by DXRW4E

DXRW4E · January 23, 2013

OK, I get your point. I will leave the current _PathSplit as it is.

Is everything Ok, (is not that the point) good to have many function, so each one use the way like, return is always the same in all fuction, so this does not change anything

Thanks Again for all reports

Ciao.

guinness · January 23, 2013

I just tried the latest update and it's still creating that 5th element, thus ReDim would have to be used. I understand why, but I will have to discuss with my fellow peers if it's worth changing.

Edit: I understand why you have to though, for paths without an extension.

By the way did you see this >> _PathSplitRegEx >>

Edited January 23, 2013 by guinness

guinness · January 23, 2013

Whoops, seems I copied the wrong SRE. The one in the first post works similar to _PathSplit. Nice and thanks for your continued support towards AutoIt.

DXRW4E · January 23, 2013

Thanks to All You, I'm here to learn, everything I know about scripts ect ect, I learned in this forum community, So thank you (AutoIt community) very much for all

Ciao.

Edited January 23, 2013 by DXRW4E

guinness · January 23, 2013

?????

My fault, seems I had copied the wrong SRE from the wrong post.

_PathSplitEx

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Similar Content