winwaitactive for more than one?

[legend]

Hi, can I use winwaitactive for more windows? so if some window appears it opens mspaint, and if some other window is detected, it also opens mspaint, I tried the code i posted here, but it doesen't work, since it waits for the first window (Notepad)

Opt("WinTitleMatchMode", 2)
func test1()
ShellExecute("mspaint.exe")
EndFunc

WinWaitActive("Notepad")
Call("test1")
WinWaitActive("Test")
Call("test1")

[nitekram]

I do not think it is possible with that function, as it will pause the script until it sees the window. You might be able to use ProcessExists() and put it in a while loop and it may work?

[water]

Use

$sWindowTitle = WinGetTitle("[ACTIVE]")

to get the title of the active window and check the title for what yo need in a loop (don't forget the Sleep).

Edited October 6, 2012 by water

[FireFox]

Hi,

Maybe this?

Opt("WinTitleMatchMode", 2)

Local $aWaitActiveWnd[2] = ["Notepad", "Test"]

_WinWaitActiveMultiple($aWaitActiveWnd)

test1()

Func test1()
ShellExecute("mspaint.exe")
EndFunc   ;==>test1

Func _WinWaitActiveMultiple($aWnd, $iTimeOut = 0)
If $iTimeOut > 0 Then
Local $iTimer = TimerInit()
EndIf

While 1
For $iWnd = 0 To UBound($aWnd) - 1
If WinActive($aWnd[$iWnd]) Then Return $iWnd
Next

If $iTimeOut > 0 Then
If TimerDiff($iTimer) >= $iTimeOut * 1000 Then ExitLoop
EndIf
Sleep(50)
WEnd
EndFunc   ;==>_WinWaitActiveMultiple

Br, FireFox.

Edited October 6, 2012 by FireFox

[legend]

hi firefox works pretty good, but if you then open notepad, and it then opens mspaint, then you open some other window, and open notepad again, then it does not open mspaint, is it possible to do that ?

[FireFox]

@legend

Of course it is :

...

While 1

_WinWaitActiveMultiple($aWaitActiveWnd)

test1()
WEnd

...

Br, FireFox.

Edited October 6, 2012 by FireFox

[wolf9228]

Hi, can I use winwaitactive for more windows? so if some window appears it opens mspaint, and if some other window is detected, it also opens mspaint, I tried the code i posted here, but it doesen't work, since it waits for the first window (Notepad)

Opt("WinTitleMatchMode", 2)
func test1()
ShellExecute("mspaint.exe")
EndFunc

WinWaitActive("Notepad")
Call("test1")
WinWaitActive("Test")
Call("test1")

expandcollapse popup

Global $ActiveArray = 0
HotKeySet("{ESC}", "Terminate")

ShellExecute("notepad.exe","",@SystemDir,"",@SW_MINIMIZE)
ShellExecute("mspaint.exe","",@SystemDir,"",@SW_MINIMIZE)
ShellExecute("wordpad.exe","",@SystemDir,"",@SW_MINIMIZE)

RegisterWindows("Untitled - Notepad","","CallbackFunc")
RegisterWindows("Untitled - Paint","","CallbackFunc")
RegisterWindows("Document - WordPad","","CallbackFunc")

While True
Sleep(100)
WEnd

Func CallbackFunc($Winhandle,$Title,$Text)
MsgBox(0,"Active","Winhandle Is " & $Winhandle & @CRLF & _
"Title Is " & $Title & @CRLF & "Text Is " & $Text)
EndFunc

Func WindowsIsActive()
if IsArray($ActiveArray) Then
For $i = 0 To (UBound($ActiveArray) - 1)
$Winhandle = WinActive($ActiveArray[$i][0],$ActiveArray[$i][1])
if ($Winhandle) Then
Call($ActiveArray[$i][2],$Winhandle,$ActiveArray[$i][0],$ActiveArray[$i][1])
RegisterWindows($ActiveArray[$i][0],$ActiveArray[$i][1],$ActiveArray[$i][2],2) ;UnRegister
ExitLoop
EndIf
Next
EndIf
EndFunc

Func RegisterWindows($Title,$Text,$CallbackFunc,$Flag = 1)
;$Flag = 1 Register
;$Flag = 2 UnRegister
Switch $Flag
Case 1
AdlibRegister("WindowsIsActive")
if Not IsArray($ActiveArray) Then
Local $TempActiveArray[1][3]
$TempActiveArray[0][0] = $Title
$TempActiveArray[0][1] = $Text
$TempActiveArray[0][2] = $CallbackFunc
$ActiveArray = $TempActiveArray
Return SetError(0,0,True)
Else
For $i = 0 To UBound($ActiveArray) - 1
if $Title == $ActiveArray[$i][0] And $Text == $TempActiveArray[0][1] _
And $CallbackFunc == $TempActiveArray[0][2] Then Return SetError(1,0,False)
Next
ReDim $ActiveArray[UBound($ActiveArray) + 1][3]
$ActiveArray[UBound($ActiveArray) - 1][0] = $Title
$ActiveArray[UBound($ActiveArray) - 1][1] = $Text
$ActiveArray[UBound($ActiveArray) - 1][2] = $CallbackFunc
Return SetError(0,0,True)
EndIf
Case 2
if IsArray($ActiveArray) Then
Local $TempActiveArray[UBound($ActiveArray)][3],$Test = False , $j = 0
For $i = 0 To UBound($ActiveArray) - 1
if $Title == $ActiveArray[$i][0] And $Text == $ActiveArray[0][1] _
And $CallbackFunc == $ActiveArray[0][2] Then
$Test = True
ContinueLoop
EndIf
$TempActiveArray[$j][0] = $ActiveArray[$i][0]
$TempActiveArray[$j][1] = $ActiveArray[$i][1]
$TempActiveArray[$j][2] = $ActiveArray[$i][2]
$j += 1
Next
if ($Test) Then
if UBound($TempActiveArray) > 1 Then
ReDim $TempActiveArray[UBound($TempActiveArray) - 1][3]
$ActiveArray = $TempActiveArray
Else
$ActiveArray = 0
AdlibUnRegister("WindowsIsActive")
EndIf
Return SetError(0,0,True)
Else
Return SetError(2,0,False)
EndIf
EndIf
Case Else
Return SetError(3,0,False)
EndSwitch
EndFunc

Func Terminate()
    Exit 0
EndFunc

Edited October 6, 2012 by wolf9228