Restricting the minimum and maximum sizes of a GUI.

[guinness]

At some point we've all seen the example for WM_GETMINMAXINFO floating around the forum, in regards to restricting the size of the GUI. I therefore decided to have a look at this and see if it could be rearranged to use structures and code already predefined in AutoIt and the UDFs. Sometimes users like to duplicate variables that may already exist in WindowsConstants.au3 or StructureConstants.au3 and it can cause problems down the line if the variable values change. You never know $GUI_EVENT_CLOSE (-3) might change to -99 one day, so this is why 'magic numbers' are bad to use in examples.

So having read about WM_GETMINMAXINFO on MSDN, the structure that was required turned out to be tagMINMAXINFO, which was made up of 5 tagPOINT structures (long X;long Y;) strung together. So I created the following code below and will probably propose that the tagMINMAXINFO structure be added to the AutoIt UDFs.

So my questions is: Does the structure look correct? Or should I use a different approach? Any feed back is much appreciated.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
#include <GUIConstantsEx.au3>
#include <Windowsconstants.au3>

; MINMAXINFO Struct >> http://msdn.microsoft.com/en-us/library/windows/desktop/ms632605(v=vs.85).aspx
; It uses a $tagPOINT structure which is long X; long Y;
Global Const $tagMINMAXINFO = "struct; long ReservedX;long ReservedY;long MaxSizeX;long MaxSizeY;long MaxPositionX;long MaxPositionY;" & _
        "long MinTrackSizeX;long MinTrackSizeY;long MaxTrackSizeX;long MaxTrackSizeY; endstruct"

; GUI API for setting the minimum an maximum sizes of the GUI. These don't need to be called by the end user, but rather use _GUISetSize().
Global Enum $__iMinSizeX, $__iMinSizeY, $__iMaxSizeX, $__iMaxSizeY, $__iGUISizeMax
Global $__vGUISize[$__iGUISizeMax]

Example()

Func Example()
    ; Create a resizable GUI.
    Local $hGUI = GUICreate('', Default, Default, Default, Default, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))
    GUISetState(@SW_SHOW, $hGUI)

    ; Set the minimum and maximum sizes of the GUI.
    _GUISetSize(150, 150, 500, 500)

    ; Register the WM_GETMINMAXINFO message.
    GUIRegisterMsg($WM_GETMINMAXINFO, 'WM_GETMINMAXINFO')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _GUISetSize($iMinWidth, $iMinHeight, $iMaxWidth, $iMaxHeight)
    $__vGUISize[$__iMinSizeX] = $iMinWidth
    $__vGUISize[$__iMinSizeY] = $iMinHeight
    $__vGUISize[$__iMaxSizeX] = $iMaxWidth
    $__vGUISize[$__iMaxSizeY] = $iMaxHeight
EndFunc   ;==>_GUISetSize

Func WM_GETMINMAXINFO($hWnd, $iMsg, $wParam, $lParam) ; Original idea by Zedna & updated by guinness 21/09/12.
    #forceref $hWnd, $iMsg, $wParam
    Local $tMINMAXINFO = DllStructCreate($tagMINMAXINFO, $lParam)
    DllStructSetData($tMINMAXINFO, 'MinTrackSizeX', $__vGUISize[$__iMinSizeX])
    DllStructSetData($tMINMAXINFO, 'MinTrackSizeY', $__vGUISize[$__iMinSizeY])
    DllStructSetData($tMINMAXINFO, 'MaxTrackSizeX', $__vGUISize[$__iMaxSizeX])
    DllStructSetData($tMINMAXINFO, 'MaxTrackSizeY', $__vGUISize[$__iMaxSizeY])
EndFunc   ;==>WM_GETMINMAXINFO

[IanN1990]

You have helped me out so many times in the past, I wish i knew the answer so in some way to repay the favour but my knowledge in GUI is very limited

[FireFox]

@guinness

This approach is better than what I've seen about this function, it's well done and the structure is understandable. Before we used the structure indexes, now we have "MinTrackSizeX", ...

Btw, why is this in the General Help and Support ? Even it's like a "tell me if it's good", this is an example.

Br, FireFox.

[jaberwacky]

