Problem with selecting a file through FileOpenDialog

[AlexChernavsky]

I'm having a strange issue with using FileOpenDialog to select a file. Everything works fine the first time you select a file. But if you change your mind (while the program is still running) and want to select a different file, nothing changes. The program is "stuck" with the first selection you made, and nothing you do will change that selection in the input box.

I pulled the function below out of my program, and I had to modify it a bit to make it run on its own. But it's basically the same as the original.

To see the problem in action, click on either of the two buttons that say, "Choose other file...". Select any file from the list. Click on the "Open" button. So far, so good. Now, repeat the process again. See? The original file you selected is still listed in the input box.

I'm stumped by this one.

Thanks in advance.

-- Alex Chernavsky in Rochester, NY

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>

_ConfirmParametersWithUser("test.txt", "test2.txt", 16, 1000, 3000, "InputFile", "WriteToFile", "Testing")

Func _ConfirmParametersWithUser($sInputFileName, $sOutputFileName, $iNumberOfProblems, $iMinTime, $iMaxTime, $sSourceOfProblems, $sOutputType, $sCondition)
Local $hSetParametersForm ; Handle to GUI
Local $hRadio1
Local $hRadio2
Local $hRadio3
Local $hRadio4
Local $hInputFileName
Local $hChooseInputFile
Local $hOutputFileName
Local $hChooseOutputFile
Local $hTrialsPerSession
Local $hTime1
Local $hTime2
Local $hCondition
Local $hExitButton
Local $hHelpButton
Local $hContinueButton
Local $nMsg
Local $sTemp

$sInputFileName = @ScriptDir & "\" & $sInputFileName
$sOutputFileName = @ScriptDir & "\" & $sOutputFileName
$hSetParametersForm = GUICreate("Reaction Time Program: Set Parameters", 580, 578, -1, -1)
GUICtrlCreateLabel("Reaction Time Program", 175, 3, 205, 23)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")

