GUIExtender - Deprecated version

[careca]

Yes, thank you, that makes sense, although im confused, because it works for me, the button is there, i mean,

it hides the listview and the rest under it, then the rest is recreated, maybe its not supposed to work this way.

now my doubt is on the button, and how that works, what it does.

$iThis_Section = _GUIExtender_Section_Start($hGUI, 0, 0)
$Button = _GUIExtender_Section_Action($hGUI, $iThis_Section + 1, "", "", 270, 40, 15, 15, 0, 1)

What means

$iThis_Section + 1

?

Expands/Retracts the next section? Then how come if i add another section that one is retracted too?

[Melba23]

careca,

One major problem I see is that the button is actually in the section you want to retract - how do you intend using it one the section is not visible?

What means

$iThis_Section + 1

?  Expands/Retracts the next section?

Exactly - the index numbers are returned in numerical order - using the "+ 1" means that you can create a button that will operate a section that you have not yet coded.

Explain exactly what you want to have in the GUI and I will code something that does what you want so that you can see how I did it.

M23

[careca]

Ok, let's say i got this code and i want to hide the listview:

#include <GUIConstantsEx.au3>
#include "GUIExtender.au3"
Opt("GUIOnEventMode", 1)
Local $Button, $iThis_Section
$hGUI = GUICreate("Vertical", 300, 270, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

_GUIExtender_Init($hGUI)

$iThis_Section = _GUIExtender_Section_Start($hGUI, 0, 50)
$Button = _GUIExtender_Section_Action($hGUI, $iThis_Section+1, "", "", 50, 75, 175, 15, 0, 1)
_GUIExtender_Section_End($hGUI)

GUICtrlCreateButton('button1', 30, 30)
GUICtrlCreateButton('button2', 130, 30)
GUICtrlCreateGroup("1", 10, 2, 280, 70)
Local $LV = GUICtrlCreateListView("2", 10, 98, 280, 70)
GUICtrlCreateButton('button3', 30, 190)
GUICtrlCreateButton('button4', 130, 190)
GUICtrlCreateGroup("3", 10, 172, 280, 70)

GUISetState()

While 1
    Sleep(100)
WEnd

Func On_Exit()
    Exit
EndFunc

[Melba23]

careca,

This should do it - I have added lots of comments so I hope you can follow:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include "GUIExtender.au3"

Opt("GUIOnEventMode", 1)

Local $Button, $iThis_Section

$hGUI = GUICreate("Vertical", 300, 270, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

_GUIExtender_Init($hGUI)

; Create the first section - we start at the top of the GUI and go down to cover all the required controls
$iThis_Section = _GUIExtender_Section_Start($hGUI, 0, 90)
; All the controls on this section need to be added here
GUICtrlCreateGroup("1", 10, 2, 280, 70)
GUICtrlCreateButton('button1', 30, 30)
GUICtrlCreateButton('button2', 130, 30)
; Including this one to action the retractable section
$Button = _GUIExtender_Section_Action($hGUI, $iThis_Section + 1, "", "", 50, 75, 175, 15, 0, 1)
; You only end the section AFTER ALL the controls have been added
_GUIExtender_Section_End($hGUI)

; Now create the section to retract - note the values of the parameters
; First one is the sum of the Start (0) and Depth (90) parametrs of the section above
; Second is the depth of this section
$iExt_Section = _GUIExtender_Section_Start($hGUI, 90, 80)
; Again the controls in this section are created BEFORE...
Local $LV = GUICtrlCreateListView("2", 10, 98, 280, 70)
; ...we close the section
_GUIExtender_Section_End($hGUI)

; And the parameters of this section follow on and complete the whole GUI - 170 + 100 = 270
_GUIExtender_Section_Start($hGUI, 170, 100)
; Create all the controls...
GUICtrlCreateButton('button3', 30, 190)
GUICtrlCreateButton('button4', 130, 190)
GUICtrlCreateGroup("3", 10, 172, 280, 70)
; ...and close the section
_GUIExtender_Section_End($hGUI)

GUISetState()

While 1
    Sleep(100)
WEnd

Func On_Exit()
    Exit
EndFunc

All clear now?

M23

[careca]

Thank you very much, i will try to do it myself on another gui with different values to see if i get it right, but those comments trully are helpful.

EDIT: Got it, here's the proof

#include <GUIConstantsEx.au3>
#include "GUIExtender.au3"
Opt("GUIOnEventMode", 1)
Local $Button, $iThis_Section
$hGUI = GUICreate("Vertical", 300, 300, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

_GUIExtender_Init($hGUI)

$iThis_Section = _GUIExtender_Section_Start($hGUI, 0, 70)
$Button = _GUIExtender_Section_Action($hGUI, $iThis_Section + 1, "", "", 270, 40, 15, 15, 0, 1)
GUICtrlCreateGroup("1", 10, 10, 250, 50)
_GUIExtender_Section_End($hGUI)

_GUIExtender_Section_Start($hGUI, 70, 70)
Local $LV = GUICtrlCreateListView("2", 10, 78, 280, 50)
GUICtrlCreateListViewItem('123', $LV)
_GUIExtender_Section_End($hGUI)

_GUIExtender_Section_Start($hGUI, 140, 160)
GUICtrlCreateGroup("3", 10, 162, 280, 50)
GUICtrlCreateGroup("4", 10, 235, 280, 50)
_GUIExtender_Section_End($hGUI)

GUISetState()

While 1
    Sleep(100)
WEnd

Func On_Exit()
    Exit
EndFunc

Thank you.

Edited May 16, 2013 by careca

[Melba23]

careca,

Delighted that you have got it working.

M23

[careca]

Hi, Mr. Melba, got a problem when trying to implement this in the mp3 player i got, so almost everything went fine, it collapsed, and expanded but once collapsed, O_0 !! Where's the Volume slider??

The code for it is as follows under this section, the whole Gui is 500x500 :

_GUIExtender_Section_Start($GUI, 360, 140)

$Slider2 = _GUICtrlSlider_Create($GUI, 440, 382, 24, 92, BitOR($TBS_TOOLTIPS, $TBS_VERT))

[Melba23]

careca,
 

That is a UDF-created control - did you use _GUIExtender_ActionCheck in your idle loop to check for expand/retract events with the  _GUIExtender_UDFCtrlCheck function to hide/show the control when required? 

Look at the GUIExtender_UDF_Event.au3 example to see how to do it.

M23

 

[careca]

Ah, i knew it had to be something like that, gonna check it. Thank you.

[careca]

Ah, i didn't explain the doubt correctly, the thing is, the slider is supposed to

move up with the rest of the buttons, in the bottom section,

when the middle section is retracted.

Got this in the script:

Third section (bottom)

$Slider2 = _GUICtrlSlider_Create($GUI, 440, 382, 24, 92, BitOR($TBS_TOOLTIPS, $TBS_VERT))
_GUIExtender_Section_End($GUI)

_GUIExtender_UDFCtrlCheck($GUI, $Slider2, 3, 440, 30)

In the loop:

If _GUIExtender_ActionCheck() Then
        _GUIExtender_UDFCtrlCheck($GUI, $Slider2, 3, 440, 30)
    EndIf

Edited May 20, 2013 by careca

[Melba23]

careca,
 

You need to make the section containing the UDF-created control actionable - even if you do not intend to do anything with it:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

#include "GUIExtender.au3"

Opt("GUIOnEventMode", 1)

Local $Button, $iThis_Section

$hGUI = GUICreate("Vertical", 300, 300, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

_GUIExtender_Init($hGUI)

$iThis_Section = _GUIExtender_Section_Start($hGUI, 0, 70)
$Button = _GUIExtender_Section_Action($hGUI, $iThis_Section + 1, "", "", 270, 40, 15, 15, 0, 1)
GUICtrlCreateGroup("1", 10, 10, 250, 50)
_GUIExtender_Section_End($hGUI)

_GUIExtender_Section_Start($hGUI, 70, 70)
Local $LV = GUICtrlCreateListView("2", 10, 78, 280, 50)
GUICtrlCreateListViewItem('123', $LV)
_GUIExtender_Section_End($hGUI)

$iEnd_Section = _GUIExtender_Section_Start($hGUI, 140, 160)
_GUIExtender_Section_Action($hGUI, $iEnd_Section) ; Make the section actionable - but do not show a button
GUICtrlCreateButton("Test", 10, 150, 80, 30)
_GUIExtender_Section_End($hGUI)

 $hSlider = _GUICtrlSlider_Create($hGUI, 40, 200, 24, 92, BitOR($TBS_TOOLTIPS, $TBS_VERT))

GUISetState()

While 1
    Sleep(10)
    If _GUIExtender_ActionCheck() Then
        _GUIExtender_UDFCtrlCheck($hGUI, $hSlider, $iEnd_Section, 10, 60) ; Now the UDF knows that there is a control to check
    EndIf
WEnd

Func On_Exit()
    Exit
EndFunc

I hope that is what you were looking for.

M23

[careca]

That's is it! Thank you, but got a problem, after the changes the control now shows up, had to tweak a bit for it to show in the correct place, but the problem is, as soon as it retracts, the gui freezes, and just, kinda crashes, doesn't close by itself, but is unresponsive, the debug says its stuck in the sleep of the loop, and now im stuck, everything seems to be exact same as you posted, only changes are the coords.

[Melba23]

careca,

I am sure you know what I am going to say.....

Post the code! 

Via PM if you do not want to publish it in open forum.

M23

Edit:  For the curious, the problem was elsewhere in the script and had nothing to do with the UDF.

Edited May 23, 2013 by Melba23

[careca]

Thank you for the help in the other issue, and sorry to bother again, but, got another issue,

that came up out of nowhere, all of a sudden, an inputbox just stopped appearing in the top section,

but it does appear and stay up, after i use the extender function, there's no overlapping, changed the placement,

no difference, there are more items in the same coord that appear, im stuck, even used guisetstate to force show, and force enable, nothing.

Are you going to ask me the code again?

EDIT: Just in case you wanna check the code, sent pm.

Edited May 23, 2013 by careca

[Melba23]

careca,

I have extracted (and redacted) the GUI part of the script and it works fine for me:

expandcollapse popup

#include <GUIExtender.au3>
#include <GUIConstantsEx.au3>
#include <GUISlider.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>

Opt("GUIOnEventMode", 1)

$GUI = GUICreate("Test", 500, 500, 100, 100, -1, $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")
;GUISetOnEvent($GUI_EVENT_MINIMIZE, "Minimize") ; Not needed - see below <<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUISetOnEvent($GUI_EVENT_RESTORE, "Restore") ; Needed, but not as you wrote it - see below <<<<<<<<<<<<<<<<<<

_GUIExtender_Init($GUI)

$iThis_Section = _GUIExtender_Section_Start($GUI, 0, 110)
$Input_1 = GUICtrlCreateInput("", 10, 10, 480, 20)
$Input_2 = GUICtrlCreateInput("", 10, 40, 480, 20)
$Button_Find = GUICtrlCreateButton("", 280, 70, 60, 20)
$Input_3 = GUICtrlCreateInput("", 10, 70, 260, 20)
$Playlistno = GUICtrlCreateLabel('', 355, 73, 50, 20)
$Input_4 = GUICtrlCreateInput("", 400, 70, 70, 20)
$Button = _GUIExtender_Section_Action($GUI, $iThis_Section + 1, "", "", 50, 94, 385, 12, 0, 1)
_GUIExtender_Section_End($GUI)

$iExt_Section = _GUIExtender_Section_Start($GUI, 110, 250)
$cListView = GUICtrlCreateListView("#|Path|File", 8, 110, 485, 250)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 40)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 40)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 360)
_GUIExtender_Section_End($GUI)


_GUIExtender_Section_Start($GUI, 360, 140)
$Button_1 = GUICtrlCreateButton("", 10, 385, 60)
$Button_2 = GUICtrlCreateButton("", 80, 385, 60)
$Button_3_P = GUICtrlCreateButton("", 80, 385, 60)
$Button_3_C = GUICtrlCreateButton("", 80, 385, 60)
$Button_4 = GUICtrlCreateButton("", 150, 385, 60)
$Button_5 = GUICtrlCreateButton("", 220, 385, 60)
$Button_6 = GUICtrlCreateButton("", 290, 385, 60)
$Button_7 = GUICtrlCreateButton("", 360, 385, 60)

$Box1 = GUICtrlCreateCheckbox("", 10, 430, -1, 17)
$Box2 = GUICtrlCreateCheckbox("", 10, 415, -1, 17)
$Box3 = GUICtrlCreateCheckbox("", 160, 415, -1, 17)
$Box4 = GUICtrlCreateCheckbox("", 160, 430, -1, 17)
$Box5 = GUICtrlCreateCheckbox("", 300, 415, -1, 17)
$Box6 = GUICtrlCreateCheckbox("", 300, 430, -1, 17)
$Box7 = GUICtrlCreateCheckbox("", 300, 445, -1, 17)
$Slider1 = GUICtrlCreateSlider(10, 362, 365, 20, '0x0001')
$Slider2 = GUICtrlCreateSlider(440, 380, 24, 92, $TBS_VERT)
GUICtrlSetLimit($Slider2, 100, 0)
$InfoTrack = GUICtrlCreateLabel('', 10, 465, 345, 30)
$InfoVol = GUICtrlCreateLabel('', 465, 422, 30, 30)
$InfoT = GUICtrlCreateLabel('', 385, 365, 140, 14)

_GUIExtender_Section_End($GUI)

GUISetState()

;Func Minimize()
    ;WinSetState('', '', @SW_MINIMIZE) ; You do not need this - mixing WinSetState and GUISetState is not recommended <<<<<<<<<<<<<<<
;EndFunc   ;==>Minimize

Func Restore()
    ;WinSetState('', '', @SW_RESTORE) ; You do not need this - mixing WinSetState and GUISetState is not recommended <<<<<<<<<<<<<<<
    _GUIExtender_Restore() ; You need this in your Restore function to get the extension/retraction correct on restore <<<<<<<<<<<<<<<<<<<<<<
EndFunc   ;==>Restore

Func Quit()
    Exit
EndFunc   ;==>Quit

; This should be a While..WEnd loop.  As yuo are in OnEvent mode, GUIGetMsg will always return 0 to why bother with it! <<<<<<<<<<<<<<<<
Do
    Sleep(20)
Until GUIGetMsg() = $GUI_EVENT_CLOSE

You will see I have added a number of comments - please ask if you do not understand why I have done so.

The inputs appear all the time regardless of what I do - can you reproduce the problem?

M23

[careca]

Hello, Thank you for the help, i understand all the comments,

and the way to reproduce the issue is when i run the exe/script i sent you, as it is.

Did it worked well, i mean, does the $input_4 appears when you run the exe??

[Melba23]

careca,

That took a bit of finding - you were using GUICtrlSetState on a tray item which had the same ControlId as the input.  Not a lot of people realise that the 2 sets of controls have separate internal arrays and so can share the same values as ControlIDs.

So look for this line:

GUICtrlSetState($CTTray, $GUI_HIDE)

change it to:

TrayItemSetState($CTTray, $GUI_HIDE)

and everything works as it should - well, it does for me.

Now stop blaming my UDF for all your problems - it has been all your fault so far!

M23

[careca]

Hehehe, true true, thank your for the finding and general help, you see, it has been working fine before,

haven't changed anything besides adding the udf, that's why i thought it could be the culprit.

Thank you.

[BillR5]

Melba23 - For at least one person (me) your spoiler with show button does not work (in multiple browsers). Please consider other solutions like adding three simple link-to-msg-nnn with at least the hidden text. Even better, link to a duplicate post without hiding the text. Or just post the complete text. Or something even better that comes to (your) mind. Thanks.

I eventually read the post by finding text within the source code. (Yuck: we non-developers are so spoiled these days).

Anyone - Is there still a link to the old version? I would like to try out a program initially without having to update it.

I would appreciate the old version link (even if it should be obvious) as I'm having lots of trouble displaying this forum in four browsers. At least with Maxthon almost all pages (but not forum search results!) display properly if refreshed once. With at least IE9 even several refreshes only work sometimes. (Ideas welcome on how to fix this, too.)

Edited November 16, 2013 by BillR5

[Melba23]

BillR5,

 

your spoiler with show button does not work (in multiple browsers)

Sorry to hear that - but you would seem to be in a minority of one who have that problem. The spoiler code is part of the IPB forum software so I am sure that there would have been many complaints if it was not working and to date yours is the first complaint I have seen that it does not.

 

I'm having lots of trouble displaying this forum in four browsers

In my opinion that makes it even more likely that it is a problem at your end - we have had no other reports of this.

 

Please consider other solutions

I think this comment should be directed more to you than us.

Turning at last to the UDF itself:

Is there still a link to the old version? I would like to try out a program initially without having to update it

The original version is still on the forum and you reach it from the link in the first line of the OP - or are you having trouble seeing that too? However, I fail to see the requirement to try out the original - the newer version offers you more functionality. Perhaps you believe that you need to original in order to update? This is certainly not the case - the code is entirely standalone and, like all AutoIt UDFs, is just an #include file to add to your base script.

Anyway should you really feel the need to see it, the original can be found at '?do=embed' frameborder='0' data-embedContent>>

Please come back if you have any further comments or questions.

M23

Edit: I have now seem your other posts in this thread. As mentioned by BrewManNH in the first post of the thread:

 

"If you would rather not download [the _GUIExtender UDF], you can comment out or delete all lines that contain any functions that reference _GUIExtender_. The script will work without using the UDF, but you lose the ability to hide the listview"

So you do not really need it at all.

Edited November 16, 2013 by Melba23