GUI design concepts.

guinness · December 24, 2012

This is a place to post GUI examples that other users may find interesting. Try to code clearly and concisely please for example DON'T USE MAGIC NUMBERS!

Splash Screen:

#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Global Const $SC_DRAGMOVE = 0xF012

Example() ; Idea by prizm1

Func Example()
    Local $iHeight = 250, $iWidth = 400

    Local $hGUI = GUICreate('', $iWidth, $iHeight, Default, Default, BitOR($WS_POPUP, $WS_BORDER), $WS_EX_TOPMOST)
    GUICtrlCreateGroup('', 0, -5, $iWidth, $iHeight + 5, $WS_THICKFRAME)
    GUICtrlCreateGroup('', -99, -99, 1, 1)
    Local $iClose = GUICtrlCreateButton('Close', $iWidth - 100, $iHeight - 40, 85, 25)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

            Case $GUI_EVENT_PRIMARYDOWN
                _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)

        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

Edited December 25, 2012 by guinness

UEZ · December 25, 2012

Found this in my collection:

;another fast hack by UEZ 2011
#include <GDIPlus.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)
_GDIPlus_Startup()

Global Const $SC_DRAGMOVE = 0xF012
Global Const $W = -1
Global Const $H = 200
Global Const $hGUI = GUICreate("GDI+ Test by UEZ 2011", $W, $H, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
Global Const $hGUI_Child = GUICreate("", $W, $H, 0, 0, $WS_POPUP, $WS_EX_MDICHILD + $WS_EX_LAYERED + $WS_EX_TOOLWINDOW, $hGUI)
GUISetBkColor(0xABCDEF, $hGUI_Child)
GUISwitch($hGUI_Child)
Global Const $idButton = GUICtrlCreateButton("Exit", 40, 20, 100, 40)
GUICtrlSetOnEvent(-1, "_Exit")
Global Const $idLabel = GUICtrlCreateLabel("TEST LABEL HERE!!!", 110, 140, 180, 20)
GUICtrlSetFont(-1, 14, 400, 0, "Times New Roman", 3)
GUICtrlSetColor(-1, 0xF0F0FF)
GUICtrlSetBkColor(-1, -2)
_WinAPI_SetLayeredWindowAttributes($hGUI_Child, 0xABCDEF, 0xFF)
GUISetState(@SW_SHOW, $hGUI_Child)
GUISetState(@SW_SHOW, $hGUI)
_SetGuiRoundCorners($hGUI, 40, False, True, True, False)

Global Const $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBitmap = _CreateCustomBk($hGUI, 0x550555)
Global Const $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_CreateCustomGroupPic($hContext, 100, 100, 200, 75, 0xff0000)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, $W, $H)

SetTransparentBitmap($hGUI, $hBitmap, 0xD0)

GUISetOnEvent(-3, "_Exit")

GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN")

While Sleep(2 ^ 16)
WEnd

Func _Exit()
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hContext)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI_Child)
    GUIDelete($hGUI)
    Exit
EndFunc ;==>_Exit

Func _CreateCustomBk($hGUI, $hexColor, $alpha = "0xAA")
    Local $iWidth = _WinAPI_GetClientWidth($hGUI)
    Local $iHeight = _WinAPI_GetClientHeight($hGUI)
    Local $oBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($oBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, 2)
    Local $hBrush = _GDIPlus_BrushCreateSolid($alpha & Hex($hexColor, 6))
    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, $iWidth, $iHeight, $hBrush)
    _GDIPlus_GraphicsFillRect($hGraphics, 2, 2, $iWidth - 6, $iHeight - 6, $hBrush)
    _GDIPlus_BrushSetSolidColor($hBrush, 0x22FFFFFF)
    Local $iTimes = Round($iWidth / 50)
    Local $aPoints[5][2]
    $aPoints[0][0] = 4
    $aPoints[1][1] = $iHeight
    $aPoints[2][1] = $iHeight
    $aPoints[4][1] = 0
    $aPoints[3][1] = 0
    For $i = 0 To $iTimes
        Local $Random1 = Random(0, $iWidth, 1)
        Local $Random2 = Random(30, 50, 1)
        $aPoints[1][0] = $Random1
        $aPoints[2][0] = $Random1 + $Random2
        $aPoints[4][0] = $aPoints[1][0] + 50
        $aPoints[3][0] = $aPoints[2][0] + 50
        _GDIPlus_GraphicsFillPolygon($hGraphics, $aPoints, $hBrush)
        $aPoints[1][0] -= $Random2 / 10
        $aPoints[2][0] = $Random1 + $Random2 - ($Random2 / 10 * 2)
        $aPoints[3][0] = $aPoints[2][0] + 50
        $aPoints[4][0] = $aPoints[1][0] + 50
        _GDIPlus_GraphicsFillPolygon($hGraphics, $aPoints, $hBrush)
    Next
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    Return $oBitmap
EndFunc ;==>_CreateCustomBk

