StringRegExp General Help

[guinness]

@guinness,

You are trying to find the string nested inside function ?

Am I getting it right ?

Correct. I'm improving SciTE Jump's feature of reporting unused functions and decided stripping comments and string literals would result in accurate results. But then I realised about Call and AdLibRegister.

So I discover the functions, append to the top of the script and then strip out the useless content.

Edited March 26, 2013 by guinness

[PhoenixXL]

Execute should be included. Right ? Edited March 26, 2013 by PhoenixXL

[guinness]

Correct.

New version, but I can't understand why the if conditional is being captured?

#include <Array.au3>
#include <Constants.au3>

Local $sData = 'AdlibRegister("_Function_1", 1000)' & @CRLF
$sData &= 'AdlibUnRegister("_Function_2", 1000)' & @CRLF
$sData &= 'Call("_Function_3")' & @CRLF
$sData &= 'DllCall("_Function_ShouldNOTDisplay")' & @CRLF
$sData &= 'GUICtrlRegisterListViewSort($iControl, "_Function_4")' & @CRLF
$sData &= 'TrayItemSetOnEvent("1000", "_Function_5")' & @CRLF
$sData &= 'HotKeySet("^,", "_Function_6")' & @CRLF
$sData &= "TrayItemSetOnEvent(1000, '_Function_7')" & @CRLF
Local $sReturn = ''

$sData = StringStripWS($sData, $STR_STRIPALL) ; Not really required!
Local $aArray = StringRegExp($sData, _
        '\b(?i:Adlib(?:Un)?Register|Call|DllCallbackRegister|Execute|OnAutoItExit(?:Un)?Register)\b' & _
        '(?:\(["''](\w+?)["''])?' & _
        '|\b(?i:GUICtrlRegisterListViewSort|GUICtrlSetOnEvent|GUIRegisterMsg|HotKeySet|TraySetOnEvent|TrayItemSetOnEvent)\b' & _
        '\((?(?="|'').*?["'']|[^,]+?),\h*["''](\w+)["'']', _
        3)
For $i = 0 To UBound($aArray) - 1
    $sReturn &= $aArray[$i] & @CRLF
Next

$aArray = StringSplit(StringTrimRight($sReturn, 2), @CRLF, 1) ; 2 is StringLen(@CRLF)
_ArrayDisplay($aArray)

[PhoenixXL]

Have a look at the second regex

#include <Array.au3>
#include <Constants.au3>

Local $sData = 'AdlibRegister("_Function_1", 1000)' & @CRLF
$sData &= 'AdlibUnRegister("_Function_2", 1000)' & @CRLF
$sData &= 'Call("_Function_3")' & @CRLF
$sData &= 'DllCall("_Function_ShouldNOTDisplay")' & @CRLF
$sData &= 'GUICtrlRegisterListViewSort($iControl, "_Function_4")' & @CRLF
$sData &= 'TrayItemSetOnEvent("1000", "_Function_5")' & @CRLF
$sData &= 'HotKeySet("^,", "_Function_6")' & @CRLF
$sData &= "TrayItemSetOnEvent(1000, '_Function_7')" & @CRLF
Local $sReturn = ''

$sData = StringStripWS($sData, $STR_STRIPALL) ; Not really required!
Local $aArray = StringRegExp($sData, '(?i:Adlib(?:Un)?Register|(?<!\w)Call|DllCallbackRegister|OnAutoItExit(?:Un)?Register)\(["''](\w+)["'']', 3)
_ArrayDisplay($aArray)

$aArray = StringRegExp($sData, '(?i:GUICtrlRegisterListViewSort|GUICtrlSetOnEvent|GUIRegisterMsg|HotKeySet|TraySetOnEvent|TrayItemSetOnEvent)' & _
'\([^,]*,[^\w]+(\w+)', 3)
_ArrayDisplay($aArray)

Edited March 26, 2013 by PhoenixXL

[guinness]

Thanks, that makes sense. Also the problem above your last post appears to be with | (OR).

Edited March 26, 2013 by guinness

[PhoenixXL]

New version, but I can't understand why the if conditional is being captured?

When you concatenate the Regexes, now there are two capturing groups. When the function group is in the second parameter, the first capturing group is blank and hence gives an additional headache