GUICtrlCreateLabel("Based on work by Seth Roberts", 200, 29, 155, 15)
GUICtrlSetFont(-1, 8, 400, 0, "MS Sans Serif")
;GUICtrlSetBkColor(-1, 0xCCFFCC) ; Give it a green background to make it easier to position it (it's a temporary thing to help design the GUI)

GUICtrlCreateGroup("Source of arithmetic problems: ", 40, 50, 528, 105)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUIStartGroup()
$hRadio1 = GUICtrlCreateRadio("Use problems included with source code", 64, 80, 257, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
If $sSourceOfProblems = "SourceCode" Then
GUICtrlSetState(-1, $GUI_CHECKED)
EndIf
$hRadio2 = GUICtrlCreateRadio("Read problems from input file: ", 64, 104, 280, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
If $sSourceOfProblems = "InputFile" Then
GUICtrlSetState(-1, $GUI_CHECKED)
EndIf
$hInputFileName = GUICtrlCreateInput($sInputFileName & " ", 81, 124, 380, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlSetState($hInputFileName, $GUI_FOCUS)
Send("{end}") ; This line and the one before it are necessary to right-align the text (useful in case of long path names, so that the left part gets cut off, not the right part)
$hChooseInputFile = GUICtrlCreateButton("Choose other file...", 465, 121)
If $sSourceOfProblems = "InputFile" Then
GUICtrlSetState($hChooseInputFile, $GUI_ENABLE)
Else
GUICtrlSetState($hChooseInputFile, $GUI_DISABLE)
EndIf

GUICtrlCreateLabel("Number of trials (problems) presented per testing session:", 48, 167, 345, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$hTrialsPerSession = GUICtrlCreateInput($iNumberOfProblems, 397, 165, 30, 22, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")

GUICtrlCreateGroup("Random delay between trials (in milliseconds): ", 40, 198, 349, 89)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")

GUICtrlCreateLabel("Minimum delay:", 64, 224, 97, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlCreateLabel("Maximum delay :", 64, 256, 104, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$hTime1 = GUICtrlCreateInput($iMinTime, 176, 224, 41, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))
$hTime2 = GUICtrlCreateInput($iMaxTime, 176, 256, 41, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_NUMBER))

GUICtrlCreateGroup("Upon completion of the testing session: ", 40, 296, 528, 110)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
$hRadio3 = GUICtrlCreateRadio("Display summary and append data to output file: ", 64, 325, 422, 17)
If $sOutputType = "WriteToFile" Then GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$hOutputFileName = GUICtrlCreateInput($sOutputFileName & " ", 81, 350, 380, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlSetState($hOutputFileName, $GUI_FOCUS)
Send("{end}") ; This line and the one before it are necessary to right-align the text (useful in case of long path names, so that the left part gets cut off, not the right part)
$hChooseOutputFile = GUICtrlCreateButton("Choose other file...", 465, 347)
If $sOutputType = "WriteToFile" Then
GUICtrlSetState($hChooseOutputFile, $GUI_ENABLE)
Else
GUICtrlSetState($hChooseOutputFile, $GUI_DISABLE)
EndIf
$hRadio4 = GUICtrlCreateRadio("Display summary but do not write data to output file", 64, 379, 320, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
If $sOutputType = "DisplayOnly" Then GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateGroup("Please describe the condition for this test:", 40, 417, 520, 90)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
$hCondition = GUICtrlCreateInput("", 54, 447, 500, 20)
GUICtrlCreateLabel("Example: ""45 mins. after taking 3 tablespoons of flaxseed oil""", 56, 477, 550, 28)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")

$hHelpButton = GUICtrlCreateButton("Help", 272, 534, 75, 25)
$hContinueButton = GUICtrlCreateButton("Continue", 382, 534, 75, 25, $BS_DEFPUSHBUTTON)
$hExitButton = GUICtrlCreateButton("Exit Program", 488, 534, 75, 25)
GUICtrlSetState($hCondition, $GUI_FOCUS) ; Set the focus to the "Condition" input box
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $hRadio1
GUICtrlSetState($hChooseInputFile, $GUI_DISABLE)
Case $hRadio2
GUICtrlSetState($hChooseInputFile, $GUI_ENABLE)
Case $hRadio3
GUICtrlSetState($hChooseOutputFile, $GUI_ENABLE)
Case $hRadio4
GUICtrlSetState($hChooseOutputFile, $GUI_DISABLE)
Case $hChooseInputFile
$sTemp = FileOpenDialog("Choose input file", @ScriptDir & "\", "All files (*.*)", 1 + 2)
If $sTemp Then
$sInputFileName = $sTemp
$hInputFileName = GUICtrlSetData($hInputFileName, $sInputFileName & " ")
EndIf
GUICtrlSetState($hCondition, $GUI_FOCUS) ; Return focus to the "Continue" button
Case $hChooseOutputFile
$sTemp = FileOpenDialog("Choose output file", @ScriptDir & "\", "All files (*.*)", 2 + 8)
If $sTemp Then
$sOutputFileName = $sTemp
$hOutputFileName = GUICtrlSetData($hOutputFileName, $sOutputFileName & " ")
EndIf
GUICtrlSetState($hCondition, $GUI_FOCUS) ; Return focus to the "Continue" button
Case $hHelpButton
ShellExecute("http://www.astrocyte-design.com/reaction-time/index.html")
Case $hContinueButton
ExitLoop
Case $hExitButton
Exit
EndSwitch
WEnd
If (BitAND(GUICtrlRead($hRadio1), $GUI_CHECKED) = $GUI_CHECKED) Then
$sSourceOfProblems = "SourceCode"
Else
$sSourceOfProblems = "InputFile"
EndIf
$iNumberOfProblems = GUICtrlRead($hTrialsPerSession)
$iMinTime = GUICtrlRead($hTime1)
$iMaxTime = GUICtrlRead($hTime2)
If (BitAND(GUICtrlRead($hRadio3), $GUI_CHECKED) = $GUI_CHECKED) Then
$sOutputType = "WriteToFile"
Else
$sOutputType = "DisplayOnly"
EndIf
$sCondition = GUICtrlRead($hCondition)
$sCondition = StringReplace($sCondition, ",", "") ; Remove any commas that the user happens to enter (they interfere with the CSV file format)
GUIDelete($hSetParametersForm)
EndFunc ;==>_ConfirmParametersWithUser

[JLogan3o13]

The problem is due to you redefining your variable. In this section:

Case $hChooseInputFile
$sTemp = FileOpenDialog("Choose input file", @ScriptDir & "", "All files (*.*)", 1 + 2)
If $sTemp Then
$sInputFileName = $sTemp
$hInputFileName = GUICtrlSetData($hInputFileName, $sInputFileName & " ")
EndIf
GUICtrlSetState($hCondition, $GUI_FOCUS) ; Return focus to the "Continue" button

you don't need to say $hInputFileName = GUICtrlSetData($hInputFileName, $sInputFileName & " "). Instead, just set the data:

Case $hChooseInputFile
$sTemp = FileOpenDialog("Choose input file", @ScriptDir & "", "All files (*.*)", 1 + 2)
 If $sTemp Then
  $sInputFileName = $sTemp
  GUICtrlSetData($hInputFileName, $sInputFileName & " ")
 EndIf
GUICtrlSetState($hCondition, $GUI_FOCUS) ; Return focus to the "Continue" button

[AlexChernavsky]

Thank you, JLogan3o13. I think that did the trick. I appreciate your help.

[JLogan3o13]

Glad to be of service