Func _CreateCustomGroupPic($hGraphics, $ix, $iy, $Width, $iHeight, $hexColor, $alpha = "0x55")
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, 2)
    Local $hBrush = _GDIPlus_BrushCreateSolid($alpha & Hex($hexColor, 6))
    _GDIPlus_GraphicsFillRect($hGraphics, $ix, $iy, $Width, $iHeight, $hBrush)
    _GDIPlus_GraphicsFillRect($hGraphics, 2, 2, $Width - 4, $iHeight - 4, $hBrush)
    _GDIPlus_BrushDispose($hBrush)
EndFunc ;==>_CreateCustomGroupPic

Func _SetGuiRoundCorners($hGUI, $iEllipse, $iLeftUp = True, $iLeftDown = True, $iRightUp = True, $iRightDown = True)
    Local $hCornerRgn
    Local $aGuiSize = WinGetPos($hGUI)
    Local $hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aGuiSize[2], $aGuiSize[3], $iEllipse, $iEllipse)
    If $iLeftUp = False Then
        $hCornerRgn = _WinAPI_CreateRectRgn(0, 0, $aGuiSize[2] / 2, $aGuiSize[3] / 2)
        _WinAPI_CombineRgn($hRgn, $hRgn, $hCornerRgn, $RGN_OR)
        _WinAPI_DeleteObject($hCornerRgn)
    EndIf
    If $iLeftDown = False Then
        $hCornerRgn = _WinAPI_CreateRectRgn(0, $aGuiSize[3] / 2, $aGuiSize[2] / 2, $aGuiSize[3])
        _WinAPI_CombineRgn($hRgn, $hRgn, $hCornerRgn, $RGN_OR)
        _WinAPI_DeleteObject($hCornerRgn)
    EndIf
    If $iRightUp = False Then
        $hCornerRgn = _WinAPI_CreateRectRgn($aGuiSize[2] / 2, 0, $aGuiSize[2], $aGuiSize[3] / 2)
        _WinAPI_CombineRgn($hRgn, $hRgn, $hCornerRgn, $RGN_OR)
        _WinAPI_DeleteObject($hCornerRgn)
    EndIf
    If $iRightDown = False Then
        $hCornerRgn = _WinAPI_CreateRectRgn($aGuiSize[2] / 2, $aGuiSize[3] / 2, $aGuiSize[2] - 1, $aGuiSize[3] - 1)
        _WinAPI_CombineRgn($hRgn, $hRgn, $hCornerRgn, $RGN_OR)
        _WinAPI_DeleteObject($hCornerRgn)
    EndIf
    _WinAPI_SetWindowRgn($hGUI, $hRgn)
EndFunc ;==>_SetGuiRoundCorners

Func SetTransparentBitmap($hGUI, $hImage, $iOpacity = 0xFF)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hMemDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc ;==>SetTransparentBitmap

Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iStride = 0, $iPixelFormat = 0x0026200A, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "int*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aResult[6]
EndFunc ;==>_GDIPlus_BitmapCreateFromScan0

Func _WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
    _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndFunc ;==>_WM_LBUTTONDOWN

Screenshot:

Br,

UEZ

Edited January 8, 2013 by UEZ

dmob · December 25, 2012

Thank you for these examples. How about an example of a floating, non-focusing toolbar please.

guinness · December 25, 2012

Please post examples only. This isn't a request thread.

PlayHD · December 25, 2012

One of my old projects...

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>
Global $RBOX_EVENT_CLOSE = 1
Global $ROUNDES = 20, $LastHwnd = 0
Global $GUIBKCOLOR = 0xEEC591
Global $ARRAY_COLOR_TOP_MIN[3] = [36 ,65 ,142] , $ARRAY_COLOR_TOP_MAX[3] = [11 ,42 ,122]

Local $hGui = RBoxCreate("Gui Design PHD",800,600)

While 1
CheckX($hGui,$RBOX_EVENT_CLOSE,"GuiCtrlSetColor("&$RBOX_EVENT_CLOSE&",0xA3A3A3)","GuiCtrlSetColor("&$RBOX_EVENT_CLOSE&",0x555555)")
$gMsg = GUIGetMsg()
Switch $gMsg
Case $RBOX_EVENT_CLOSE, $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

Func RBoxCreate($Title,$width, $height ,$left=-1 ,$top=-1 ,$show=1)
Local $GUI = GUICreate($Title,$width,$height,$left,$top,$WS_POPUP)
GUISetBkColor($GUIBKCOLOR,$GUI)
_GuiRoundCorners($GUI,0,0,$ROUNDES,$ROUNDES)
$RBOX_EVENT_CLOSE = GUICtrlCreateLabel('X',$width-20,3,25,25)
GUICtrlSetCursor($RBOX_EVENT_CLOSE,0)
GUICtrlSetBkColor($RBOX_EVENT_CLOSE,-2)
GUICtrlSetFont($RBOX_EVENT_CLOSE,15,800)
GUICtrlSetColor($RBOX_EVENT_CLOSE,0x555555)
$Title &= " "
Local $hTitle = GUICtrlCreateLabel($Title,0,0,$width-20,26,$SS_CENTER,$GUI_WS_EX_PARENTDRAG)
GUICtrlSetFont($hTitle,17,400,0,"Consolas")
GUICtrlSetBkColor($hTitle,-2)
Local $Graphic = GUICtrlCreateGraphic (0,0, $width, 25)
GUICtrlSetState($Graphic,$Gui_DISABLE)
GradientFill($Graphic, 0, 0, $width, 25, $ARRAY_COLOR_TOP_MIN, $ARRAY_COLOR_TOP_MAX)
If $show = 1 Then GUISetState(@SW_SHOW,$GUI)
Return $GUI
EndFunc

