_IsPalindrome() - Check if a string is a palindrome.

[guinness]

This is a quick little function to check whether or not a string is a Palindrome.

Function: Optimised version.

; #FUNCTION# ====================================================================================================================
; Name ..........: _IsPalindrome
; Description ...: Check if a string is a palindrome.
; Syntax ........: _IsPalindrome($sString)
; Parameters ....: $sString                      - A string value containing the palindrome.
;                  $bRetainNonAlphaNumeric      - [optional] Retain all non-word characters. Default is False.
; Return values .: Success - True
;                  Failure - False
; Author ........: guinness
; Remarks .......: Characters are checked with the case ignored i.e. A == a and Z == z.
; Example .......: Yes
; ===============================================================================================================================
Func _IsPalindrome($sString, $bRetainNonAlphaNumeric = Default)
    If Not $bRetainNonAlphaNumeric Then
        $sString = StringRegExpReplace($sString, '\W', '')
    EndIf
    Return $sString = StringReverse($sString)
EndFunc   ;==>_IsPalindrome

Function: With custom StringReverse()

; #FUNCTION# ====================================================================================================================
; Name ..........: _IsPalindrome
; Description ...: Check if a string is a palindrome.
; Syntax ........: _IsPalindrome($sString)
; Parameters ....: $sString                      - A string value containing the palindrome.
;                  $bRetainNonAlphaNumeric      - [optional] Retain all non-word characters. Default is False.
; Return values .: Success - True
;                  Failure - False
; Author ........: guinness
; Remarks .......: Characters are checked with the case ignored i.e. A == a and Z == z.
; Example .......: Yes
; ===============================================================================================================================
Func _IsPalindrome($sString, $bRetainNonAlphaNumeric = Default)
    If Not $bRetainNonAlphaNumeric Then
        $sString = StringRegExpReplace($sString, '\W', '')
    EndIf
    
    Local Const $iChar_Length = 1
    Local $bReturn = True, _
            $i = 1, $j = StringLen($sString)
    While ($i < $j) ; Converted from this: http://marc.info/?l=php-general&m=120422082915762
        If Not (StringMid($sString, $i, $iChar_Length) = StringMid($sString, $j, $iChar_Length)) Then
            $bReturn = False
            ExitLoop
        EndIf
        $i += 1
        $j -= 1
    WEnd
    Return $bReturn
EndFunc   ;==>_IsPalindrome

Example use of Function:

Example()

Func Example()
    ConsoleWrite('Racecar: ' & _IsPalindrome('Racecar') & @CRLF)
    ConsoleWrite('String: ' & _IsPalindrome('String') & @CRLF)
    ConsoleWrite('A man, a plan, a canal, Panama: ' & _IsPalindrome('A man, a plan, a canal, Panama!') & @CRLF)
    ConsoleWrite('Palindrome: ' & _IsPalindrome('Palindrome') & @CRLF)
    ConsoleWrite('Was it a car or a cat I saw?: ' & _IsPalindrome('Was it a car or a cat I saw?', True) & @CRLF) ; This is a palindrome, but the flag has been set to True, so will return False, due to symbols being retained.
    ConsoleWrite('Elk rap song? No sparkle: ' & _IsPalindrome('Elk rap song? No sparkle') & @CRLF)
    ConsoleWrite('I saw desserts; I''d no lemons, alas no melon! Distressed was I: ' & _IsPalindrome('I saw desserts; I''d no lemons, alas no melon! Distressed was I') & @CRLF)
EndFunc   ;==>Example

Edited October 11, 2014 by guinness

[guinness]

Updated code. Removed StringStripWS and add the [:space:] character class to the SRER.

[guinness]

Change the regular expression and updated the example with a few more palindromes.

Source: http://www.palindromelist.net/

[czardas]

I'm a bit confused as to why you decided to strip out non word characters. A palindrome need not be limited to words and numbers. I would never have thought that the following phrase: 'Was it a car or a cat I saw' would be classified as a palindrome, but it appears others do consider it to be so. I think that in the strict sense of the word a palindrome ought to be exactly the same backwards as it is forwards without any modification, as it is in other fields outside of literature. I also think this would be potentially more useful if case sensitivity was made optional, although that's not part of the definition of a palindrome.

Edited January 23, 2013 by czardas

[Mat]

I'm a bit confused as to why you decided to strip out non word characters. The function checks if a string is a palindrome after modification. A palindrome need not be limited to words and numbers, and I also think it would be potentially more useful if case sensitivity was made optional.

A man, a plan, a canal, Panama.

Madam in Eden, I am Adam.

Those are the two palindromic sentences I know, and they wouldn't work without stripping bits.

However, I agree that flags would make this more useful.

[czardas]

Sorry for keep changing my wording while you respond Mat. I was just expressing my thoughts. We think you should add some flags guinness.

[guinness]

A palindrome is a word, phrase, number, or other sequence of units that may be read the same way in either direction, with general allowances for adjustments to punctuation and word dividers.

But at your request I add a single flag as you didn't specify what it should be exactly.

[czardas]

If you only want one flag, you could use: 0 = default (exact string - no modification), 1 = case insensitive, 2 = strip non alphanumeric characters, 4 = .strip out numbers. These are just suggestions for a more robust function: Obviously there are many possibilities. You may wish to make the default alphanumeric only.

Edited January 23, 2013 by czardas

[guinness]

That's a possibility. I will have a look sometime this week, as it was just meant to be a bit of fun.

[czardas]

I imagine it has some application for programming. I think that full words can represent a unit. Checking that would make it quite cool.

time after time = word unit palindrome. I made that up LOL!

Edited January 23, 2013 by czardas

[guinness]