If you don't get what I said, try debugging your combined regex with the flag set to 4

Edited March 26, 2013 by PhoenixXL

[guinness]

Gotcha. It's not a major issue and I can live with it. I also opted for b...b instead of the negative lookbehind.

I honestly think I'm improving in my understanding, which is a good sign.

Edited March 26, 2013 by guinness

[czardas]

@guinness I have been thinking again the syntax you used to escape single quotes, and I'm still wondering if using that particular syntax in a RegExp pattern is the best choice. I believe it is specific to AutoIt and not part of PCRE. I would have been inclined to use the the hex x27 instead, which would ensure the patterns portability to other languages. Perhaps I'm wrong about this.

[PhoenixXL]

Execute function. Have a look at this,

#include <Array.au3>
#include <Constants.au3>

#cs - Possibilities
Function is inside string
Non-Function is inside string
Nesting
Most dangerous - a nested Execute function - limitation
#ce

$sData = 'Execute("_Function_1( $a + 1, _Function_2( _Function_3()), "OtherString()", _Function_4( 1000 + 20 ))")'
$aArray = Execute_GetFuncArray($sData)
_ArrayDisplay( $aArray )

$sData = 'Execute("$a + 1")'
$aArray = Execute_GetFuncArray($sData)
_ArrayDisplay( $aArray )

Func Execute_GetFuncArray($sString)

$sString = StringRegExpReplace($sString, "(?im)^\h*Execute\h*\(\h*([""'])(.*)\1\)\h*$", "\2") ;Get the Execute String

$sString = StringRegExpReplace($sString, "([""']).*?(\1)", '\1\2') ;String Literals

If StringRegExp($sString, "(?i)\bexecute\(") Then Return SetError(1, 0, -1) ;I fear I cannot proceed if there is a nested Execute Function.

Return StringRegExp($sString, "(\w+)\h*\(", 3) ;Logic : After Literals gone, any "(" followed by a word is a function.
EndFunc ;==>Execute_GetFuncArray

Edited March 26, 2013 by PhoenixXL

[jchd]

@czardas,

Can you elaborate a little, as I don't see what you refer to as being specific to AutoIt wrt ' vs x27.

[guinness]

Thanks PhoenixXL for improving the accuracy of parsing an Execute parameter string.

@czardas,

I'm sure both are fine.

[czardas]

@czardas,

Can you elaborate a little, as I don't see what you refer to as being specific to AutoIt wrt ' vs x27.

I was referring to escaping quotes by repeating the character. I thought the syntax might not be universal. I didn't notice it in PCRE specs, but I confess that I still need to study them properly.

$sPattern = '['']'

This might not mean the same thing in another language. If it's a universal convention, or part of RegExp syntax, then I'm mistaken.

@czardas,

I'm sure both are fine.

I agree, but I don't know if it's portable and I would like to know. Edited March 26, 2013 by czardas

[jchd]

But the regexp engines never sees an AutoIt-escaped quote (single or double). Quote escaping is for the AutoIt interpreter layer, like when you do:

ConsoleWrite('O''Brian' & @LF)

[czardas]

But the regexp engines never sees an AutoIt-escaped quote (single or double). Quote escaping is for the AutoIt interpreter layer, like when you do:

ConsoleWrite('O''Brian' & @LF)

Which is exactly what I thought: meaning the pattern is not transferable between languages.

[guinness]

Okay now I get it. Well in this case it doesn't matter because [''] is the same as ['] since it's the characters inside the class.

Edited March 26, 2013 by guinness

[jchd]

Sorry I don't get it. Nothing that SciteJump does is transferable to another language. Well, unless a full load of changes.

[czardas]

I understand that it does not affect SciTEJump. I merely wanted to point out that I personally prefer to stick to reuseable RegExp patterns, not necessarily for use with AutoIt. The pattern would almost certainly fail if you tried to use it with another language.

[guinness]

I understand, but then if you copy something without understanding then it will land you in hot water.

[czardas]

I understand, but then if you copy something without understanding then it will land you in hot water.

I generally make code reusable for myself, not specifically for anyone else. What you have written is good and valid AutoIt, but it is not PCRE.

Edited March 26, 2013 by czardas

[guinness]

It's PCRE in AutoIt.