_SingletonHWID() - Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.

[guinness]

Similar to other functions around the Forum, this uses _WinAPI_UniqueHardwareID instead to create a unique id based on the user's hardware.

If you're familiar with _Singleton or _SingletonPID, then you will understand how this works.

Function:

expandcollapse popup

#include <APIDiagConstants.au3>
#include <StringConstants.au3>
#include <WinAPIDiag.au3>

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonHWID
; Description ...: Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.
; Syntax ........: _SingletonHWID($sINIFilePath[, $iFlag = 0])
; Parameters ....: $sINIFilePath        - Filepath of the INI file to store the unique id.
;                  $iFlag               - [optional] Optional parameters. Default is 0.
;                  0 - Exit the script with the exit code -1 if another instance already exists.
;                  1 - Return the PID of the main executable and without exiting the script too.
; Return values .: Success - 0 No other process is running.
;                  Failure - The PID of the main executable.
; Author ........: guinness with initial ideas by Valik for _Singleton & KaFu for _EnforceSingleInstance.
; Remarks .......: Requires WinAPIEx.au3 & APIConstants.au3.
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonHWID($sINIFilePath, $iFlag = 0)
    Local $sOccurenceName = IniRead($sINIFilePath, '_SingletonID_', 'GUID', Default)
    If $sOccurenceName = Default Then
        $sOccurenceName = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD))
        IniWrite($sINIFilePath, '_SingletonID_', 'GUID', $sOccurenceName)
    EndIf
    Local $iExtension = StringInStr($sINIFilePath, '.', Default, -1) - 1, _
            $sUniqueName = $sINIFilePath
    If $iExtension Then
        $sUniqueName = StringLeft($sUniqueName, $iExtension)
    EndIf
    Local $iBackslash = StringInStr($sUniqueName, '\', Default, -1)
    If $iExtension Then
        $sUniqueName = StringTrimLeft($sUniqueName, $iBackslash)
    EndIf
    $sOccurenceName &= '_' & $sUniqueName

    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        AutoItWinSetTitle($sOccurenceName & @AutoItPID)
        $hAutoItWnd = WinGetHandle($sOccurenceName & @AutoItPID)
        AutoItWinSetTitle($sOccurenceName)

        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|SINGLETON_HWID:' & @AutoItPID & @CRLF)
    Else
        If $iFlag = Default Then $iFlag = 0
        If BitAND($iFlag, 1) Then ; $SINGLETON_HWID
            $iReturn = Int(StringRegExp(ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                    '|SINGLETON_HWID:0' & @CRLF, _
                    '\|SINGLETON_HWID:(\d+)\R', $STR_REGEXPARRAYGLOBALMATCH)[0])
        Else
            Exit -1
        EndIf
    EndIf
    Return $iReturn
EndFunc   ;==>_SingletonHWID

Example use of Function:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    If @Compiled Then
        Local $iSingleton = _SingletonHWID('myUniqueName', 1)
        If Not $iSingleton Then
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'This is the first instance of the program running: ' & $iSingleton)
        Else
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'There is another instance running. This PID is: ' & $iSingleton)
        EndIf
    Else
        MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'Please compile the code and run the executable twice to see the two different messages.')
    EndIf
EndFunc   ;==>Example

Another approach >> Edited July 24, 2014 by guinness

[JScript]

The idea is great, but I realized that having two or more different programs using your UDF, even if filenames ($sINIFilePath) is different, the numbering will be the same!

In case of a program A is running, when opening the program B will return me that B already running!

Edit:

Download example: _SingletonHWID_Example.zip

JS

Edited December 14, 2012 by JScript

[guinness]

The idea is great, but I realized that having two or more different programs using your UDF, even if filenames ($sINIFilePath) is different, the numbering will be the same!

In case of a program A is running, when opening the program B will return me that B already running!

Of course, this is also the same for _Singleton too. The idea for this snippet was just to create a very unique occurrence name, so instead of 'myProg' you have a MD5 hash of the user's system.

[JScript]

Of course, this is also the same for _Singleton too. The idea for this snippet was just to create a very unique occurrence name, so instead of 'myProg' you have a MD5 hash of the user's system.

I completely disagree! Run the example below, both files "ProgA" and "ProgB" and see that work independently!

Download example: _SingleTon_Example.zip

Image:

JS

[JScript]

Here is the same test using your UDF:

JS

[guinness]

Yeh that is correct as the occurrence name is exactly the same, the INI file is just to store the MD5 hash so it doesn't have to be created every time. Changing the INI has no affect on the 'occurrence name.'

