_SingletonHWID() - Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.

guinness · December 16, 2012

@guiness - Thanks for sharing.
I can see potential with your original script, where perhaps I distribute a few programs that have the potential of a conflict or some kind of sharing violation. Employing your script for each of my programs, would mean that only one would ever be allowed to run at the same time.
What I would suggest though, is the inclusion of some kind of signature for each program creator, so that I could run a program from Creator 1 (czardas) and Creator 2 (JohnOne) at the same time, but not more than one by each obviously.
In other words, before compiling for distribution, the necessity for an author signature line in the script?
This would also give the potential for an author to use more than one signature to overcome the issue JScript initially complained of.
EDIT
Before anyone mentions it, YES I know using the regular _Singleton can achieve much of the above. Obviously this would be an alternative ... for whatever reason.

Changing the INI filename to the author is an option.

guinness · December 16, 2012

My original idea for this function was one application per system, but overtime this function has changed to what was my original design idea.

guinness · December 16, 2012

TheSaint,

What about this?

Function:

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonHWID
; Description ...: Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.
; Syntax ........: _SingletonHWID([$sOccurenceName = Default[, $iFlag = 0[, $hGUI = Default]]])
; Parameters ....: $sOccurenceName      - [optional] String to identify the occurrence of the script with the unique id. Default is Blank.
;                                         If this is left blank then the unqiue hardware id is use.
;                  $iFlag               - [optional] Optional parameters. Default is 0.
;                  -1 - Set the $hGUI parameter to be used later by other applications that call _SingletonHWID.
;                  0 - Exit the script with the exit code -1 if another instance already exists.
;                  1 - Return the PID of the main executable and without exiting the script too.
;                  2 - Return the hWnd of the main executable and without exiting the script too.
;                  $hGUI                - [optional] A valid GUI handle. Default is 0x0000000000000000 (no handle.)
; Return values .: Success - 0 No other process is running.
;                  Failure - The PID or hWnd of the main executable. See flags for return type.
; Author ........: guinness with initial ideas by Valik for _Singleton & KaFu for _EnforceSingleInstance.
; Remarks .......: Requires WinAPIEx.au3 & APIConstants.au3.
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonHWID($sOccurenceName = Default, $iFlag = 0, $hGUI = Default)
    If $iFlag = Default Then
        $iFlag = 0
    EndIf
    If $sOccurenceName = Default Then
        $sOccurenceName = ''
    EndIf
    Local $sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & '_' & StringStripWS($sOccurenceName, 8)
    Local $hWnd = WinGetHandle($sGUID)
    If @error Then
        AutoItWinSetTitle($sGUID)
        $hWnd = WinGetHandle($sGUID)
        If IsHWnd($hGUI) = 0 Then
            $hGUI = '0x0000000000000000'
        EndIf
        ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & @AutoItPID & '|hWnd:' & $hGUI)
    Else
        Local $sData = ControlGetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'))
        If $sData = '' Then
            $sData = 'PID:' & @AutoItPID & '|hWnd:0x0000000000000000'
        EndIf
        Local $aSRE = StringRegExp($sData, 'PID:(\d+)|hWnd:(0x[[:xdigit:]]+)', 3)
        $aSRE[0] = Int($aSRE[0])
        If $iFlag = -1 And IsHWnd($hGUI) And ($aSRE[0] = @AutoItPID) Then
            ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & $aSRE[0] & '|hWnd:' & $hGUI)
            Return -2
        EndIf
        If Not ($aSRE[0] = @AutoItPID) Then
            If BitAND($iFlag, 1) Then
                Return $aSRE[0] ; Return PID when $iFlag is 1.
            ElseIf BitAND($iFlag, 2) Then
                Return HWnd($aSRE[1]) ; Return hWnd when $iFlag is 2.
            EndIf
            Exit -1
        EndIf
    EndIf
    Return 0
EndFunc   ;==>_SingletonHWID

Example 1:

#include <APIDiagConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIDiag.au3>

; Use the HWID id of the user's system and return the hWnd set previously.
Local $hSingleton = _SingletonHWID(Default, 2)

If $CmdLine[0] = 0 Then
    If @Compiled Then
        Run(@ScriptFullPath & ' /OneInstance', @WorkingDir)
    Else
        Run(@AutoItExe & ' "' & @ScriptFullPath & '" /OneInstance', @WorkingDir)
    EndIf
EndIf

