Good coding practices in AutoIt

[guinness]

We see a lot of examples submitted by users but rarely do we see threads about good coding practice. Post below if you have an example which exhibits the "dos and don'ts" of coding in AutoIt.

Why using Dim over Local/Global is not always a good option:

#include <MsgBoxConstants.au3>

Dim $vVariableThatIsGlobal = "This is a variable that has ""Program Scope"" aka Global."

MsgBox($MB_SYSTEMMODAL, "", "An example of why Dim can cause more problems than solve them.")

Example()

Func Example()
    MsgBox($MB_SYSTEMMODAL, "", $vVariableThatIsGlobal) ; That looks alright to me as it displays the following text: This is a variable that has "Program Scope" aka Global.

    Local $vReturn = SomeFunc() ; Call some random function.

    MsgBox($MB_SYSTEMMODAL, $vReturn, $vVariableThatIsGlobal) ; The Global variable ($vVariableThatIsGlobal) changed because I totally forgot I had a duplicate variable name in "SomeFunc".
EndFunc   ;==>Example

Func SomeFunc()
    ; This should create a variable in Local scope if the variable name doesn"t already exist.
    ; For argument sake I totally forgot that I declared a variable already with the same name.
    ; Well I only want this to be changed in the function and not the variable at the top of the script.
    ; Should be OK right? Think again.
    Dim $vVariableThatIsGlobal = ""

    For $i = 1 To 10
        $vVariableThatIsGlobal &= $i ; This will return 12345678910 totally wiping the previous contents of $vVariableThatIsGlobal.
    Next
    Return $vVariableThatIsGlobal
EndFunc   ;==>SomeFunc

Edited November 4, 2017 by guinness

[guinness]

Declaring Global variables in a Function is never a good idea:

#include <MsgBoxConstants.au3>

; Calling Example() first will initialise the Global variable $vVariableThatIsGlobal and therefore calling SomeFunc() won't return an error.
; Now look at Example 2.
Example()

Func Example()
    ; Declaring a variable in a function can cause serious problems, hence why all Global variables should be declared at the top of a script.
    Global $vVariableThatIsGlobal = 'This is a variable that has ''File Scope'' aka Global.'
    SomeFunc()
EndFunc   ;==>Example

Func SomeFunc()
    MsgBox($MB_SYSTEMMODAL, '', $vVariableThatIsGlobal) ; As the variable was initialised this will not return an error.
EndFunc   ;==>SomeFunc

Example 2:

#include <MsgBoxConstants.au3>

; Calling SomeFunc() first will bypass the Global variable $vVariableThatIsGlobal being initialised and therefore AutoIt has no idea of what data the variable
; $vVariableThatIsGlobal contains.
SomeFunc()

Func Example()
    ; Declaring a variable in a function can cause serious problems, hence why all Global variables should be declared at the top of a script.
    Global $vVariableThatIsGlobal = 'This is a variable that has ''File Scope'' aka Global.'
    SomeFunc()
EndFunc   ;==>Example

Func SomeFunc()
    MsgBox($MB_SYSTEMMODAL, '', $vVariableThatIsGlobal) ; As the variable wasn't initialised this will return an error of "variable used without being declared."
EndFunc   ;==>SomeFunc

Question: What if I want to retain variable data once returned from a Function and only use that variable in that particular Function, can't it be declared as Global then?

Answer: Static variables.

#include <MsgBoxConstants.au3>
Example()

Func Example()
    SomeFunc() ; This will display a message box of 1, 1.
    SomeFunc() ; This will display a message box of 1, 2.
    SomeFunc() ; This will display a message box of 1, 3.
EndFunc   ;==>Example

Func SomeFunc()
    ; This initialises a Static variable in Local scope. When a variable is declared just in Local scope (within a Function,)
    ; it's destroyed when the Function ends/returns. This isn't the case for a Static variable. The variable can't be
    ; accessed from anywhere else in the script apart from the Function it was declared in.
    Local Static $vVariableThatIsStatic = 0
    Local $vVariableThatIsLocal = 0
    $vVariableThatIsLocal += 1 ; This will always be 1 as it was destroyed once returned from SomeFunc.
    $vVariableThatIsStatic += 1 ; This will increase by 1.
    MsgBox($MB_SYSTEMMODAL, $vVariableThatIsLocal, $vVariableThatIsStatic)
EndFunc   ;==>SomeFunc

Edited September 4, 2015 by guinness

[guinness]

Declaring variables in loops (For, While, Do etc..) can have an affect on efficiency:

#include <MsgBoxConstants.au3>

; Declaring variables inside loops should be avoided as the variable is re-declared on each repetition.
For $i = 1 To 10 ; $i is in 'loop scope.'
    Local $iInt = $i
Next
MsgBox($MB_SYSTEMMODAL, '', $iInt) ; This will display 10.

#include <MsgBoxConstants.au3>

; Declaring variables outside of loops is more efficent in the long run.
Local $iInt = 0
For $i = 1 To 10 ; $i is in 'loop scope.'
    $iInt = $i
Next
MsgBox($MB_SYSTEMMODAL, '', $iInt) ; This will display 10.

Edited September 4, 2015 by guinness

[TheSaint]

I never really appreciated using 'Local', until I read the Wiki entry or whatever on Recursion, and put it into practice.

