Deleting Array Elements within an loop

[billthecreator]

When using For..To..Next loop to delete an array element, it fails because of the size decrease.

When using For..In..Next, The delete function doesn't even work.

I have an array that contains some blank elements. It's also a 2D array.

I need to delete those blank elements, how can I do so using a loop, or any other method?

Thank you

[czardas]

Use this loop:

For $i = Ubound($aArray) -1 To 1 Step -1
    _ArrayDelete($aArray, $i)
Next

[billthecreator]

Thank you so much!

Worked, never thought of that. Will remember

[czardas]

No problem!

[guinness]

Could you provide an example of said array please, if you don't want to use _ArrayDelete.

Edited November 13, 2012 by guinness

[czardas]

I think what guiness is referring to are speed issues associated with the function _ArrayDelete. There may be faster alternatives. If your array is very large it could take a long time using _ArrayDelete.

Edited November 13, 2012 by czardas

[guinness]

I think what guinness is referring to are speed issues associated with the function _ArrayDelete. There may be faster alternatives. If your array is very large it could take a long time using _ArrayDelete.

Exactly.

[rudi]

Hi.

Pls. let me jump in with an associated "addon" question:

So far I just worked with pretty small arrays, so the speed wasn't an issue so far.

What are alternatives to _arraydelete(), in case I should run into the need of huge arrays? Introduce an extra dimension to "flag" array entries as "marked for deletion", instead of deleting them?

Regards, Rudi.

[BrewManNH]

I create a temporary array that is as large as the array to be checked, if the entry isn't going to be deleted, it gets added to the temp array and I have a variable that keeps track of the count of non-deleted items. Once I've cycled through the array and found everything I want to keep, I ReDim the temp array to the count variable, and then if needed I copy the temp array to the original array. This way you're only redimming the array once and doing an array to array copy is quick.

$OriginalArray = $tempArray copies one array to another.

[water]

That depends on what you need to do with the array after the entries have been deleted.

A flag or setting an existing entry a value that denotes that the entry is to be bypassed could be a solution.

So: It depends

[guinness]

This is how I would do it >>

expandcollapse popup

#include <Array.au3> ; Only for _ArrayDisplay

Example()

Func Example()
    Local $aArray = __ArrayFill(1, True) ; 1d Array
    For $i = 1 To $aArray[0]
        $fRemove = Random(0, 1, 1) = 1 ; Create random blank elements inside the Array.
        If $fRemove Then
            $aArray[$i] = ''
        EndIf
    Next
    ; _ArrayDisplay($aArray) ; Show the 1d Array with blank elements.

    Local $aReturn[$aArray[0] + 1] ; Create an Array the same size as the original.
    For $i = 1 To $aArray[0] ; Loop through the original Array.
        If StringStripWS($aArray[$i], 8) = '' Then ; Strip whitespace to see if the element is blank.
            ContinueLoop ; If it is, then continue looping through the original Array.
        EndIf
        ; Otherwise...
        $aReturn[0] += 1 ; Add 1 to the 0th index.
        $aReturn[$aReturn[0]] = $aArray[$i] ; Add the data to the next available index using the 0th index as reference.
    Next

    $aArray = 0 ; Destroy the original Array.
    ReDim $aReturn[$aReturn[0] + 1] ; ReDim to remove blank elements. Total count + one for the 0th index.
    _ArrayDisplay($aReturn) ; Show the 1d Array without blank elements.
EndFunc   ;==>Example

Func __ArrayFill($iType, $fIsIndexCount = Default)
    Local $iRows = Random(2, 1000, 1)
    If $fIsIndexCount = Default Then
        $fIsIndexCount = True
    EndIf
    Switch $iType
        Case 2
            Local $iCols = Random(2, 25, 1)
            Local $aReturn[$iRows][$iCols]
            For $i = 0 To $iRows - 1
                For $j = 0 To $iCols - 1
                    $aReturn[$i][$j] = 'Row ' & $i & ': Col ' & $j
                Next
            Next
            If $fIsIndexCount Then
                For $i = 0 To $iCols - 1
                    $aReturn[0][$i] = ''
                Next
                $aReturn[0][0] = $iRows - 1
            EndIf
        Case Else
            Local $aReturn[$iRows]
            For $i = 0 To $iRows - 1
                $aReturn[$i] = 'Row ' & $i
            Next
            If $fIsIndexCount Then
                $aReturn[0] = $iRows - 1
            EndIf
    EndSwitch
    Return $aReturn
EndFunc   ;==>__ArrayFill

[water]

I think it highly depends on what the jumped on user (rudi) needs to do with the array.

If he wants to write it to a file it is enough to ignore the "deleted" elements. No need to create a second array and copy all "valid" entries.

[rudi]

@all: Thanks to your replies, I've got the information I was looking for. Regards, Rudi.

[guinness]

I think it highly depends on what the jumped on user (rudi) needs to do with the array.

If he wants to write it to a file it is enough to ignore the "deleted" elements. No need to create a second array and copy all "valid" entries.

My code was for the OP.

[VijaySaibola]

On 11/13/2012 at 1:32 AM, czardas said:

Use this loop:

 

 

For $i = Ubound($aArray) -1 To 1 Step -1
    _ArrayDelete($aArray, $i)
Next

Sorry to bring this up again.

Is there any reason why you loop $1 from upper bound only until 1 and not 0 ? Do we not miss the first element of the array?

[jchd]

Depends on if the first entry is a row count or not.