Func CheckX($hGui, $CtrlID, $sCMD, $eCMD)
Local $cGui = GUIGetCursorInfo($hGui)
If Not IsArray($cGui) Then Return 0
if $LastHwnd <> $cGui[4] And $cGui[4] = $CtrlID Then Return Execute($sCMD) + Assign("LastHwnd",$cGui[4])
if $LastHwnd <> $cGui[4] Then Return Execute($eCMD) + Assign("LastHwnd",$cGui[4])
EndFunc


Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
Dim $pos, $ret, $ret2
$pos = WinGetPos($h_win)
$ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
If $ret[0] Then
$ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
If $ret2[0] Then
Return 1
Else
Return 0
EndIf
Else
Return 0
EndIf
EndFunc

Func GradientFill($im, $x1, $y1, $width, $height, $left_color, $right_color)

Local $color0=($left_color[0]-$right_color[0])/$height
Local $color1=($left_color[1]-$right_color[1])/$height
$color2=($left_color[2]-$right_color[2])/$height
For $Y=0 to $height-1

$red=$left_color[0]-floor($Y*$color0)
$green=$left_color[1]-floor($Y*$color1)
$blue=$left_color[2]-floor($Y*$color2)

$col = Dec(Hex($blue,2) & Hex($green,2) & Hex($red,2))

GUICtrlSetGraphic($im,$GUI_GR_COLOR, $col)
GUICtrlSetGraphic($im,$GUI_GR_MOVE,0,$Y)
GUICtrlSetGraphic($im,$GUI_GR_LINE,$width,$Y)
Next
GUICtrlSetGraphic($im,$GUI_GR_COLOR, 0x000000)
GUICtrlSetGraphic($im,$GUI_GR_MOVE,0,$height)
GUICtrlSetGraphic($im,$GUI_GR_LINE,$width,$height)
GUICtrlSetGraphic($im,$GUI_GR_REFRESH)
EndFunc

Here is a screen : http://prntscr.com/ni5sq

Edited December 29, 2012 by PlayHD

guinness · December 25, 2012

PlayHD,

Just looking at your code what is -3? A label?

Edited December 25, 2012 by guinness

PlayHD · December 25, 2012

@guinness -3 is $GUI_EVENT_CLOSE

Example:

#include <GUIConstantsEx.au3>
MsgBox(0,0,$GUI_EVENT_CLOSE)

guinness · December 25, 2012

@guinness -3 is $GUI_EVENT_CLOSE
Example:
#include <GUIConstantsEx.au3>
MsgBox(0,0,$GUI_EVENT_CLOSE)

Please refrain from using magic numbers when posting examples in the Forum, as I said above the code should be clear and concise.

taietel · December 26, 2012

I use this template in my projects:

#include <GuiConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#region GLOBAL VARIABLES
Global $iW = 600, $iH = 400, $iT = 52, $iB = 52, $iLeftWidth = 150, $iGap = 10, $hMainGUI
#endregion GLOBAL VARIABLES

_MainGui()

Func _MainGui()
Local $hFooter, $nMsg, $aPos
Local $iLinks = 5
Local $sMainGuiTitle = "Sample Title"
Local $sHeader = "Sample GUI"
Local $sFooter = "2012 © AutoIt"
Local $aLink[$iLinks], $aPanel[$iLinks]
$aLink[0] = $iLinks - 1
$aPanel[0] = $iLinks - 1
$hMainGUI = GUICreate($sMainGuiTitle, $iW, $iH, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_TABSTOP))
GUISetIcon("shell32.dll", -58, $hMainGUI)

GUICtrlCreateLabel($sHeader, 48, 8, $iW - 56, 32, $SS_CENTERIMAGE)
GUICtrlSetFont(-1, 14, 800, 0, "Arial", 5)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)

GUICtrlCreateIcon("shell32.dll", -131, 8, 8, 32, 32)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
GUICtrlCreateLabel("", 0, $iT, $iW, 2, $SS_SUNKEN);separator
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKHEIGHT)
GUICtrlCreateLabel("", $iLeftWidth, $iT + 2, 2, $iH - $iT - $iB - 2, $SS_SUNKEN);separator
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKBOTTOM + $GUI_DOCKWIDTH)
GUICtrlCreateLabel("", 0, $iH - $iB, $iW, 2, $SS_SUNKEN);separator
GUICtrlSetResizing(-1, $GUI_DOCKBOTTOM + $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKHEIGHT)

$hFooter = GUICtrlCreateLabel($sFooter, 10, $iH - 34, $iW - 20, 17, BitOR($SS_LEFT, $SS_CENTERIMAGE))
GUICtrlSetTip(-1, "AutoIt Forum", "Click to open...")
GUICtrlSetCursor(-1, 0)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