If $hSingleton = 0 Then
    Example()
Else
    MsgBox($MB_SYSTEMMODAL, '', 'There is another instance running. The hWnd of the first instance is: ' & $hSingleton & @CRLF & _
            'The window will now minimise once this MsgBox has been closed.')
    WinSetState($hSingleton, '', @SW_MINIMIZE)
EndIf

Func Example()
    Local $hGUI = GUICreate('', 400, 300)
    Local $iClose = GUICtrlCreateButton('Close', 310, 265, 85, 30)
    GUISetState(@SW_SHOW, $hGUI)

    WinSetTitle($hGUI, '', 'PID: ' & @AutoItPID & ', hWnd: ' & $hGUI)

    ; Set the handle returned by GUICreate to be used by other applications that call _SingletonHWID.
    _SingletonHWID(Default, -1, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

Example 2:

#include <APIDiagConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIDiag.au3>

; Use the HWID id of the user's system and return the hWnd set previously.
Local $hSingleton = _SingletonHWID(Default, 2)

If $CmdLine[0] = 0 Then
    If @Compiled Then
        Run(@ScriptFullPath & ' /OneInstance', @WorkingDir)
    Else
        Run(@AutoItExe & ' "' & @ScriptFullPath & '" /OneInstance', @WorkingDir)
    EndIf
EndIf

If $hSingleton = 0 Then
    Example()
Else
    MsgBox($MB_SYSTEMMODAL, '', 'There is another instance running. The hWnd of the first instance is: ' & $hSingleton & @CRLF & _
            'The window will now bounce once this MsgBox has been closed.')
    _BounceWindow($hSingleton)
EndIf

Func Example()
    Local $hGUI = GUICreate('', 400, 300)
    Local $iClose = GUICtrlCreateButton('Close', 310, 265, 85, 30)
    GUISetState(@SW_SHOW, $hGUI)

    WinSetTitle($hGUI, '', 'PID: ' & @AutoItPID & ', hWnd: ' & $hGUI)

    ; Set the handle returned by GUICreate to be used by other applications that call _SingletonHWID.
    _SingletonHWID(Default, -1, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

; guinness - 2012
Func _BounceWindow($hWnd)
    Local $aWinGetPos = WinGetPos($hWnd)
    Local $iCount = 0, $iTaskbarSize = 0

    For $iCount = 0 To 1024
        Sleep(10)
        $aWinGetPos[1] += $iCount
        If $aWinGetPos[1] >= @DesktopHeight - $aWinGetPos[3] - $iTaskbarSize Then
            ExitLoop
        EndIf
        WinMove($hWnd, '', $aWinGetPos[0], $aWinGetPos[1])
    Next
    If $iCount <= 1 Then
        Return SetError(1, 0, 0)
    EndIf
    WinMove($hWnd, '', $aWinGetPos[0], @DesktopHeight - $aWinGetPos[3] - $iTaskbarSize)
    For $iCount = $iCount To 0 Step -1
        Sleep(10)
        $aWinGetPos[1] -= $iCount
        WinMove($hWnd, '', $aWinGetPos[0], $aWinGetPos[1])
    Next
    WinMove($hWnd, '', $aWinGetPos[0], $aWinGetPos[1])
EndFunc   ;==>_BounceWindow

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonHWID
; Description ...: Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.
; Syntax ........: _SingletonHWID([$sOccurenceName = Default[, $iFlag = 0[, $hGUI = Default]]])
; Parameters ....: $sOccurenceName      - [optional] String to identify the occurrence of the script with the unique id. Default is Blank.
;                                         If this is left blank then the unqiue hardware id is use.
;                  $iFlag               - [optional] Optional parameters. Default is 0.
;                  -1 - Set the $hGUI parameter to be used later by other applications that call _SingletonHWID.
;                  0 - Exit the script with the exit code -1 if another instance already exists.
;                  1 - Return the PID of the main executable and without exiting the script too.
;                  2 - Return the hWnd of the main executable and without exiting the script too.
;                  $hGUI                - [optional] A valid GUI handle. Default is 0x0000000000000000 (no handle.)
; Return values .: Success - 0 No other process is running.
;                  Failure - The PID or hWnd of the main executable. See flags for return type.
; Author ........: guinness with initial ideas by Valik for _Singleton & KaFu for _EnforceSingleInstance.
; Remarks .......: Requires WinAPIEx.au3 & APIConstants.au3.
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonHWID($sOccurenceName = Default, $iFlag = 0, $hGUI = Default)
    If $iFlag = Default Then
        $iFlag = 0
    EndIf
    If $sOccurenceName = Default Then
        $sOccurenceName = ''
    EndIf
    Local $sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & '_' & StringStripWS($sOccurenceName, 8)
    Local $hWnd = WinGetHandle($sGUID)
    If @error Then
        AutoItWinSetTitle($sGUID)
        $hWnd = WinGetHandle($sGUID)
        If IsHWnd($hGUI) = 0 Then
            $hGUI = '0x0000000000000000'
        EndIf
        ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & @AutoItPID & '|hWnd:' & $hGUI)
    Else
        Local $sData = ControlGetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'))
        If $sData = '' Then
            $sData = 'PID:' & @AutoItPID & '|hWnd:0x0000000000000000'
        EndIf
        Local $aSRE = StringRegExp($sData, 'PID:(\d+)|hWnd:(0x[[:xdigit:]]+)', 3)
        $aSRE[0] = Int($aSRE[0])
        If $iFlag = -1 And IsHWnd($hGUI) And ($aSRE[0] = @AutoItPID) Then
            ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & $aSRE[0] & '|hWnd:' & $hGUI)
            Return -2
        EndIf
        If Not ($aSRE[0] = @AutoItPID) Then
            If BitAND($iFlag, 1) Then
                Return $aSRE[0] ; Return PID when $iFlag is 1.
            ElseIf BitAND($iFlag, 2) Then
                Return HWnd($aSRE[1]) ; Return hWnd when $iFlag is 2.
            EndIf
            Exit -1
        EndIf
    EndIf
    Return 0
