Good coding practices in AutoIt

[acidman]

Ok one more question I have for you if that's ok, let's say a user has a very slow pc. Is there a way I could limit the amount of data written into the memory/variable(s)?

[guinness]

Read the title of this thread. Questions like that should be redirected to General help and support.

[acidman]

Ahhh mannn!!!! I have been struggling to get that type of return for a long time now damn, enum just made my day!! Ok wait maybe I should, check out the stuff I never really cared about!

[guinness]

I'm curious as to whether or not the code below could be deemed as 'good coding practice'?

#include <MsgBoxConstants.au3>

Local Const $aState[2] = ['False State', 'True State']
Local Const $bState = False ; This is equal to the integer value 0.
MsgBox($MB_SYSTEMMODAL, '', $aState[Int($bState)]) ; Convert the boolean value to a 32-bit integer.

Edited September 4, 2015 by guinness

[BrewManNH]

It's not very readable that way, if this were somewhere deep in the script, I'd need to find out what $aState contains, and what $fState equals before I could understand what you're doing in it.

[guinness]

True.

I would do it like this though in the future...

#include <MsgBoxConstants.au3>

Local Const $bState = False ; This is equal to the integer value 0.
; v3.3.10.0+ and above or use _Iif.
MsgBox($MB_SYSTEMMODAL, '', $bState ? 'True State' : 'False State')

Edited September 4, 2015 by guinness

[Exit]

v3.3.9.4+ and above or use _Iif.

I think it would be better to say: v3.3.9.5 and above or use _Iif

v3.3.9.4 has no ternary operator.

[jaberwacky]

Model - View - Controller

Let's talk about something which I have only recently just begun to grasp. I grasp it well enough to describe it's basics. I hope. I will endeavor to provide a basic explanation and describe some methods to implement MVC into AutoIt scripts. At least one of you might say that this does not pertain to AutoIt. But it does I think.

The MVC pattern is many and varied. There does not seem to be one agreed upon method. There are other modern flavors too such as Model View Presenter and Model View ViewModel none of which I have begun to look into.

So let's begin with the model.

Model

The model knows how to perform your program's calculations. It has your algorithms. The model also has a database if your program has one. The model maintains your program's state. It's the brains of the operation.

View

This module manages your GUI essentially. This module doesn't perform its own program calculations. The view just takes the data that is feed to it and presents it on the screen.

Controller

This module coordinates the user's actions with the model and the view. If the user clicks on a button or enters information into an input field it then takes that information and does one or many things with it. The controller may take the information and give it to the model to store in a database. If a user clicks a button the controller may then ask the model for the result of a calculation. Then the controller may take this information from the model and give it to the view. For example it may take a list of customer names from the model and then give it to the view which may then update a listview control with that list.