I'd never thought to reuse a variable like that. I presume that each instance of the same variable, just gets a different namespace or whatever it's called .... I am just a Hacker after all, and only pick up things as I go ... no courses and very few tutorials for me.

'Global' can be bad in a function, yes, but far worse in an 'Include' or UDF ... a definite no no.

[BrewManNH]

There are many uses of Global variables in most of the included UDFs, definitely not a no-no to the devs. Every XXconstants.au3 file is nothing but global variables. It all depends on what you need the variable for that decides its scope.

[jaberwacky]

Better to avoid mutable state. If you need Global variables then try to make them Const. Many many scripts can be written with very fre GLobals and most if not all of those Const.

I may add to not rely on or modify global state in functions. Pass the information that a function needs in the argument list. This way a function can be analyzed based on it's parameters. Seems to make things easier to bug test.

[guinness]

Anyone have any examples?

[czardas]

I generally avoid using globals like the plague. The main reason they appear in my examples nowadays is to simplify the code for some beginners. I also have the notion that if some keyword such as Dim happens to be part of the language, it ought to have a useful purpose of some kind. I personally use the Dim keyword to represent undefined scope (something I invented), but it wouldn't bother me if it were dropped from the language tomorrow.

[FireFox]

Good examples

The Dim statement should be only used to erase the content of a globally declared array, so ReDim only to resize it.

Everything out of functions should be declared as Global, and inside them as Local.

But this is only notes.

[czardas]

The Dim statement should be only used to erase the content of a globally declared array,

Interesting statement. Why do you say that?

Edited December 21, 2012 by czardas

[FireFox]

Interesting statement. Why do you say that?

If you declare a variable with Global or Local statement, there is no ambiguities. But as you know for the Dim statement, it's more "complicated" and most of people do not know if this last has a global or local scope.

[czardas]

Yeah I agree with that, and I see the connection between Dim and Redim. I only recently found out that Dim was a depreciated keyword. What that means exactly isn't clear to me. The following code runs and the string variable $hello is automagically converted to a local variable. The code is nonesense, but it still works.

MsgBox(0, "Dim String Test", _Dim())

Func _Dim()
    Dim $hello = "Hello"
    Return $hello
EndFunc

This is an example of bad coding practice.

Edited December 21, 2012 by czardas

[FireFox]

ok, what I said is a little bit wrong.

Here is my example :

Global $var
Local $var
;these vars are declared in the global scope, no matter of their statement, it's Global.
;to avoid any ambiguity, use only the Global statement.

Global $aArray[2] = [1, 2] ;just an array.

Func _myFunc()
Local $var
;only use the local statement inside functions, if you want to declare a Global var,
;it's better to first initialize it in the global scope.

ReDim $aArray[3] ;resize the array and keep its content.

Dim $aArray[2] ;erases the content of the array. [and resizes it]

;it's better to use Dim/ReDim to edit an array, otherwise use Local or Global to declare a var.
EndFunc

Of course I don't say it's right nor I'm the one to follow and I'm opened to criticisms.

@czardas

If you declare a non existing var with the Dim statement, then It will be declared according to the current scope, otherwise it will take the scope of the declared var.

[czardas]

Here is my example :

Nice example. Dim is indeed more complicated than it at first appears. In view of this I believe the depreciation of this keyword perhaps ought to be revised.

Edited December 21, 2012 by czardas

[guinness]

@czardas

If you declare a non existing var with the Dim statement, then It will be declared according to the current scope, otherwise it will take the scope of the declared var.

Doesn't the example I created above show this?

MsgBox(0, "Dim String Test", _Dim())

Func _Dim()
    Dim $hello = "Hello"
    Return $hello
EndFunc

This is an example of bad coding practice.

Perhaps post what it should be as well. Edited December 21, 2012 by guinness

[czardas]

Perhaps post what it should be as well.

For those who don't know, it should be something like this:

MsgBox(0, "Declare String Test", _Declare())

Func _Declare()
    Local $hello = "Hello"
    Return $hello
EndFunc

Edited December 21, 2012 by czardas

[FireFox]

Doesn't the example I created above show this?

If you are referring to what I said, it seems that czardas did not understand/read it, so I just gave him my explanation. Edited December 21, 2012 by FireFox

[guinness]

czardas,

I meant add it to your previous post.

[czardas]

If you are referring to what I said, it seems that czardas did not understand/read it, so I just gave him my explanation.

Why does everyone seem to think this? Oh well, it was worth repeating I guess.

I meant add it to your previous post.

Too late now.

Anyway I think this thread ought to become a sticky. I don't always agree with everyone's concept of good coding practices BTW. AutoIt allows for many methods, and the best method will generally depend on appropriate factors. As Firefox showed: Dim being depreciated now seems like it could be a step in the wrong direction.

Edited December 21, 2012 by czardas

[BrewManNH]

When something in the language is referred to as deprecated it means that it still works for backwards compatibility purposes, but shouldn't be used going forward.

Dim shouldn't ever be used because there's no defining what scope the variable will end up in. Especially if you're releasing a function to the general public. Matching variable names in a function, that have been declared in a global scope, may end up being reset by using Dim, causing all sorts of trouble shooting problems with people using a function that someone released. In this case you should never post a script or function for others to use with any variables declared using Dim. Explicit declaration is always preferred, Dim is always wrong.