ROT47

[DeltaRocked]

Hope this helps someone.

$string = 'Hello World'
$string=Rot47($string)
MsgBox(0, 'Encode', $string)
$string=Rot47($string)
MsgBox(0, 'Decode', $string)
Func Rot47($input)
Local $rotted, $i=1
While $i <= StringLen($input)
$pos = StringMid($input, $i, 1)
If Asc($pos) + 47 >= 127 And Asc($pos) > 32 And Asc($pos) < 127 Then
$rotted &= Chr(Asc($pos) - 47)
ElseIf Asc($pos) + 47 <= 126 And Asc($pos) > 32 And Asc($pos) < 127 Then
$rotted &= Chr(Asc($pos) + 47)
Else
$rotted &= $pos
EndIf
$i += 1
WEnd
Return $rotted
EndFunc ;==>Rot47

Edited October 20, 2012 by deltar

[Reaper HGN]

Pretty cool. Mostly for obfuscation?

[guinness]

Nice. It's ROT13 with a larger character set.

[wraithdu]

Call me a perfectionist, looks nicer to my eyes.

Func Rot47($input)
    Local $rotted = ""
    For $i = 1 To StringLen($input)
        $pos = Asc(StringMid($input, $i, 1))
        If $pos > 32 And $pos > 79 And $pos < 127 Then
            $rotted &= Chr($pos - 47)
        ElseIf $pos > 32 And $pos < 80 And $pos < 127 Then
            $rotted &= Chr($pos + 47)
        Else
            $rotted &= Chr($pos)
        EndIf
    Next
    Return $rotted
EndFunc   ;==>Rot47

Edited September 27, 2012 by wraithdu

[DeltaRocked]

wraithdu - perfectionist -- yep 100%. Initially I was just unable to comprehend / understand your code.

Modified the code.

Func Rot471($input)
Local $rotted = ""
For $i = 1 To StringLen($input)
     $pos = Asc(StringMid($input, $i, 1))
     If $pos > 79 And $pos < 127 Then ;$pos > 32 And
         $rotted &= Chr($pos - 47)
     ElseIf $pos > 32 And $pos < 80 Then ;And $pos < 127
         $rotted &= Chr($pos + 47)
     Else
         $rotted &= Chr($pos)
     EndIf
Next
Return $rotted
EndFunc ;==>Rot47

Edited October 20, 2012 by deltar

[guinness]

Func Rot47($sValue)
    Local $iChar = 0, $sRotted = ""
    For $i = 1 To StringLen($sValue)
        $iChar = Asc(StringMid($sValue, $i, 1))
        If $iChar >= 33 And $iChar <= 79 Then
            $iChar += 47
        ElseIf $iChar >= 80 And $iChar <= 126 Then
            $iChar -= 47
        EndIf
        $sRotted &= Chr($iChar)
    Next
    Return $sRotted
EndFunc   ;==>Rot47

This is an improved version of wraithdu's.

Edited January 10, 2015 by guinness

[SmOke_N]

This has >rot ciphers 1 - 47

Guinness, I think you forgot to remove $iPos for $iChar.

Edit:

Hmm, @guinness, after testing, your "improved version" doesn't produce true Rot47 data.

Edited January 10, 2015 by SmOke_N

[guinness]

 

Hmm, @guinness, after testing, your "improved version" doesn't produce true Rot47 data.

Fixed it. Thanks.

Edit: I created on a system that doesn't have AutoIt installed nor do I have access to AutoIt Portable.

Edited January 10, 2015 by guinness

[Ward]

I am a perfectionist, too. Here is my suggestion:

1. To deal with string char by char, don't forget use StringToASCIIArray()/StringFromASCIIArray().

String concatenation in script language is slow. (SmOke_N's example did it well.)

2. Conditional statements should be avoid in loop. We can use map instead in this case.

My version:

Func Rot47($String)
    Static $Map[127]
    If Not $Map[33] Then
        For $i = 33 To 79
            $Map[$i] = $i + 47
        Next
        For $i = 80 To 126
            $Map[$i] = $i - 47
        Next
    EndIf

    Local $Array = StringToASCIIArray($String)
    For $i = 0 To UBound($Array) - 1
        If $Array[$i] >= 33 And $Array[$i] <= 126 Then
            $Array[$i] = $Map[$Array[$i]]
        EndIf
    Next
    Return StringFromASCIIArray($Array)
EndFunc

[guinness]

Nice. But then it's the question of speed vs memory management. Still, nice use of StringToASCIIArray().

1001 iterations =>

211.718616347897 (mine)

134.484747469317 (yours)

Edited January 10, 2015 by guinness