The common method of MVC seems to be the following picture: (http://www.songho.ca/opengl/files/gl_mvc01.png)

The way that I use MVC in AutoIt is to leave out the arrow connecting the View and the Model. The controller can call functions in the View and can call functions in the Model. The model can not call functions in the Controller or the View. Conversely, the View may not call methods in the Model or the Controller.

Here is an oversimplified example:

Model.au3

#include-once

Func _model_get_username()
    Return @UserName
EndFunc

View.au3

#include-once

GUICreate("My Program", 100, 100)

Global Const $h_label = GUICtrlCreateLabel('', 10, 10, 80, 80)

Func _view_display_username(Const $username)
    GUICtrlSetData($h_label, $username)
EndFunc

Controller.au3

$include "View.au3"

$include "Model.au3"

Global Const $account_username = _model_get_username()

_view_display_username($account_username)

Do
    Switch GUIGetMsg()
        Case $gui_close_event
            Exit
    EndSwitch
Until False

I'm sure I will amend this document throughout the next day or two so check back. Fell free to offer enhancements etc.

Edited February 27, 2013 by jaberwocky6669

[guinness]

Using the Default keyword is a preferable choice when using the optional parameters of a custom function.

OnAutoItExitRegister('SomeFuncWrapper')
SomeFunc(10)

Func SomeFunc($iValue = 0, $sString = Default, $hVar = 0x00000000)
    ; If the Default keyword is passed then set the default parameter and thus you don't have to remember the optional parameters.
    If $iValue = Default Then $iValue = 0
    If $sString = Default Then $sString = 'SomeString'
    If $hVar = Default Then $hVar = 0x00000000
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iValue = ' & $iValue & @CRLF & '>Error code: ' & @error & @CRLF)
EndFunc   ;==>SomeFunc

Func SomeFuncWrapper()
    SomeFunc(Default, Default, Default)
    ; Instead of having to refer back to the function. e.g.
    ; SomeFunc(0, Default, 0x00000000)
    ; Because if you change the optional parameters of SomeFunc() and forget to update this function, then it could lead to problems.
EndFunc   ;==>SomeFuncWrapper

[AZJIO]

This improves the readability of not function. Parameters by default are unknown. For some functions just slows down work in a loop.

Func _ArrayDisplay(Const ByRef $avArray, $sTitle = Default, $iItemLimit = Default, $iTranspose = Default, $sSeparator = Default, $sReplace = Default, $sHeader = Default)
    If (Not IsArray($avArray)) Or (Not UBound($avArray, 1)) Then Return SetError(1, 0, 0)

    ; Default values
    If $sTitle = Default Then $sTitle = "Array: ListView Display"
    If $iItemLimit = Default Then $iItemLimit = -1
    If $iTranspose = Default Then $iTranspose = 0
    If $sSeparator = Default Then $sSeparator = ""
    If $sReplace = Default Then $sReplace = "|"
    If $sHeader = Default Then $sHeader = ""

[guinness]

But you know as well as I do AZJIO, that a different approach would be adopted for using a function in a "tight loop".

[czardas]

I have been thinking about this and have come to the conclusion that advantages to using the Default keyword will often dependant on the order of parameters. There is no need to use the Default keyword for the last parameter since it can simply be omitted when calling the function. Using Default for the parameters in the following code would seem uneccessary since both default values need to be altered for anything to happen.

Func _ParamOrder($bSomething = False, $bSomethingTwice = False)
    If $bSomething And $bSomethingTwice Then ConsoleWrite("Hello World")
EndFunc

[guinness]

By default, the keyword Default is similar to False, so if the parameter by default is boolean, then it makes no difference to using False or Default. So in your snippet Default can be used as well.

[czardas]

Okay, I changed it.

Func _NewVersion($bSame_Thing = True, $bSame_Thing_Again = True)
    If Not ($bSame_Thing Or $bSame_Thing_Again) Then ConsoleWrite("Hello World" & @LF)
EndFunc

Modified following PlayHD's comment below.

Edited April 22, 2013 by czardas

[water]

What do you mean by "similar to False"?

MsgBox(0, "", Default = True)
MsgBox(0, "", Default = False)

both return False. The documentation for 3.3.8.1 states nothing about what you say. Edited April 21, 2013 by water

[guinness]

No water, I didn't say it was False, I said it was similar.

#include <Constants.au3>

Local $bSomeVar = Default
If $bSomeVar Then MsgBox($MB_SYSTEMMODAL, '', 'Variable is True (1)')

$bSomeVar = True
If $bSomeVar Then MsgBox($MB_SYSTEMMODAL, '', 'Variable is True (2)')

$bSomeVar = False
If $bSomeVar Then MsgBox($MB_SYSTEMMODAL, '', 'Variable is True (3)')

Edited September 4, 2015 by guinness

[PlayHD]

Okay, I changed it.

Func _NewVersion($bSame_Thing = True, $bSame_Thing_Again = True)
If Not ($bSame_Thing And $bSame_Thing_Again) Then ConsoleWrite("Hello World")
EndFunc

Atention!

If you put Not in front a pair of parentheses, and inside is a keyword like AND / OR, AND will become OR and vice versa

Eg.

_NewVersion(False,True)
Func _NewVersion($bSame_Thing = True, $bSame_Thing_Again = True)
If Not ($bSame_Thing And $bSame_Thing_Again) Then ConsoleWrite("Hello World"&@LF)
EndFunc

Edited April 21, 2013 by PlayHD

[czardas]

Thanks PlayHD, that's good information. I didn't test what I wrote - which I should have done. I was mistaken to think that expressions are evaluated within parentheses first. I had intended the following behaviour, but my example is getting kind of silly.

If Not $bSame_Thing And Not $bSame_Thing_Again Then ConsoleWrite("Hello World" & @LF)

In any case, instead of boolean, the parameters could be numbers with a default value of zero. The function may depend on both values not being equal to zero to trigger an event. I don't see the advantage of using the Default keyword in such a scenario.

Edited April 21, 2013 by czardas

[AZJIO]

I read parameters in the first line

_ArrayDisplay(Const ByRef $avArray [, $sTitle = "Array: ListView Display" [, $iItemLimit = -1 [, $iTranspose = 0 [, $sSeparator = "" [, $sReplace = "|" [, $sHeader = ""]]]]]])

_ArrayDisplay(Const ByRef $avArray [, $sTitle = Default [, $iItemLimit = Default [, $iTranspose = Default [, $sSeparator = Default [, $sReplace = Default [, $sHeader = Default]]]]]])

I wouldn't want to read a detailed description to find out the default settings. To me the first line suffices. Edited April 21, 2013 by AZJIO

[guinness]

But most users should read the documentation not the code.