how to align text in listbox

[coolcurrent]

i need to align text in a listbox like the image in this post, does anyone know of any way to achieve this?

[water]

Welcome to AutoIt and the forum!

Use a ListView. That makes aligning much easier. Check the GuiListView UDF and function _GUICtrlListView_SetColumn for alignment.

Edited November 16, 2012 by water

[AZJIO]

listbox

#include <ListBoxConstants.au3>
#NoTrayIcon

GUICreate("List", 360, 175)
$StatusBar = GUICtrlCreateLabel('StatusBar', 5, 175 - 25, 150, 24)
GUICtrlSetFont(-1, 13)
$iCombo = GUICtrlCreateList("", 10, 5, 340, 100, $GUI_SS_DEFAULT_LIST + $LBS_NOINTEGRALHEIGHT)
GUICtrlSetFont(-1, Default, 400, 0, 'Lucida Console')
_ComboBox_SetDrive($iCombo, 'd')
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $iCombo
            GUICtrlSetData($StatusBar, 'Selecting a disk: ' & StringLeft(GUICtrlRead($iCombo), 1))
        Case -3
            ExitLoop
    EndSwitch
WEnd

Func _ComboBox_SetDrive($i_ID_Combo, $SelectDrive = 'C')
    Local $aDrives = DriveGetDrive('all'), $Current, $Type, $i, $list = '', $sString
    For $i = 1 To $aDrives[0]
        $Type = DriveGetType($aDrives[$i] & '')

        If $aDrives[$i] = 'A:' Or  $Type = 'CDROM' Then ContinueLoop
        If $Type = 'Removable' Then $Type = 'Rem'
        $sLabel = DriveGetLabel($aDrives[$i] & '')
        If StringLen($sLabel)>15 Then $sLabel = StringLeft($sLabel, 12) & '...'

        $sString = StringFormat("%-2s %-5s %-15s %-5s %9.03f Gb", StringUpper($aDrives[$i]), $Type, $sLabel, DriveGetFileSystem($aDrives[$i] & ''), DriveSpaceTotal($aDrives[$i] & '') / 1024)
        $list &= '|' & $sString
        If $aDrives[$i] = $SelectDrive & ':' Then $Current = $sString
    Next
    GUICtrlSetData($i_ID_Combo, $list, $Current)
EndFunc

ComboBox

expandcollapse popup

#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#NoTrayIcon

GUICreate("List", 160, 75)
$StatusBar = GUICtrlCreateLabel('StatusBar', 5, 75 - 25, 150, 24)
GUICtrlSetFont(-1, 13)
$iCombo = GUICtrlCreateCombo('', 10, 5, 50, 23, $CBS_DROPDOWNLIST + $WS_VSCROLL)
_GUICtrlComboBox_SetDroppedWidth($iCombo, 340)
GUICtrlSetFont(-1, Default, 400, 0, 'Lucida Console')
_ComboBox_SetDrive($iCombo, 'd')
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $iCombo
            GUICtrlSetData($StatusBar, 'Selecting a disk: ' & StringLeft(GUICtrlRead($iCombo), 1))
        Case -3
            ExitLoop
    EndSwitch
WEnd

Func _ComboBox_SetDrive($i_ID_Combo, $SelectDrive = 'C')
    Local $aDrives = DriveGetDrive('all'), $Current, $Type, $i, $list = '', $sString
    For $i = 1 To $aDrives[0]
        $Type = DriveGetType($aDrives[$i] & '')

        If $aDrives[$i] = 'A:' Or  $Type = 'CDROM' Then ContinueLoop
        If $Type = 'Removable' Then $Type = 'Rem'
        $sLabel = DriveGetLabel($aDrives[$i] & '')
        If StringLen($sLabel)>15 Then $sLabel = StringLeft($sLabel, 12) & '...'

        $sString = StringFormat("%-2s %-5s %-15s %-5s %9.03f Gb", StringUpper($aDrives[$i]), $Type, $sLabel, DriveGetFileSystem($aDrives[$i] & ''), DriveSpaceTotal($aDrives[$i] & '') / 1024)
        $list &= '|' & $sString
        If $aDrives[$i] = $SelectDrive & ':' Then $Current = $sString
    Next
    GUICtrlSetData($i_ID_Combo, $list, $Current)
EndFunc

[coolcurrent]

AZJIO thanks,

this is what i got, but i wanted the last text to be aligned right to the end of the listbox, which code part do i tweak. The StringFormat Function? This is what i got