who is the parent of an msgbox?

[Gianni]

Hello to You that are reading this,

With the WinExists() function I check if a windows (an msgbox in my case) with a specified text title appear on the screen, and when it does, I simply close it.

Select
Case WinExists(" Reset ok", "The reset command was executed on remote client")
WinClose(" Reset ok")
Case WinExists("client not online", "The client was unreachable")
WinClose("client not online")
EndSelect

well, is it there a way to know the handle of the executable who opened that window? (an msgbox on my case).

Thanks on advance.

[Nunos]

http://www.autoitscript.com/autoit3/docs/intro/au3spy.htm

Does the Windows Info Tool report anything about the msgbox?

[Gianni]

hi Wayfarer

no, the Windows Info Tool report nothing about the parent.

Edited December 26, 2012 by Pincopanco

[bogQ]

you can try to modify example from _ProcessGetName to see if you can solve it with it

[Gianni]

hi bogQ

The msgbox appears on screen, but without any associated process ID in taskmanager, so, apparently, no references to the windows (pid) are available to _ProcessGetName.

I would need an "_MsgBoxGetParent()" ......

[MilesAhead]

This one by Gary Frost works for me:

Even Tray Apps if I want to go to the folder where the exe is, I do About Box then hit the hotkey. My HomeFolder program just calls the function in the link above and gets the folder from the exe path.

edit: unless the Hwnd param is used in the MsgBox call, it does not have a parent. But you can still get the exe that launched it using the GF function... provided the Windows in question has the tools he uses.

Edited December 26, 2012 by MilesAhead

[BrewManNH]

I ran a simple script that just displays a message box in it. I ran a second script that just has WinGetProcess in it, I used the title of the message box in that function. It gave me the PID of the exe that is running, the MsgBox doesn't have its own PID, so if you can retrieve the process id of the message box, you have the parent process that created that message box.

Compile this script and run it, but don't click the message box button

GUICreate("test")
GUISetState()
While 1
    If MsgBox(64, "Test MsgBox", "Hello there") Then Exit
WEnd

Run this script, and it will retrieve the PID, you should see the PID of the program that spawned the MsgBox.

ConsoleWrite(WinGetProcess("Test MsgBox") & @crlf)

[Gianni]

Yes!

Thanks MilesAhead & Thanks BrewManNH

with

$pid = WinGetProcess("Title") (window or MsgBox is the same)

I can get the PID of the program that spawned the MsgBox.

thanks a lot again for the useful and quick help!

bye

[DicatoroftheUSA]

You might also check out sysinternals process explorer.

[MilesAhead]

The Gary Frost function is slower. But it has the advantage that a 32 bit app using it under SysWow64 can get the path of the process associated with a window even if the process is 64 bit.

If both processes have the same "bitness" then this function will work You need the WinAPIEx UDF to include.

; _WindowExeInfo(ByRef $exePath, ByRef $cmdTail, ByRef $workDir, $WindowTitle = "[ACTIVE]")
; on success sets $exePath to executable path of program associated with
; window $WindowTitle and $cmdTail with it's command line args, if any.
;
; Returns 1 on success, 0 otherwise and sets @error.
;
Func _WindowExeInfo(ByRef $exePath, ByRef $cmdTail, ByRef $workDir, $WindowTitle = "[ACTIVE]")
$exePath = ""
$cmdTail = ""
$workDir = ""
Local $pid = WinGetProcess($WindowTitle)
If $pid = -1 Then Return SetError(1, 0, 0)
Local $pHandle = _WinAPI_OpenProcess(0x410, False, $pid)
If @error Then Return SetError(1, 1, 0)
$exePath = _WinAPI_GetModuleFileNameEx($pHandle)
If $exePath = "" Then
_WinAPI_CloseHandle($pHandle)
Return SetError(1, 2, 0)
EndIf
$workDir = _WinAPI_GetProcessWorkingDirectory($pid)
If $workDir = "" Then
_WinAPI_CloseHandle($pHandle)
Return 1
EndIf
$cmdTail = _WinAPI_GetProcessCommandLine($pid)
_WinAPI_CloseHandle($pHandle)
Return 1
EndFunc ;==>_WindowExeInfo

GetModuleFileNameEx() doesn't work across the 32/64 bit divide.

Edited December 26, 2012 by MilesAhead