;add links to the left side
$aLink[1] = _AddNewLink("Link 1")
$aLink[2] = _AddNewLink("Link 2", -167)
$aLink[3] = _AddNewLink("Link 3", -222)
$aLink[4] = _AddNewLink("Link 4", -22)
;and the corresponding GUI's
$aPanel[1] = _AddNewPanel("Title for the panel 1")
$aPanel[2] = _AddNewPanel("Title for the panel 2")
$aPanel[3] = _AddNewPanel("Title for the panel 3")
$aPanel[4] = _AddNewPanel("Title for the panel 4")

;add some controls to the panels
_AddControlsToPanel($aPanel[1])
GUICtrlCreateEdit("", 10, 37, $iW - $iLeftWidth + 2 - 20 - 5, $iH - $iT - $iB - 40, BitOR($ES_AUTOVSCROLL, $ES_NOHIDESEL, $ES_WANTRETURN, $WS_VSCROLL), $WS_EX_STATICEDGE)
Local $sTestTxt = ""
For $i = 1 To 10
$sTestTxt &= @TAB & "Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vestibulum felis lectus, pharetra vel laoreet nec, pulvinar nec justo. Donec malesuada, nunc eu faucibus sodales, diam sem tempor neque, id condimentum turpis nunc vel lacus. Nulla a nulla libero, eget eleifend dolor. Vivamus volutpat tincidunt ultricies. Vestibulum eu libero nisi, quis tincidunt nisi. Proin tincidunt, ipsum ullamcorper posuere venenatis, libero nulla venenatis enim, ultrices tincidunt ipsum arcu nec turpis. In at erat sed ipsum gravida mattis in at felis. Vivamus diam purus, dictum ut luctus vitae, sollicitudin ut velit. Maecenas velit mauris, fringilla ut condimentum bibendum, aliquam a neque. Nulla metus eros, commodo id dictum in, interdum sed ipsum. Vivamus feugiat, mi at auctor fringilla, libero lectus vulputate tortor, eu sollicitudin nulla lacus at neque." & @CRLF
$sTestTxt &= @TAB & "Sed vel ante magna. Curabitur porttitor ante in tellus bibendum non tristique diam volutpat. Class aptent taciti sociosqu ad litora torquent per conubia nostra, per inceptos himenaeos. In tellus lectus, ultrices in tempus eget, sollicitudin quis eros. Curabitur at arcu bibendum massa feugiat euismod at a felis. Nunc molestie, enim non ornare tincidunt, ipsum nisi tempus sapien, quis elementum elit velit ut neque. Suspendisse eu adipiscing risus. Nam tempor odio ut elit auctor rhoncus. Etiam viverra elit id felis feugiat pellentesque pretium porttitor dui. Vivamus eu quam non ante suscipit vehicula a nec eros. Phasellus congue massa sed libero interdum ullamcorper. Quisque fringilla massa ut lorem fringilla pulvinar eget ullamcorper eros. Praesent faucibus, erat at consequat tempus, nulla erat sodales mi, eget sagittis nibh erat nec nunc. Phasellus risus nibh, porta viverra pretium nec, vehicula eget nisi." & @CRLF
$sTestTxt &= @TAB & "Sed vel neque vel urna elementum accumsan feugiat quis mauris. Sed mi nisl, consequat dapibus molestie ac, rutrum ut elit. Praesent sed risus sem. Mauris rutrum blandit magna nec tristique. Vestibulum ante ipsum primis in faucibus orci luctus et ultrices posuere cubilia Curae; Suspendisse consequat iaculis odio nec cursus. Duis varius tincidunt ligula ac ultricies. Ut eget magna in nulla vulputate dapibus ut vel sem. Integer ac tempor risus." & @CRLF
$sTestTxt &= @TAB & "Maecenas molestie semper turpis, id tristique nibh pharetra eget. Aliquam erat volutpat. In egestas, lorem quis varius vestibulum, enim diam porta lorem, quis dictum arcu ante a diam. Nullam vel nisi mauris. Cum sociis natoque penatibus et magnis dis parturient montes, nascetur ridiculus mus. Aliquam ut leo purus, eget vulputate augue. Fusce et est sagittis felis accumsan sollicitudin eget a lectus. Cras sapien sapien, rutrum eu tempor non, tempor nec velit. Vivamus interdum adipiscing felis in malesuada. Fusce quis purus est, eget molestie turpis. In hac habitasse platea dictumst." & @CRLF
$sTestTxt &= @TAB & "Aenean eleifend risus vitae lorem laoreet facilisis. Suspendisse ac urna quam, vel rutrum sem. Sed bibendum porta tellus malesuada scelerisque. Vestibulum at ligula sed nulla sollicitudin tincidunt. Pellentesque mi magna, vulputate et aliquam a, auctor et nunc. Phasellus feugiat fringilla accumsan. Donec ultrices, elit id dapibus auctor, nunc odio viverra lorem, non commodo mi libero a libero. Cras vitae felis venenatis augue laoreet tincidunt scelerisque id odio. Proin lorem purus, molestie feugiat pretium nec, ornare aliquam turpis. "
Next
GUICtrlSetData(-1, $sTestTxt)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM)