Plus, ProgA and ProgB are two different programs. If you change _Singleton('ProgB') to _Singleton('ProgA') then you will see the same outcome as my version.

[JScript]

I think you misunderstand!

What I meant is that the UDF "_SingleTon ()" allows multiple programs open at once, each one monitoring a recurrence of the same.

But with your UDF you can not use more than one program at the same time!

JS

Edited December 15, 2012 by JScript

[guinness]

Yes you can if $iFlag is set to 1. You can have 100 programs running with this function, by 99 will report that there is a program already running.

[JScript]

Yes you can if $iFlag is set to 1. You can have 100 programs running with this function, by 99 will report that there is a program already running.

Whatever it is set to 0, 1 or 2!

The program "B" will only report another occurrence if really the same program is opened again!

JS

[guinness]

If it is set 0 it will Exit the application if another instance is running, so there is difference with that flag. I'm not understanding your problem with the function?

[guinness]

What if you use this, is this what you expect now when running ProgB?

$sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & StringLeft(@ScriptName, StringInStr(@ScriptName, '.', 2, -1) - 1)

[JScript]

What if you use this, is this what you expect now when running ProgB?

$sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & StringLeft(@ScriptName, StringInStr(@ScriptName, '.', 2, -1) - 1)

Perfect, this is expected not only for myself, but anyone who wants to open more than one program using your UDF!

JS

[guinness]

But that isn't the point of the function, this is to be used for one application where you want the use of _Singleton and a unique id that is tied to the system. If you want that then _Singleton or _SingletonPID is a better option.

[JScript]

Let us suppose that I have 4 programs that use your UDF:

1-DVI-Remote.exe

2-Netsend.exe

3-CaptureIt.exe

4-WaterMark.exe

In the original form of the UDF, if I run the "DVI-Remote.exe" I will not be able to open any of the other programs!

After this change:

$ = sGUID _WinAPI_UniqueHardwareID (BITOR ($ UHID_MB, UHID_BIOS $, $ UHID_HDD)) & StringLeft (@ ScriptName, StringInStr (ScriptName @, '.', 2, -1) - 1)

I can open all at the same time without any problems, which will be reported only other occurrence was open if for example I try to run "DVI-Remote.exe" again!

Without this change I do not see any sense to use the UDF in its original form, because I am unable to open any other program that use the UDF!

In any case, in my opinion with the changes you posted makes perfect sense to use the UDF!

JS

[guinness]

OK, I will update it but it was never intended to be used by multiple programs.

Edited December 15, 2012 by guinness

[guinness]

Updated the function. Now it's the following >>

{Unique_Hardware_MD5Hash}_INIFileName e.g. {AC2F9AC8-46B4-11E2-AE88-609DFEA9A379}_Settings

[JScript]

Thank you!

JS

[guinness]

Thank you!

JS

You're welcome.

[TheSaint]

@guiness - Thanks for sharing.

I can see potential with your original script, where perhaps I distribute a few programs that have the potential of a conflict or some kind of sharing violation. Employing your script for each of my programs, would mean that only one would ever be allowed to run at the same time.

What I would suggest though, is the inclusion of some kind of signature for each program creator, so that I could run a program from Creator 1 (czardas) and Creator 2 (JohnOne) at the same time, but not more than one by each obviously.

In other words, before compiling for distribution, the necessity for an author signature line in the script?

This would also give the potential for an author to use more than one signature to overcome the issue JScript initially complained of.

EDIT

Before anyone mentions it, YES I know using the regular _Singleton can achieve much of the above. Obviously this would be an alternative ... for whatever reason.

Edited December 16, 2012 by TheSaint

[nullschritt]

@guiness - Thanks for sharing.

I can see potential with your original script, where perhaps I distribute a few programs that have the potential of a conflict or some kind of sharing violation. Employing your script for each of my programs, would mean that only one would ever be allowed to run at the same time.

What I would suggest though, is the inclusion of some kind of signature for each program creator, so that I could run a program from Creator 1 (czardas) and Creator 2 (JohnOne) at the same time, but not more than one by each obviously.

In other words, before compiling for distribution, the necessity for an author signature line in the script?

This would also give the potential for an author to use more than one signature to overcome the issue JScript initially complained of.

func _winapi_hwid($mutex)
$sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & StringLeft(@ScriptName, StringInStr(@ScriptName, '.', 2, -1) - 1)
$sGUID = _Crypt_encryptdata($sGUID, $mutex, $CALG_RC4)
return $sGUID
endfunc

tada

$mutex = author name, or any string.

Edited December 16, 2012 by nullschritt