EndFunc   ;==>_SingletonHWID

Edited April 23, 2014 by guinness

TheSaint · December 17, 2012

That's one way to do it, though my suggestion was to combine the unique hardware ID with your occurrence name in some manner, but I guess either or is fine.

The only possible issue with just using an occurrence name, is that it is much the same as just using _Singleton, and is dependent on a unique set of characters, that someone else might also use, but chances are probably very unlikely if one is careful enough.

For instance, when I use _Singleton, I always split my program name up with dashes and finish with my alias -->

_Singleton("USB-Safe-Ejector-thsaint")

Extremely unlikely someone else would come up with that.

guinness · December 17, 2012

Updated the previous function example.

TheSaint · December 17, 2012

func _winapi_hwid($mutex)
$sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & StringLeft(@ScriptName, StringInStr(@ScriptName, '.', 2, -1) - 1)
$sGUID = _Crypt_encryptdata($sGUID, $mutex, $CALG_RC4)
return $sGUID
endfunc

tada

$mutex = author name, or any string.

That seems another possibility, but haven't really followed the logic through, and it seems like $mutex is being used as an encryption key? Correct me if I'm wrong.

guinness · December 17, 2012

That seems another possibility, but haven't really followed the logic through, and it seems like $mutex is being used as an encryption key? Correct me if I'm wrong.

It's another unique approach, but that's just my 2cents!

GUID: {AC2F9AC8-46B4-11E2-AE88-609DFEA9A379}myProg
Username: guinness
Output: 0xF60796A600633AE63F3659983B769882EA436A5C5EDA2D4BBC1268E2F5C4CCD3F35B1BBBB7ED5103B7E95847

TheSaint · December 17, 2012

Updated the previous function example.

Hadn't noticed that before my last post here before logging off last night.

Very good!

Elegantly simple!

guinness · December 17, 2012

Hadn't noticed that before my last post here before logging off last night.
Very good!
Elegantly simple!

You're welcome.

TheSaint · December 17, 2012

You know what would be nice?

Instead of the regular _Singleton or your HWID version just preventing another copy running, if it also brought to the foreground/made active the first instance.

Because, usually the reason people (accidentally) attempt to run a program more than once, is because they may have forgot it was running already ... possibly buried behind other Windows or minimized to the Taskbar &/or Tray area.

Be great if a switch/parameter could be added for this feature.

JScript · December 18, 2012

@guinness

I really enjoyed your UDF, but I modified it for not having the ini file. It works perfectly the way I hoped!

Here is if someone wishes the same way:

#include <APIConstants.au3>
#include <WinAPIEx.au3>

Local $iSingleton = _SingletonHWID('ProgramA', 1)