_AddControlsToPanel($aPanel[2])
GUICtrlCreateLabel("Label1", 8, 38, 36, 17)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
Local $hInput1 = GUICtrlCreateInput("Input1", 56, 35, 121, 21)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
Local $hButton1 = GUICtrlCreateButton("Button1", 200, 33, 75, 25)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)

_AddControlsToPanel($aPanel[3])
GUICtrlCreateList("", 8, 37, 121, 93, -1, 0)
GUICtrlSetData(-1, "dfgdfg|ertert|kljlkj|poipoi|qweqwe")
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)

_AddControlsToPanel($aPanel[4])
GUICtrlCreateGroup("Group1", 8, 35, 129, 90)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
Local $aChkBox[4]
For $i = 1 To 3
$aChkBox[$i] = GUICtrlCreateRadio("Some radio " & $i, 16, 56 + ($i - 1) * 20, 113, 17)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
Next
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateGroup("", -99, -99, 1, 1)

;set default to Panel1
GUISwitch($aPanel[1])
;show the main GUI
GUISetState(@SW_SHOW, $hMainGUI)

While 1
Sleep(10)
$nMsg = GUIGetMsg(1)
Switch $nMsg[1]
Case $hMainGUI
Switch $nMsg[0]
Case $GUI_EVENT_CLOSE
Exit
Case $GUI_EVENT_MINIMIZE, $GUI_EVENT_MAXIMIZE, $GUI_EVENT_RESTORE
$aPos = WinGetPos($hMainGUI)
$iW = $aPos[2]
$iH = $aPos[3]
For $i = 0 To $aPanel[0]
WinMove($aPanel[$i], "", $iLeftWidth + 2, $iT, $iW - $iLeftWidth + 2, $iH - $iT - $iB - 20)
Next
Case $aLink[1], $aLink[2], $aLink[3], $aLink[4]
For $i = 1 To $aLink[0]
If $nMsg[0] = $aLink[$i] Then
GUISetState(@SW_SHOW, $aPanel[$i])
Else
GUISetState(@SW_HIDE, $aPanel[$i])
EndIf
Next
Case $hFooter
ShellExecute("http://www.autoitscript.com/forum/topic/146952-gui-design-concepts/")
EndSwitch
Case $aPanel[2]
Switch $nMsg[0]
Case $hButton1
MsgBox(32, "Test", "You have " & GUICtrlRead($hInput1) & "?")
EndSwitch
Case $aPanel[4]
Switch $nMsg[0]
Case $aChkBox[1], $aChkBox[2], $aChkBox[3]
For $i = 1 To 3
If GUICtrlRead($aChkBox[$i]) = $GUI_CHECKED Then MsgBox(64, "Test", "You checked nr. " & $i & "!")
Next
EndSwitch
EndSwitch
WEnd
EndFunc ;==>_MainGui

Func _AddNewLink($sTxt, $iIcon = -44)
Local $hLink = GUICtrlCreateLabel($sTxt, 36, $iT + $iGap, $iLeftWidth - 46, 17)
GUICtrlSetCursor(-1, 0)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
GUICtrlCreateIcon("shell32.dll", $iIcon, 10, $iT + $iGap, 16, 16)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
$iGap += 22
Return $hLink
EndFunc ;==>_AddNewLink

Func _AddNewPanel($sTxt)
Local $gui = GUICreate("", $iW - $iLeftWidth + 2, $iH - $iT - $iB, $iLeftWidth + 2, $iT, $WS_CHILD + $WS_VISIBLE, -1, $hMainGUI)
GUICtrlCreateLabel($sTxt, 10, 10, $iW - $iLeftWidth - 20, 17, $SS_CENTERIMAGE)
GUICtrlSetFont(-1, 9, 800, 4, "Arial", 5)
GUICtrlSetResizing(-1, $GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKWIDTH + $GUI_DOCKHEIGHT)
Return $gui
EndFunc ;==>_AddNewPanel

Func _AddControlsToPanel($hPanel)
GUISwitch($hPanel)
EndFunc ;==>_AddControlsToPanel

Loz · December 26, 2012

I use this template in my projects:

I like it. Thanks for sharing

czardas · December 26, 2012

One of my own favourite designs is Resources to run the program are in the zip file attached to the first post in the linked to thread. The idea was to hide all the controls and avoid making its operation obvious. This is generally a bad idea, but this is not true in this particular case. While there have been no comments, I think it's a cool design, especially the background image. It also has one or two 'unique' features.

Posted Image

Controls only appear when you mouse over them.

Not exactly obvious now is it? :blink:

Edited December 31, 2012 by czardas

lorenkinzel · December 27, 2012

This is an "exit splash". I stripped all the stuff from the GUI because they're boring work items.

The point is: on exit.

Livening-up work items needs to be subtle.

