Report Help File Issues Here

[Melba23]

Hi,

Someone asked today how to have more than one value in a Switch Case statement. Looking at the examples, I see that all the Cases are of the To type - perhaps we should show the whole range of syntax possibilities. Here is a suggested replacement - can you tell I have just eaten?

Local $msg
Switch @HOUR
    Case 6 To 8
        $msg = "Breakfast"
    Case 13, 14
        $msg = "Lunch"
    Case 16
        $msg = "Tea"
    Case 18, 19
        $msg = "Dinner"
    Case Else
        $msg = "Greedy!"
EndSwitch

M23

[BrewManNH]

Hi,

Someone asked today how to have more than one value in a Switch Case statement. Looking at the examples, I see that all the Cases are of the To type - perhaps we should show the whole range of syntax possibilities. Here is a suggested replacement - can you tell I have just eaten?

M23

Or perhaps something like this.

Local $msg
Switch @HOUR
    Case 6 To 7, 8 to 9
        $msg = "Breakfast"
    Case 13, 14
        $msg = "Lunch"
    Case 16
        $msg = "Tea"
    Case 18, 19
        $msg = "Dinner"
    Case Else
        $msg = "Greedy!"
EndSwitch

Shows that you can have multiple To types on the same line as well.

[AZJIO]

I it seems too offered... Switch

[Melba23]

AZJIO,

Interesting final example.

Do you have a real-world example of when it could be useful - because I am struggling to think of one.

M23

[AZJIO]

Melba23

I changed real option a little. I used it not once.

Switch $GUI_CHECKED
    Case GUICtrlRead($iRadio1)
        $sArgs = " /z"
    Case GUICtrlRead($iRadio2)
        $sArgs = " /v"
    Case GUICtrlRead($iRadio3)
        $sArgs = " /h"
EndSwitch

[Melba23]

AZJIO,

Interesting idea - thank you for showing us.

M23

[jaberwacky]

I have accumulated more typos that I have found in the help file. If you have confusion about the structure of this then let me know.

Edit: The very first thing is either my mistake or has been corrected since I last noticed.

Edit: Also, _ArrayDisplay has the word array twice in the helpfile and the calltip.

Displays given 1D or 2D array array in a listview.

Edited February 24, 2013 by jaberwocky6669

[guinness]

Thanks. I will have a look at these next month.

[jaberwacky]

That will give me time to remove the super anal ones like double spaces between sentences which I have since become lax about.

[guinness]

That will give me time to remove the super anal ones like double spaces between sentences which I have since become lax about.

This is what I expect, don't remove them. Also the help file should use American English for consistency with AutoIt functions. I would love to change color to colour, but alas I can't.

[AZJIO]

Script Editors

Notepad++ need to be added in the list

You can add a button to copy the code in the "GUI Reference - MessageLoop Mode" and in other sections. For example.

#include <FileOperations.au3>
$sKey = '_@#%&'
$sLink = ''
$sPath = @ScriptDir
$aFileList = _FO_FileSearch($sPath, '*.htm*', True, 125, 0)

