Disable or remove close, minimize, maximize buttons on any window in runtime !

[W2lkm2n]

However, there is a it took me several hours to figure out how to do it on other windows in runtime, so I tought it might help others.

So you want to remove buttons like this:

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>

$h = WinGetHandle("Untitled - Note")

$iOldStyle = _WinAPI_GetWindowLong($h, $GWL_STYLE)
ConsoleWrite("+ old style: " &amp;amp; $iOldStyle &amp;amp; @CR)
$iNewStyle = BitXOr($iOldStyle, $WS_MINIMIZEBOX, $WS_MAXIMIZEBOX)
_WinAPI_SetWindowLong($h, $GWL_STYLE, $iNewStyle)
_WinAPI_ShowWindow($h, @SW_SHOW)

or remove even the close button:

instead of

$iNewStyle = BitXOr($iOldStyle, $WS_MINIMIZEBOX, $WS_MAXIMIZEBOX)

use

$iNewStyle = BitXOr($iOldStyle, $WS_SYSMENU)

The cool part about these is that you can still close the window with ALT+F4 or minimize it clicking the tray icon.

The trickiest part caused me the biggest headache that if you just set the window style with a SetWindowLong() API call, but don't run

_WinAPI_ShowWindow($h, @SW_SHOW)

the following can happen. To show up properly after the style change, I tried redrawing the window, redrawing everything, sending WM_PAINT message to the Window, calling SetWindowLong() with different handles and options, nothing worked, until I found this comment. So it is very important to run it after setting the style. You can find more about Window styles on MSDN or Autoit help

Now, what if you want only disable the buttons, but don't want to remove them ?

Like this:

(The close button is "greyed" out, the other two are still visible. but if you click them, nothing happens.)

The following forum topic solution is very good:

You can disable any of you want with these functions:

; Constants from http://msdn.microsoft.com/en-us/library/windows/desktop/ms646360(v=vs.85).aspx
Const $SC_CLOSE = 0xF060
Const $SC_MOVE = 0xF010
Const $SC_MAXIMIZE = 0xF030
Const $SC_MINIMIZE = 0xF020
Const $SC_SIZE = 0xF000
Const $SC_RESTORE = 0xF120


Func GetMenuHandle($hWindow, $bRevert = False)
If $bRevert = False Then
$iRevert = 0
Else
$iRevert = 1
EndIf

$aSysMenu = DllCall("User32.dll", "hwnd", "GetSystemMenu", "hwnd", $hWindow, "int", $iRevert)
ConsoleWrite("+ Menu Handle: " & $aSysMenu[0] & @CRLF)
Return $aSysMenu[0]
EndFunc

Func DisableButton($hWindow, $iButton)
$hSysMenu = GetMenuHandle($hWindow)
DllCall("User32.dll", "int", "RemoveMenu", "hwnd", $hSysMenu, "int", $iButton , "int", 0)
DllCall("User32.dll", "int", "DrawMenuBar", "hwnd", $hWindow)
EndFunc

Func EnableButton($hWindow, $iButton)
$hSysMenu = GetMenuHandle($hWindow, True)
DllCall("User32.dll", "int", "RemoveMenu", "hwnd", $hSysMenu, "int", $iButton , "int", 0)
DllCall("User32.dll", "int", "DrawMenuBar", "hwnd", $hWindow)
EndFunc

by calling the functions like this:

DisableButton($handle, $SC_CLOSE)
DisableButton($handle, $SC_MAXIMIZE)
DisableButton($handle, $SC_RESTORE)
DisableButton($handle, $SC_MINIMIZE)

Same with EnableButton().

If you disable $SC_SIZE, the window will not be resizeable with the mouse.

If you disable SC_MOVE, you also cannot move it.

Note: everything was tested on Windows 7 with Aero theme. On other system you might not have the same problem (window becoming a ghost after style update). If you test it on other system, please make a feedback about it !

Hope this helps somebody !

Edited January 12, 2013 by W2lkm2n

[KaFu]

Instead of a ShowWindow() call I would recommend a SetWindowPos() with SWP_FRAMECHANGED.

SetWindowLong - See Remarks

http://msdn.microsoft.com/en-us/library/windows/desktop/ms633591%28v=vs.85%29.aspx

SetWindowPos - See Remarks

http://msdn.microsoft.com/en-us/library/windows/desktop/ms633591%28v=vs.85%29.aspx

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>

Run("notepad.exe")
$timer = TimerInit()
While Sleep(10)
    ; $hWnd = WinGetHandle("Unbenannt - Editor")
    $hWnd = WinGetHandle("Untitled - Note")
    If IsHWnd($hWnd) Then ExitLoop
    If TimerDiff($timer) > 10000 Then Exit 1
WEnd