#include <GUIConstantSex.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <MenuConstants.au3>
$gui = GUICreate("gui", 80, @DesktopHeight * .925, @DesktopWidth * .75, 10, -1, $WS_EX_COMPOSITED)
WinSetOnTop("gui", "", 1)
$movePatch = GUICtrlCreateLabel("", 1, @DesktopHeight * .925 * .5, 78, 40)
GUICtrlSetBkColor($movePatch, 0x302030)
GUICtrlSetTip($movePatch, "hold here to move")
GUISetState()
While 1
$nMsg = GUIGetMsg()
Select
Case $nMsg = $GUI_EVENT_CLOSE
BlueAway()
GetSkinny()
ExitLoop
Case $nMsg = $movePatch
move_it()
EndSelect
WEnd
Func move_it()
_SendMessage($gui, $WM_SYSCOMMAND, ($SC_MOVE + $HTCAPTION), 0)
EndFunc ;==>move_it
Func BlueAway()
GUISetBkColor(0x0000ff, $gui)
For $i = 250 To 120 Step -1.5
WinSetTrans($gui, "", $i)
Next
EndFunc ;==>BlueAway
Func GetSkinny()
For $i = 80 To 4 Step -1
WinMove($gui, "", @DesktopWidth * .75, 10, $i, @DesktopHeight * .925)
Next
GetShort()
EndFunc ;==>GetSkinny
Func GetShort()
For $i = @DesktopHeight * .925 To 4 Step -1
WinMove($gui, "", @DesktopWidth * .75, 10, 4, $i)
Next
EndFunc ;==>GetShort

Edited December 27, 2012 by lorenkinzel

czardas · December 28, 2012

Thank you for these examples. How about an example of a floating, non-focusing toolbar please.

Posted Image

I still can't believe how I got so lucky with this arrangement, which caters for all printable win-1252 codepage extended ascii characters. Only 70 keys being required: filling exactly 5 rows of 14 keys. Talk about serendipity, or what!

Please refrain from using magic numbers when posting examples in the Forum

There is only one exception to this: That is when the required constant is missing from the includes library. Edited December 29, 2012 by czardas

water · December 28, 2012

Wouldn't it be nice if there was a screenshot with each example script?

czardas · December 28, 2012

I have one more I made this year, but I've been too busy lately to focus on anything new. This GUI replaces the default title bar, minimize and close buttons.

Posted Image

guinness · December 28, 2012

There is only one exception to this: That is when the required constant is missing from the includes library.

True, but that put it in a comment of what it should be e.g.

0xFF0 ; WM_SOMETHING or MSG_OKCANCEL

BrewManNH · December 28, 2012

Here are 2 examples of using transparency in a GUI. The first uses a background image that is used to display an oval shaped GUI and controls on top of it. It's just a basic one color oval, but you can use anything in it's place to make a GUI of any shape, as long as the background has a consistent single color to be used for the transparent color.

The second is a GUI that is nearly fully transparent except for the label text. This example also shows how to use a label as a hyperlink, and a label that can be used to drag a GUI around like a title bar.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>
Opt("GUIOnEventMode", 1)
Global $URL[4]
Global $Active = 1
_Main()
_Links()
Func _Main() ; Partially transparent GUI
    $Temp = GUICreate("", 800, 280, -1, -1, $WS_POPUP, $WS_EX_LAYERED) ; set up GUI to be transparent
    GUISetBkColor(0x9FBAD8) ; set the back ground color of the GUI to match the color of the upper left pixel of the back ground picture
    GUICtrlCreatePic(@ScriptDir & "\bg.bmp", 0, 0, 0, 0) ; use a bmp as the back ground picture, jpg can be used but it won't look as good.
    GUICtrlSetState(-1, $GUI_DISABLE) ; disable the picture so you can interact with the controls
    GUISetOnEvent($GUI_EVENT_CLOSE, "_TempClose1")
    GUICtrlSetFont(-1, 10, 800, -1, "Consolas")
    GUICtrlSetColor(-1, 0x0000000)
    GUICtrlCreateButton(" Close ", 225, 210, -1) ; buttons can show artifacts that you don't want on your GUI
    GUICtrlSetOnEvent(-1, "_TempClose1")
    GUICtrlCreateIcon("shell32.dll", -28, 230, 150) ; icons look much better on this type of GUI
    GUICtrlSetOnEvent(-1, "_TempClose1") ; the icon acts like a button
    Local $idProgress = GUICtrlCreateProgress(110, 100, 280, 20)
    $iProgress = 1
    GUISetState()
    While $Active
        Sleep(100)
        $iProgress += 1
        If $iProgress = 101 Then $iProgress = 1
        GUICtrlSetData($idProgress, $iProgress)
    WEnd
EndFunc ;==>_Main