I imagine it has some application for programming.

Really? Because I don't think many members would.

[czardas]

I said some applictation (as in limited potential). Its usefulness would depend entirely on context. It's perhaps the kind of thing a cryptographer, or an artist (not only writers), might wish to use. Perhaps compression is a valid application, but implimenting such a method may be very time consuming, although computers keep getting faster.

Edited January 23, 2013 by czardas

[kiritoproject]

It is interesting to see such a function.

But I can not explain a particular choice in regular expressions. Why use StringLower, if we take both uppercase and lowercase letters? You have a string, all lower case (with StringLower), and take both uppercase and lowercase? [^a-z0-9] is not good?

[guinness]

My bad, that was left over from the old function.

[guinness]

Example 2:

expandcollapse popup

#include <String.au3>

Example()

Func Example()
    Local Const $ISPALINDROME_DEFAULT = 0, $ISPALINDROME_CASEINSENSITIVE = 1, $ISPALINDROME_STRIPNONALPHA = 2, $ISPALINDROME_STRIPNUMBERS = 4

    ConsoleWrite('Racecar: ' & _IsPalindrome('Racecar', $ISPALINDROME_CASEINSENSITIVE) & @CRLF)
    ConsoleWrite('String: ' & _IsPalindrome('String', $ISPALINDROME_DEFAULT) & @CRLF)
    ConsoleWrite('A man, a plan, a canal, Panama: ' & _IsPalindrome('A man, a plan, a canal, Panama!', $ISPALINDROME_DEFAULT) & @CRLF)
    ConsoleWrite('Palindrome: ' & _IsPalindrome('Palindrome', BitOR($ISPALINDROME_CASEINSENSITIVE, $ISPALINDROME_STRIPNONALPHA, $ISPALINDROME_STRIPNUMBERS)) & @CRLF)
    ConsoleWrite('Was it a car or a cat I saw?: ' & _IsPalindrome('Was it a car or a cat I saw?', $ISPALINDROME_STRIPNONALPHA) & @CRLF)
    ConsoleWrite('Elk rap song? No sparkle: ' & _IsPalindrome('Elk rap song? No sparkle', BitOR($ISPALINDROME_STRIPNONALPHA, $ISPALINDROME_STRIPNUMBERS)) & @CRLF)
    ConsoleWrite('I saw desserts; I’d no lemons, alas no melon! Distressed was I: ' & _IsPalindrome('I saw desserts; I’d no lemons, alas no melon! Distressed was I', BitOR($ISPALINDROME_CASEINSENSITIVE, $ISPALINDROME_STRIPNONALPHA, $ISPALINDROME_STRIPNUMBERS)) & @CRLF)
EndFunc   ;==>Example

; #FUNCTION# ====================================================================================================================
; Name ..........: _IsPalindrome
; Description ...: Check if a string is a palindrome.
; Syntax ........: _IsPalindrome($sString)
; Parameters ....: $sString             - A string value containg the palindrome.
;                  $iFlag               - [optional] An integer value. Default is $ISPALINDROME_DEFAULT (0).
;                 |$ISPALINDROME_DEFAULT = 0 - Use the string without any modification.
;                 |$ISPALINDROME_CASEINSENSITIVE = 1 - Convert the string to lowercase.
;                 |$ISPALINDROME_STRIPNONALPHA = 2 - Strip non-alphanumeric characters from the string.
;                 |$ISPALINDROME_STRIPNUMBERS = 4 - Strip numbers from the string.
; Return values .: Success - True
;                  Failure - False
; Author ........: guinness
; Remarks .......: String.au3 must be included.
; Example .......: Yes
; ===============================================================================================================================
Func _IsPalindrome($sString, $iFlag = Default)
    Local Const $ISPALINDROME_DEFAULT = 0, $ISPALINDROME_CASEINSENSITIVE = 1, $ISPALINDROME_STRIPNONALPHA = 2, $ISPALINDROME_STRIPNUMBERS = 4
    If $iFlag = Default Then
        $iFlag = $ISPALINDROME_DEFAULT
    EndIf
    If BitAND($iFlag, $ISPALINDROME_CASEINSENSITIVE) Then
        $sString = StringLower($sString)
    EndIf
    If BitAND($iFlag, $ISPALINDROME_STRIPNONALPHA) Then
        $sString = StringRegExpReplace($sString, '(?i)[^a-z0-9]', '')
    EndIf
    If BitAND($iFlag, $ISPALINDROME_STRIPNUMBERS) Then
        $sString = StringRegExpReplace(StringLower($sString), '[0-9]', '')
    EndIf
    Return $sString == _StringReverse($sString)
EndFunc   ;==>_IsPalindrome

[czardas]

Hey guinness, I wasn't expecting you to adapt it so quickly. I like the method you use, which is a great example of good coding. Thanks for your time and effort.

[guinness]

I'm sure it can be improved, I hope someone does improve it with more features.

[guinness]

_StringReverse has been a hot topic as of late, so I decided to update this function without the use of _StringReverse.

Source: http://stackoverflow.com/questions/52002/how-to-check-if-the-given-string-is-palindrome?page=2&tab=votes#tab-top

[UEZ]

Here another version:

Func _IsPalindrome($sString) ;coded by UEZ 2013
    Local $sCompacted = StringRegExpReplace(StringLower($sString), '[^a-z0-9]', '')
    Local $i, $iEnd = StringLen($sCompacted)
    For $i = 1 To Floor($iEnd / 2)
        If StringMid($sCompacted, $i, 1) <> StringMid($sCompacted, 1 + $iEnd - $i, 1) Then Return 0
    Next
    Return 1
EndFunc

Br,

UEZ

[guinness]

Thanks UEZ.