Sleep(2000)

$iOldStyle = _WinAPI_GetWindowLong($hWnd, $GWL_STYLE)
ConsoleWrite("+ old style: " & $iOldStyle & @CR)
$iNewStyle = BitXOR($iOldStyle, $WS_MINIMIZEBOX, $WS_MAXIMIZEBOX)
_WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iNewStyle)
; _WinAPI_ShowWindow($h, @SW_SHOW)
_WinAPI_SetWindowPos($hWnd, 0, 0, 0, 0, 0, BitOR($SWP_FRAMECHANGED, $SWP_NOMOVE, $SWP_NOSIZE))

[W2lkm2n]

Ok, I didn't realized, there is a nice UDF for manipulating menus, so it's even easier:

; Original script: http://www.autoitscript.com/forum/topic/100125-disable-close-button/#entry716490
; USer32.dll functions: http://msdn.microsoft.com/en-us/library/ms647985(v=vs.85).aspx
#include <GuiMenu.au3>

Run("Notepad")
WinWait("Untitled - Notepad")

$handle = WinGetHandle("Untitled - Notepad")
ConsoleWrite('+ Window Handle: ' & $handle & @CRLF)

DisableButton($handle, $SC_CLOSE)
;~ EnableButton($handle, $SC_CLOSE)

DisableButton($handle, $SC_MAXIMIZE)
DisableButton($handle, $SC_RESTORE)
DisableButton($handle, $SC_MOVE)

Func DisableButton($hWnd, $iButton)
$hSysMenu = _GUICtrlMenu_GetSystemMenu($hWnd, 0)
_GUICtrlMenu_RemoveMenu($hSysMenu, $iButton, False)
_GUICtrlMenu_DrawMenuBar($hWnd)

EndFunc

Func EnableButton($hWnd, $iButton)
$hSysMenu = _GUICtrlMenu_GetSystemMenu($hWnd, 1)
_GUICtrlMenu_RemoveMenu($hSysMenu, $iButton, False)
_GUICtrlMenu_DrawMenuBar($hWnd)
EndFunc

[guinness]

Interesting code from the both of you. Thanks.

[johnmcloud]

I have tested the both code.

First: Please guys don't use:

$handle = WinGetHandle("Untitled - Notepad")

But

$handle = WinGetHandle("[CLASS:Notepad]")

Not everyone have a english windows.

The first script ( remove the button ) work fine on XP, the second ( the disable script ) disable only the close button, i have tested both version, the dll and the GuiMenu

Edited January 14, 2013 by johnmcloud

[W2lkm2n]

Thanks for the feedback !

[guinness]

johnmcloud,

I would even suggest using WinWait.

[johnmcloud]

Yeah guinness you have right.

Just for know, how to apply this to every active window? You can't put in a loop because work in runetime, or the script apply the same command more than once.

So should'll understand when the active window changes and activate it only once ( so if you active the same window 2 times he apply the style only the first time ), this for every active window

What do you think, is possible?

[Rich071]

W2lkm2n,

I tested the first code in post #1 and the code in post #2 on Windows 7 x64 and Windows x32. The minimize and maximize buttons disappeared, which is good.

Tested code in post #3 on Windows 7 x64 and Windows x32. The Close button was grayed out. however the Minimize and Maximize buttons still show and are active as normal.

These results match the results from johnmcloud in post #5.

I am looking for a way to disable and gray out the maximize button.

You had stated it worked on Windows 7. Did you test both, x32 and x64.

I appreciate you sharing the code.

Thanks,

[Rich071]

W2lkm2n,

Interesting  I removed $WS_MINIMIZEBOX from the code in post #2 and the maximize button is displayed,  grayed out and doesn't work. With both the $WS_MINIMIZEBOX and the $WS_MAXIMIZEBOX in the code, both  buttons actually disappear.

With the code in post #3, I had failed to mention, that the $SC_MOVE had actually worked as well. Further testing, selecting only the maximize or the minimize/restore, one at a time, neither one worked. The buttons always show and are enabled regardless.

Thanks,

[guinness]

What's your question? Because you decided to revive a thread that is 5 months old.

[Rich071]

I have been looking for a way to disable the maximize button only. I realize the thread was a few months old but the code works.

Is there any way to covert the Autoit exe to a dll and be used outside Autoit?

Thanks,

[guinness]

But isn't that what you're looking for?

GUICreate('')

[Rich071]

No, I don't need a GUI interface. I have modified the code to remove the timers, accept the input through the command line and and have the program exit with no command line input. It works quite nicely. I was hoping to convert it to a DLL instead of a EXE.

Thanks anyway.

[guinness]

You can't convert an exe to a dll in AutoIt.

[l4tran]

Any ideas to get this to work on Windows 10 app?