Func _Links() ; Fully transparent GUI with hyperlinks
    Local $Func[4]
    $URL[0] = "http://www.autoitscript.com/forum"
    $URL[1] = "http://www.autoitscript.com/forum/forum/2-general-help-and-support/"
    $URL[2] = "http://www.autoitscript.com/forum/forum/9-example-scripts/"
    $URL[3] = "Extended Message Box"
    Local $Text = "You can drag the GUI around by left clicking on this label and dragging it." & @LF & @LF & _
            "Some helpful links: "
    $Func[0] = "Main forum page"
    $Func[1] = "General Help and Support"
    $Func[2] = "Example Scripts"
    $Func[3] = ""
    $Temp = GUICreate("", 800, 280, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
    GUISetBkColor(0xFFFFFF) ; set the back ground color of the GUI to match the color of the Upper left pixel of the background image. In this case it's white.
    GUICtrlCreatePic(@ScriptDir & "\White.bmp", 0, 0, 0, 0)
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_TempClose")
    GUISetBkColor(0xFFFFFF, $Temp)
    GUICtrlCreateLabel($Text, 40, 10, 750, 100, Default, $GUI_WS_EX_PARENTDRAG) ; You can drag the window around with this label
    GUICtrlSetFont(-1, 10, 800, -1, "Consolas")
    GUICtrlSetBkColor(-1, 0x00DDDD) ; sets the back ground color of the label so you can see where it starts/ends
    GUICtrlSetColor(-1, 0x0000000)
    GUICtrlCreateButton(" Close ", 360, 230, -1)
    GUICtrlSetOnEvent(-1, "_TempClose")
    For $I = 0 To 3
        GUICtrlCreateLabel($Func[$I], 40, 130 + ($I * 20), 200, 20)
        GUICtrlSetColor(-1, 0x000000)
        GUICtrlSetFont(-1, 9, 400, 0)
    Next
    GUICtrlCreateLabel($URL[0], 260, 130, 400, 20)
    GUICtrlSetOnEvent(-1, "_ForumURL")
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x00000FF)
    GUICtrlSetFont(-1, 9, 400, 4)
    GUICtrlCreateLabel($URL[1], 260, 150, 400, 20)
    GUICtrlSetOnEvent(-1, "_GHSURL")
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x00000FF)
    GUICtrlSetFont(-1, 9, 400, 4)
    GUICtrlCreateLabel($URL[2], 260, 170, 348, 20)
    GUICtrlSetOnEvent(-1, "_ExampleURL")
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x00000FF)
    GUICtrlSetFont(-1, 9, 400, 4)
    GUICtrlCreateLabel($URL[3], 260, 190, 400, 20)
    GUICtrlSetOnEvent(-1, "_EMBURL")
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x00000FF)
    GUICtrlSetFont(-1, 9, 400, 4)
    GUISetState()
    While 1
        Sleep(10)
    WEnd
EndFunc ;==>_Links
Func _TempClose()
    Exit
EndFunc ;==>_TempClose
Func _TempClose1()
    $Active = 0
    GUIDelete()
EndFunc ;==>_TempClose1
Func _ForumURL()
    ShellExecute($URL[0])
EndFunc ;==>_ForumURL
Func _GHSURL()
    ShellExecute($URL[1])
EndFunc ;==>_GHSURL
Func _ExampleURL()
    ShellExecute($URL[2])
EndFunc ;==>_ExampleURL
Func _EMBURL()
    ShellExecute("http://www.autoitscript.com/forum/index.php?showtopic=109096")
EndFunc ;==>_EMBURL

You will need the files in the attached zip to see these in action, extract them to the same folder that the script is being run from.

You can use files other than BMP files, but they won't look as good because of artifacting due to image compression. A PNG should/might work as well, I haven't tried that yet.

Backgrounds.zip

PlayHD · January 11, 2013

Take a look

http://pastebin.com/jVAA8DLq

mesale0077 · January 23, 2013

maybe

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <ProgressConstants.au3>
#include <EditConstants.au3>

dim $Label1[100]
$Form1 = GUICreate("forum ", 0, 0, -1, -1)
GUISetBkColor(0x0000FF)
GUISetState(@SW_SHOW)
grow($Form1, 380, 380, 1, 5)
local $iWinSize = WinGetClientSize($Form1 )

$Label1[1] = GUICtrlCreateLabel("autoit ı love you", 56+$iWinSize[0], 24+$iWinSize[1], 217, 17)
GUICtrlSetTip(-1," by"& @CRLF&".@mesale0077.")
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xFFFFFF)

$Label1[2]= GUICtrlCreateLabel("autoit :", 16+$iWinSize[0] ,56+$iWinSize[1], 66, 17)
GUICtrlSetTip(-1," by"& @CRLF&".@mesale0077.")
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xFFFFFF)

$Label1[3] = GUICtrlCreateLabel("autoit love :", 16+$iWinSize[0], 128+$iWinSize[1], 63, 17)
GUICtrlSetTip(-1," by"& @CRLF&".@mesale0077.")
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xFFFFFF)
$Label1[4] = GUICtrlCreateInput("", 16+$iWinSize[0], 88+$iWinSize[1], 289, 21)


$Label1[5] = GUICtrlCreateInput("", 16+$iWinSize[0], 160+$iWinSize[1], 289, 21)

$Label1[6] = GUICtrlCreateButton("ok", 24+$iWinSize[0], 224+$iWinSize[1], 97, 33, $WS_GROUP)

GUICtrlSetCursor (-1, 0)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")

$Label1[7]= GUICtrlCreateButton("exit", 200+$iWinSize[0], 224+$iWinSize[1], 97, 33, $WS_GROUP)

