Error multi-line 'if' missing 'then'

[EddCase]

Hi guys i'm almost done but having a few issues, I'm writing myself a little app to run with Handbrake so that instead of always automatically running the sample it pops up a message box everything works, but I'm having an issue when I try and add some error checking, this is my code so far

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\Downloads\vlc.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=c:\program files (x86)\autoit3\forms\frmmain.kxf
$frmMain = GUICreate("VLC Launcher", 301, 111, -1, -1)
GUISetIcon("launcher.exe", -1)
$lblEddCase = GUICtrlCreateLabel("By EddCase", 220, 90, 80, 20)
GUICtrlSetState(-1, $GUI_DISABLE)
$btnLaunch = GUICtrlCreateButton("Launch VLC Player", 10, 10, 280, 80)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $btnLaunch
$reg = RegRead ( "HKEY_LOCAL_MACHINE\SOFTWARE\VideoLAN\VLC\", "" )
If @error = 1 Then $reg = RegRead ( "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\VideoLAN\VLC\", "" )
     If @error = 1 Then MsgBox (0, "VideoLan", "VLC is not installed, please install and rerun") & ShellExecute ("http://www.videolan.org/index.html")
WinActivate ("HandBrake")
WinWaitActive("HandBrake")
ControlFocus ("HandBrake", "", "[NAME:text_destination]")
Send("^a")
Send("^c")
$destination = ClipGet()
$short = StringTrimRight ($destination,4)
$file = $short & "_sample.mkv"
run ( '"' & $reg & '"' &" "&"-vvv"&" "& '"' & $file & '"')
Exit

EndSwitch
WEnd

the issue I'm having is with this section

$reg = RegRead ( "HKEY_LOCAL_MACHINE\SOFTWARE\VideoLAN\VLC\", "" )
If @error = 1 Then $reg = RegRead ( "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\VideoLAN\VLC\", "" )
     If @error = 1 Then MsgBox (0, "VideoLan", "VLC is not installed, please install and rerun") & ShellExecute ("http://www.videolan.org/index.html")

It gives me the Error multi-line 'if' missing 'then', I'm trying to read the 32bit registry key, if its not there then trying the 64bit registry key if that key doesn't exist either then bring up the message box and open the vlc web page.

Thanks in advance for your help

Edd

[Melba23]

EddCase,

What are you expecting to happen with this line:

If @error = 1 Then MsgBox (0, "VideoLan", "VLC is not installed, please install and rerun") & ShellExecute ("http://www.videolan.org/index.html")

Because it make no sense at all at present. Do you want a MsgBox and then a browser opening? If that is the case then:

If @error = 1 Then
    $reg = RegRead ( "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\VideoLAN\VLC\", "" )
    If @error = 1 Then 
        MsgBox (0, "VideoLan", "VLC is not installed, please install and rerun")
        ShellExecute ("http://www.videolan.org/index.html")
    EndIf
EndIf

might be a better bet.

M23

[jchd]

The reason behind this is that & in AutoIt is the string concatenation operator.

Because AutoIt is dynamically typed, the action part of your If statement is a string. So it's equivaalent to the following:

If <condition> Then <string>

This is a syntax error since <string> by itself is not a valid statement.

Things are different when the action part (after the Then keyword) is indeed a valid statement. Run this by itself to see what happens:

Local $str
If @error <> 1 Then $str = MsgBox (0, "VideoLan", "VLC is not installed, please install and rerun") & ' -- ' & ShellExecute ("http://www.videolan.org/index.html")
MsgBox(0, '', $str)

Note that I've inserted ' -- ' only for readability. The internal result of both statements (MsgBox and ShellExecute) are converting to strings because the & operator which forces conversion to strings then the whole string is assigned to a variable, a valid standalone AutoIt statement.

Of course I don't advocate using such useless assignment to string (or any type whatsoever) just to use a single-line If in place of a much clearer multi-line If, but I hope this note helps you understand why you got the error in the first place.