$iCount = 0
For $i = 1 To $aFileList[0]
    $sText = FileRead($sPath & '\' & $aFileList[$i])
    StringReplace($aFileList[$i], '\', '')
    Switch @extended
        Case 0
            $sLink = 'images/copysmall.gif'
        Case 1
            $sLink = '../images/copysmall.gif'
        Case 2
            $sLink = '../../images/copysmall.gif'
    EndSwitch
    $sText = StringReplace($sText, '<p class="codebox">', '<a href="javascript:ClipBoard(au3_' & $sKey & ');"><IMG title="Копировать в буфер" style="margin: 10px 4px 0px 0px;" src="' & $sLink & '" border="0" align="right"></a>' & @CRLF & '<p id="au3_' & $sKey & '" class="codebox">')
    $iCountRP = @extended
    If Not $iCountRP Then ContinueLoop
    For $j = 1 To $iCountRP
        $sText = StringReplace($sText, $sKey, $j, 2, 2)
    Next
    $iCount += 1
    $sText = StringReplace($sText, '</BODY>', '<textarea ID="holdtext" STYLE="display:none;"></textarea><SCRIPT LANGUAGE="Javascript">function ClipBoard(NumBlok){holdtext.innerText = NumBlok.innerText;Copied = holdtext.createTextRange();Copied.execCommand("Copy");}</SCRIPT></BODY>')
    $hFile = FileOpen($sPath & '\' & $aFileList[$i], 2)
    FileWrite($hFile, $sText)
    FileClose($hFile)
Next
MsgBox(0, 'Yes', 'Count Files = ' & $iCount)

Edited March 7, 2013 by AZJIO

[nitekram]

Can we add to the helpfile for the command/function Send() the work around for sticking keys - maybe a link to the FAQ?

I have seen this issue come up, and as per this is not a bug, but a computer issue and I think it should be mentioned in the place it is first seen - the help file?

[guinness]

Linking to the Wiki isn't recommended and in terms of my stance on adding this, even if it was documented the question would probably still arise.

[nitekram]

Are you saying that it will not be added? If you will not add the link, can you at least post that if you have issue, look in the FAQ?

[guinness]

I just can't understand how this issue is related to the AutoIt help file. Maybe someone else can shed some light on it.

Edit: I should clarify, the way I see it this is a Microsoft issue and thus has no business being in the help file in my humble opinion, but then again there are a couple of us who work on the help file so I'm happy to hear their opinion on the subject.

Edit 2: I appreciate you helping, but as you can probably understand, not everything should or can be added to the help file.

Edited March 9, 2013 by guinness

[Melba23]

guinness,

This problem is a not infrequent question here and, as I indicated in the thread to which nitekram linked, I think it could be worth a line in the Help file:

"In some circumstances Send can cause the modifier (Ctrl-Alt-Shft) keys to remain "stuck down" when they are among the keys sent. This is not an AutoIt bug and some possible remedies can be found in the FAQ in the AutoIt Wiki."

I am not at all hard over on this - you are the guardian of the Help file and I am perfectly ready to accept what you decide.

M23

Edited March 9, 2013 by Melba23
Typo

[Exit]

The examples for _IEDocInsertHTML() are broken for IE10 on Win7.

_IEGetObjByName() does NOT return the object. Using _IEGetObjById() does the job.

Here the modified examples.

I modified the color of the text also, since black on darkblue is nearly invisible. Even without IE10.

expandcollapse popup

; *******************************************************
; Example 1 - Insert HTML at the top and bottom of a document
; *******************************************************

#include <IE.au3>

Local $oIE = _IECreate("http://www.autoitscript.com/")
Local $oBody = _IETagNameGetCollection($oIE, "body", 0)

_IEDocInsertHTML($oBody, '<h2 style="color:Black; background-color:White" >This HTML is inserted after Begin</h2>', "afterbegin")
_IEDocInsertHTML($oBody, '<h2 style="color:Black; background-color:White" >This HTML is inserted before End</h2>', "beforeend")

; *******************************************************
; Example 2 - Open a browser with the basic example page, insert HTML
;        in and around the DIV tag named "IEAu3Data" and display Body HTML
; *******************************************************

#include <IE.au3>

$oIE = _IE_Example("basic")
;Local $oDiv = _IEGetObjByName($oIE, "IEAu3Data")  ; do NOT use _IEGetObjByName() on IE10 !!!
Local $oDiv = _IEGetObjById($oIE, "IEAu3Data")

_IEDocInsertHTML($oDiv, "<br><b>(HTML beforebegin)", "beforebegin")
_IEDocInsertHTML($oDiv, "<i>(HTML afterbegin)", "afterbegin")
_IEDocInsertHTML($oDiv, "<br><b>(HTML beforeend)", "beforeend")
_IEDocInsertHTML($oDiv, "<i>(HTML afterend)", "afterend")

ConsoleWrite(_IEBodyReadHTML($oIE) & @CRLF)

; *******************************************************
; Example 3 - Advanced example
;        Insert a clock and a referrer string at the top of every page, even when you
;        browse to a new location.  Uses _IEDocInsertText, _IEDocInsertHTML and
;        _IEPropertySet features "innerhtml" and "referrer"
; *******************************************************

#include <IE.au3>

$oIE = _IECreate("http://www.autoitscript.com")

AdlibRegister("UpdateClock", 1000) ; Update clock once per second

; idle as long as the browser window exists
While WinExists(_IEPropertyGet($oIE, "hwnd"))
    Sleep(10000)
WEnd

Exit

Func UpdateClock()
    Local $curTime = '<div style="color:Black; background-color:White" ><b>Current Time is: </b>' & @HOUR & ":" & @MIN & ":" & @SEC & "</div>"
    ; _IEGetObjByName is expected to return a NoMatch error after navigation
    ;   (before DIV is inserted), so temporarily turn off notification
    _IEErrorNotify(False)
    ;Local $oAutoItClock = _IEGetObjByName($oIE, "AutoItClock")   ; do NOT use _IEGetObjByName() on IE10 !!!
    Local $oAutoItClock = _IEGetObjById($oIE, "AutoItClock")
    If Not IsObj($oAutoItClock) Then ; Insert DIV element if it wasn't found
        ;
        ; Get reference to BODY, insert DIV, get reference to DIV, update time
        Local $oBody = _IETagNameGetCollection($oIE, "body", 0)
        _IEDocInsertHTML($oBody, "<div id='AutoItClock'></div>", "afterbegin")
        ;$oAutoItClock = _IEGetObjByName($oIE, "AutoItClock")   ; do NOT use _IEGetObjByName() on IE10 !!!
        $oAutoItClock = _IEGetObjById($oIE, "AutoItClock")
        _IEPropertySet($oAutoItClock, "innerhtml", $curTime)
        ;
        ; Check referrer string, if not blank insert after clock
        _IELoadWait($oIE)
        Local $sReferrer = _IEPropertyGet($oIE, "referrer")
        If $sReferrer Then _IEDocInsertText($oAutoItClock, _
                "  Referred by: " & $sReferrer, "afterend")
    Else
        _IEPropertySet($oAutoItClock, "innerhtml", $curTime) ; update time
    EndIf
    _IEErrorNotify(True)
EndFunc   ;==>UpdateClock

There are also other helpfile examples broken, like _IEDocInsertText().

_IEGetObjByName() should be changed to _IEGetObjById() in most cases.

[Exit]

Hotkeyset()

An additional example should include error checking and one function for multiple Hotkeys.

Const $_Stop = 16
Const $_TopMost = 262144
If HotKeySet("{ESC}", "_Hotkey") = 0 Then Exit MsgBox($_Stop+$_TopMost, "Hotkeyset Error", "Hotkey {ESC} already set.")
If HotKeySet("{F1}", "_Hotkey") = 0 Then Exit MsgBox($_Stop+$_TopMost, "Hotkeyset Error", "Hotkey {F1} already set.")
Func _Hotkey()
    Switch @HotKeyPressed
        Case "{ESC}"
            Exit MsgBox($_TopMost, "Hotkey()", "Exit", 0)
        Case "{F1}"
            ShellExecute("http://www.autoitscript.com/autoit3/docs/functions/HotKeySet.htm")
    EndSwitch
EndFunc   ;==>_Hotkey

While Sleep(999999)
WEnd

Edited March 18, 2013 by Exit

[guinness]

Thanks Exit. Would you mind replacing the MsgBox values with constant variables and then I will update. Thanks.

[AZJIO]

Number

exponential numbers are supported.