_StringEncrypt Strange Behavior on Different Computers

[swoop]

I have 7 computers in our office, 6 running Windows 7. One running Windows XP.

The exact same script using _StringEncrypt is compiled and run on these computers.

Two out of the six Windows 7 computers return the same encrypted string, no matter what I enter to the function. The others work fine.

On the Win XP computer, the output string is blank.

This is the oddest behavior I've seen and I just can't figure out what might be wrong. Has anyone else encountered this behavior or something similar to it in AutoIt with the encryption or string functions?

Thanks in advance for any insight!

#include <String.au3>

Func _encryption($input)
Local $base_key,$output
$base_key = "hyuief15"
$output = _StringEncrypt(1,$input,$base_key)
Return $output
EndFunc

[JScript]

On the Win XP computer, the output string is blank.

Your code tested on XP:

#include <String.au3>

Local $input = 'MsgBox(4096, "Title", _encryption($input))'

MsgBox(4096, "Title", _encryption($input))

Func _encryption($input)
    Local $base_key, $output
    $base_key = "hyuief15"
    $output = _StringEncrypt(1, $input, $base_key)
    Return $output
EndFunc   ;==>_encryption

JS

Edited October 31, 2012 by JScript

[dany]

On Win 7 64-bit I get the same results as JScript (using his testcase), compiled both 32- and 64-bit. I can't reproduce your problem, sorry...

[guinness]

_StringEncrypt is outdated, therefore try to use the _Crypt_*** functions. Look at using _Crypt_EncryptData instead.

#include <Constants.au3>
#include <Crypt.au3>

Example()

Func Example()
    ; Encrypt text using a generic password.
    Local $sEncrypted = StringEncrypt(True, 'Encrypt this data.', 'securepassword')

    ; Display the encrypted text.
    MsgBox($MB_SYSTEMMODAL, '', $sEncrypted)

    ; Decrypt the encrypted text using the generic password.
    Local $sDecrypted = StringEncrypt(False, $sEncrypted, 'securepassword')

    ; Display the decrypted text.
    MsgBox($MB_SYSTEMMODAL, '', $sDecrypted)
EndFunc   ;==>Example

Func StringEncrypt($fEncrypt, $sData, $sPassword)
    _Crypt_Startup()
    Local $sReturn = ''
    If $fEncrypt Then
        $sReturn = _Crypt_EncryptData($sData, $sPassword, $CALG_RC4)
    Else
        $sReturn = BinaryToString(_Crypt_DecryptData($sData, $sPassword, $CALG_RC4))
    EndIf
    _Crypt_Shutdown()
    Return $sReturn
EndFunc   ;==>StringEncrypt

Edited May 24, 2013 by guinness

[LWC]

I've fixed Binary($sData) to be $sData = Binary($sData).

Also added support for empty values:

 

#include <Crypt.au3>

Example()

Func Example()
    ; Encrypt text using a generic password.
    Local $sEncrypted = StringEncrypt(True, 'Encrypt this data.', 'securepassword')

    ; Display the encrypted text.
    MsgBox(4096, '', $sEncrypted)

    ; Decrypt the encrypted text using the generic password.
    Local $sDecrypted = StringEncrypt(False, $sEncrypted, 'securepassword')

    ; Display the decrypted text.
    MsgBox(4096, '', $sDecrypted)
EndFunc   ;==>Example

Func StringEncrypt($fEncrypt, $sData, $sPassword)
    if $sData="" then
        return $sData
    endif

    _Crypt_Startup()
    Local $sReturn = ''
    If $fEncrypt Then
        $sReturn = _Crypt_EncryptData($sData, $sPassword, $CALG_RC4)
    Else
        If IsString($sData) Then
            $sData = Binary($sData)
        EndIf
        $sReturn = BinaryToString(_Crypt_DecryptData($sData, $sPassword, $CALG_RC4))
    EndIf
    _Crypt_Shutdown()
    Return $sReturn
EndFunc   ;==>StringEncrypt

Edited May 24, 2013 by LWC

[guinness]

Thanks. But that line isn't really required, hence why the function still worked.