Using AutoItv3 Wrapper Directives as Variables

[Flaky]

I am trying to make my application a little bit more user-friendly, since it will be distributed at my place of work. So I have begun using file versions when I compile my script. Is it possible to use a compiler directive as a variable elsewhere in the program?

#AutoIt3Wrapper_Res_Fileversion=1.0.1

I want that fileversion to be used in a small GUI that is accessible in a help menu. But I don't want to remember to update the "v1.0.1" every single time I compile my program.

[Mat]

FileGetVersion

#AutoIt3Wrapper_Res_Fileversion=1.0.1

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, Default, FileGetVersion(@ScriptFullPath))

Try compiling and then running. This won't work when not compiled, so you might have to do some hack involving reading the script or something.

Edited January 22, 2013 by Mat

[Mat]

And here's a snippet for getting it from the source code if the script is not compiled.

#AutoIt3Wrapper_Res_Fileversion=1.0.1

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, Default, "Version: " & _GetScriptVersion())

Func _GetScriptVersion()
    If @Compiled Then
        Return FileGetVersion(@ScriptFullPath)
    Else
        Local $sText = FileRead(@ScriptFullPath)
        If @error Then Return SetError(1, 0, "0.0.0.0") ; File couldn't be read

        Local $asRet = StringRegExp($sText, "(?i)(?:\A|\n)\#AutoIt3Wrapper\_Res\_Fileversion\=(.*?)(?:\z|\n)", 3)
        If @error Then Return SetError(2, 0, "0.0.0.0") ; No version number found

        Return $asRet[0]
    EndIf
EndFunc   ;==>_GetScriptVersion

[guinness]

Nice little snippet.

[MilesAhead]

The include file MilesAheadMisc.au3 in this has a _ScriptVersion() function to return the file version from compiled programs, and both au3 and ahk source. Requires that the comple settings are saved in the source file. Just enable auto-increment to avoid manually updating. Also the included utility, SaveVersion is handy to put in the SendTo folder. If you right click exe and scripts that have file version info, it copies them to files with the file version appended to the name like MyScript.exe and MyScript.au3 copy to MyScript_1_0_0_0.exe and MyScript_1_0_0_0.au3 etc..

[Flaky]

FileGetVersion

#AutoIt3Wrapper_Res_Fileversion=1.0.1

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, Default, FileGetVersion(@ScriptFullPath))

Try compiling and then running. This won't work when compiled, so you might have to do some hack involving reading the script or something.

Thanks Mat. That is exactly what I needed.

[Bester]

And here's a snippet for getting it from the source code if the script is not compiled.

 

#AutoIt3Wrapper_Res_Fileversion=1.0.1

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, Default, "Version: " & _GetScriptVersion())

Func _GetScriptVersion()
    If @Compiled Then
        Return FileGetVersion(@ScriptFullPath)
    Else
        Local $sText = FileRead(@ScriptFullPath)
        If @error Then Return SetError(1, 0, "0.0.0.0") ; File couldn't be read

        Local $asRet = StringRegExp($sText, "(?i)(?:\A|\n)\#AutoIt3Wrapper\_Res\_Fileversion\=(.*?)(?:\z|\n)", 3)
        If @error Then Return SetError(2, 0, "0.0.0.0") ; No version number found

        Return $asRet[0]
    EndIf
EndFunc   ;==>_GetScriptVersion

And this is exactly what i needed, thank you very much for this.

Edited January 23, 2014 by Bester