I see this but I'm probably just not aware of any recent changes to AutoIt:

$tagMINMAXINFO = "struct;

What's the "struct" for?

Edit: Nevermind, I actually did some reading.

Edit2: This is definitely going into my current script!

Edited September 22, 2012 by LaCastiglione

[guinness]

You have helped me out so many times in the past, I wish i knew the answer so in some way to repay the favour but my knowledge in GUI is very limited

No problem. The code works, just wanting some expertise to know if my structure is OK.

@guinness

This approach is better than what I've seen about this function, it's well done and the structure is understandable. Before we used the structure indexes, now we have "MinTrackSizeX", ...

Btw, why is this in the General Help and Support ? Even it's like a "tell me if it's good", this is an example.

Br, FireFox.

Thanks. I would say using index numbers is just the same as using 'magic numbers' a huge no no! I could put it in the examples, it just didn't cross my mind at the time.

Edit2: This is definitely going into my current script!

Great!

[guinness]

Another one I will re-visit is WM_COPYDATA as well. Expect an update/post in the next couple of days.

[FireFox]

Another one I will re-visit is WM_COPYDATA as well. Expect an update/post in the next couple of days.

Great ! We should add examples for the WM in the help file, I know there are some but it's not for the func themselves.

Br, FireFox.

[martin]

Only 4 values, or only 2 points, are needed so wouldn't a more appropriate tag be

Global Const $tagRECT = "struct;long Left;long Top;long Right;long Bottom;endstruct"

?

But the need to have a struct for this at all is not clear to me and seems to make the code more complicated.

If you are going to hard code the Min/Max values in the _GuiSetSize function then you might as well leave out the function and hard code the values into the WM_GETMINMAXINFO handler. If you are not hard coding the values then you have to assign values to each element in the struct and then use the struct members later when it would be simpler to use an array or individual variables. Structs are particuarly useful when you need to pass a handle to one but that isn't the case here so why use one at all?

If you have a script with more than one window you would need to have an array of structs so that in the GetMinMax handler you can test for the window handle and then apply the appropriate constraints, so the struct could include a window handle. Or at least there should be some way to know which window the constraints in a particular struct are for. In this case I would say an array would be a more sensible choice than a struct.

EDIT: Misunderstood so struck out everything

Edited September 23, 2012 by martin

[FireFox]

I'm out... too tired to understand this (I would have preferred to be English)

[guinness]

martin,

The idea for _GUISetSize was just an example and I was also trying to keep it simple for the 'end user' without having to interact too much with the WM_GETMINMAXINFO, it's how I code these days by creating an 'API system' in which I set specific values using a function, just makes life easier for debugging issues with Global variables. An idea I picked up from a Dev.

Global Const $tagRECT = "struct;long Left;long Top;long Right;long Bottom;endstruct"

?

Though it does seem logical only passing 2 points, from what MSDN says and trying it, the structure should be built like above. I have tried using "struct;long Left;long Top;long Right;long Bottom;endstruct" and it doesn't work.

About your other point, you can't pass the GUI handle using the structure or am I missing something?

Edited September 23, 2012 by guinness

[martin]

Guiness,

Reading your post again I see that I misunderstood and the result was that I wrote nonsense. I read it that you were using a struct to hold some values to be used later but you were using an array and then copying the array values into the struct. I should play with AutoIt more to improve my reading.

Apologies, please ignore my post.

[guinness]

No problem martin, it's nice to be challenged as this improves my knowledge too, especially when it comes down to converting 'MSDN chat' to something a little more understandable.

[JFX]

Structure looks correct, but i think you should remove "struct;" and "endstruct;"

It just confuse people, as there is not reason to use it here.

[guinness]

Structure looks correct, but i think you should remove "struct;" and "endstruct;"

It just confuse people, as there is not reason to use it here.

Why do you think it confused people?

[JFX]

Sorry guinness, just me was confused.

Had not noticed that POINT is a structure and can be misaligned in some causes .

[guinness]

Sorry guinness, just me was confused.

Had not noticed that POINT is a structure and can be misaligned in some causes .

No problem at all.

Suffice to say I don't think my example is wrong from the feedback I have received, which has been wonderful.