GUICtrlSetCursor (-1, 0)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")

for $66= 1 to 7
AnimateControl($Form1,$Label1[$66],4,1,5,1)

next





While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
for $66= 1 to 7
AnimateControl($Form1,$Label1[$66],8,1,5,2)

next
grow($Form1, 0, 0, 3, 2)
Exit
Case $Label1[6]
EndSwitch
WEnd

Func AnimateControl($hWnd, $iHandle, $iAnimate = 1, $iSpeed = 1,$hoz=1,$pp=1)

if $pp=1 then
local $iPos = ControlGetPos($hWnd, "", $iHandle)
local $iWinSizee = WinGetClientSize($hWnd)
$iPos[0]=$iPos[0]-$iWinSize[0]
$iPos[1]=$iPos[1]-$iWinSize[1]


else
if $pp=2 then
local $iPos = ControlGetPos($hWnd, "", $iHandle)
local $iWinSizee = WinGetClientSize($hWnd)

endif
endif

If $iAnimate = 1 Then
For $i = -40 To $iPos[0] step $hoz
GUICtrlSetPos($iHandle, $i, $iPos[1])
GUICtrlSetState(-1,@SW_show)
Sleep($iSpeed)
Next
Return
EndIf

If $iAnimate = 2 Then
For $i = $iWinSizee[0] To $iPos[0] Step -1*$hoz

GUICtrlSetPos($iHandle, $i, $iPos[1])
GUICtrlSetState(-1,@SW_show)
Sleep($iSpeed)
Next
Return
EndIf

If $iAnimate = 3 Then
For $i = 0 To $iPos[1] step $hoz
GUICtrlSetPos($iHandle, $iPos[0], $i)
GUICtrlSetState(-1,@SW_show)
Sleep($iSpeed)
Next
Return
EndIf

If $iAnimate = 4 Then
For $i = $iWinSizee[1] + 30 To $iPos[1] Step -1*$hoz
GUICtrlSetPos($iHandle, $iPos[0], $i)
GUICtrlSetState(-1,@SW_show)
Sleep($iSpeed)
Next
Return
EndIf

If $iAnimate = 5 Then
For $i = $iPos[0] To -$iWinSizee[0] step -1*$hoz
GUICtrlSetPos($iHandle, $i, $iPos[1])

Sleep($iSpeed)
Next
GUICtrlDelete( $iHandle)
Return
EndIf
If $iAnimate = 6 Then
For $i = $iPos[0] To $iWinSizee[0]Step 1*$hoz

GUICtrlSetPos($iHandle, $i, $iPos[1])

Sleep($iSpeed)
Next
GUICtrlDelete( $iHandle)
Return
EndIf
If $iAnimate = 7 Then
For $i = $iPos[1] To -40 step -1*$hoz
GUICtrlSetPos($iHandle, $iPos[0], $i)

Sleep($iSpeed)
Next
GUICtrlDelete($iHandle)
Return
EndIf

If $iAnimate = 8 Then
For $i = $iPos[1] To $iWinSizee[1] + $iPos[1] Step 1*$hoz
GUICtrlSetPos($iHandle, $iPos[0], $i)

Sleep($iSpeed)
Next
GUICtrlDelete($iHandle)
Return
EndIf

EndFunc

Func grow($gui, $guix, $guiy, $type, $step)
$size = WinGetClientSize($gui)
If $type = 1 Then
For $x = $size[0] To $guix Step $step/3
$size = WinGetClientSize($gui)
$zx = (@DesktopWidth/2) - ($size[0]/2)
$zy = (@DesktopHeight/2) - ($size[1]/2)
WinMove($gui, '', $zx, $zy, $x + $step, 25)
Next
For $y = $size[1] To $guiy Step $step/2
$size = WinGetClientSize($gui)
$zx = (@DesktopWidth/2) - ($size[0]/2)
$zy = (@DesktopHeight/2) - ($size[1]/2)
WinMove($gui, '', $zx, $zy, $x, $y + $step)
Next
endif
If $type = 2 Then
For $w = 0 To 102 Step $step/4
$size = WinGetClientSize($gui)
$dw = (@DesktopWidth/2) - ($size[0]/2)
$dh = (@DesktopHeight/2) - ($size[1]/2)
WinMove($gui, '', $dw, $dh, ($guix/100)*$w, ($guiy/100)*$w)
Next
EndIf
If $type = 3 Then

local $aPos = WinGetClientSize($gui)
local $gPos = WinGetPos($gui)

for $aaa= 1 to $aPos[0]-28 step 2
WinMove($gui, "", $gPos[0], $gPos[1], $aPos[0], $aPos[1] - $aaa)
next
$Pos = WinGetPos($gui)
for $mm= 1 to $aPos[1]+200 step 2
WinMove($gui, "", $gPos[0], $gPos[1], $aPos[0] - $mm, 28)
next

endif

EndFunc

Edited January 24, 2013 by mesale0077

guinness · January 23, 2013

Please use [autoit][/autoit] tags rather than the generic (code)(/code) tags. Thanks

Edited January 23, 2013 by guinness

GUI design concepts.

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members