If $iSingleton = 0 Then
    MsgBox(4096, 'Program A', 'This is the first instance of the program running: ' & $iSingleton)
Else
    MsgBox(4096, 'Program A', 'There is another instance running. This PID is: ' & $iSingleton)
EndIf

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonHWID
; Description ...: Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.
; Syntax ........: _SingletonHWID($sOccurenceName[, $iFlag = 0])
; Parameters ....: $sOccurenceName    - String to identify the occurrence of the script.
;                 $iFlag               - [optional] Optional parameters. Default is 0.
;                  0 - Exit the script with the exit code -1 if another instance already exists.
;                  1 - Return the PID of the main executable and without exiting the script too.
; Return values .: Success - 0 No other process is running.
;                 Failure - The PID of the main executable.
; Author ........: guinness with initial ideas by Valik for _Singleton & KaFu for _EnforceSingleInstance.
; Modified ......: JScript
; Remarks .......: Requires WinAPIEx.au3 & APIConstants.au3.
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonHWID($sOccurenceName, $iFlag = 0)
    Local $sGUID, $iExtension, $sUniqueName, $iBackslash, $avWinList, $hWnd

    $sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & "_" & $sOccurenceName

    $hWnd = WinGetHandle($sGUID)
    If @error Then
        AutoItWinSetTitle($sGUID)
        $hWnd = WinGetHandle($sGUID)
        ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), @AutoItPID)
    Else
        If BitAND($iFlag, 1) Then
            Return Number(ControlGetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1')))
        Else
            Exit -1
        EndIf
    EndIf
    Return 0
EndFunc   ;==>_SingletonHWID

Regards,

JS

guinness · December 18, 2012

Thanks, but that isn't that the same as in post #23?

Be great if a switch/parameter could be added for this feature.

Pretty trivial to add. I will add something later on today, but it will be a new thread as this is going way and above the intended use of this function. Edited December 18, 2012 by guinness

guinness · December 18, 2012

TheSaint,

See post again. I also updated the example.

TheSaint · December 19, 2012

No worries, thanks.

I'll give it a go, but it looks as though you are minimizing the first instance after calling your function, rather than restoring/making it active via the function (if the right flag is used).

Similar to what I've seen with other programs over the years, where clicking the exe of a program that is already running, just gives it focus, rather than run another instance.

guinness · December 19, 2012

It's an example to show it works. You replace that function with whatever you want. I didn't want to put any activation code in the function and limit its usage.

guinness · December 19, 2012

TheSaint,

See above for a second example to show how it's usage isn't limited. Feel free to edit the function, but I think doing it this way offers more versatility.

TheSaint · December 19, 2012

Fair enough, though I wouldn't have thought having a specific flag to do something like a Restore/Make Active, would be too limiting? One would either specify that flag or not. The whole idea from my point of view, is for a UDF to do standard things to save on User code, while also giving the User the ability to use code for whatever (i.e. Bouncing a Window, etc) if they want.

Be nice to only just have to put ->

#include <_SingletonHWID.au3>
_SingletonHWID("thsaint", 5)

at the beginning of my script. With the '5' representing Restore (Make Active).

Nice, quick and simple.

Edited December 19, 2012 by TheSaint

guinness · December 19, 2012

Feel free to add it, but I think there are too many options to decide what are important.

TheSaint · December 19, 2012

I should probably do that, but I'm not a UDF creating person.

I can see though, that my concept has moved far & away from your original conception.

For starters, I would ~~be using the HWID element on the compiler's machine, not the user's, just to~~ simplify life with the use of _Singleton, creating a unique name & restore with very little effort, other than pasting a snippet like the one exampled by me above. So while related, it's kind of very different to your endgame.

Thanks for the food for thought though, etc.

EDIT

I crossed out that dubious section, as I realized I hadn't really thought it through, and haven't got any time at the moment to figure out what I really meant/want.

Edited December 19, 2012 by TheSaint

guinness · December 20, 2012

Well tell me the options you want e.g. Minimize, Show etc and I will show you how to add it.

Sign In

_SingletonHWID() - Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.

Recommended Posts

guinness

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

guinness

guinness

guinness

guinness

guinness

TheSaint

guinness

TheSaint

guinness

TheSaint

guinness

TheSaint

JScript

guinness

guinness

TheSaint

guinness

guinness

TheSaint

guinness

TheSaint

guinness

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta