_FileWriteFromArray

[BrandNewTester]

Hi all,

I m new to autoit...m using __FileWriteFromArray function for writing some value to file.

what i m doing here is, i just read value to one variable that containes five values.

i only need third value,i dt need other values...

plz help me to do this...

thanks in advance.....

this is my sample script..

Local $filesys = StringRegExp($sXML, '<q1:fileSystem>(.*?)</q1:fileSystem>', 3)

Local $hfilesys = FileOpen($sFile,1)

FileWrite($hfilesys,"FILESYSTEM : ")

;_ArrayDisplay($address)

_FileWriteFromArray($hfilesys, $filesys, 0)

here it writes five values to file..

i just want 3rd value..i don't want 0th,1st, 2nd and 4th value..

plz help me..

[BrewManNH]

Use FileWriteToLine($hFilesys, $address[3]) and see if that does what you're looking for.

[BrandNewTester]

hey i got the answer by using upper bound..

but i have facing one more problem..

i just want 0th value...i gave 0 for both upper and lower bound..it writes all the value..it takes as default...

if i give 0 for lower and 1 for upper bound it displays 0th and 1st index value

i just want 0th value..

[BrewManNH]

The way the function is written, there's no way for it to determine that you want to only write the 0 element.

[BrewManNH]

I have submitted a bug report to the tracker in ticket number 2242 for this but in the meantime, here's an updated _FileListToArray function that will correct the problem of not being able to write to the file just the zeroth element ([0]).

expandcollapse popup

; <<< Changed the default value of $i_Ubound from 0 to -1 >>>
 
Func __FileWriteFromArray($File, $a_Array, $i_Base = 0, $i_UBound = -1, $s_Delim = "|")
     ; Check if we have a valid array as input
     If Not IsArray($a_Array) Then Return SetError(2, 0, 0)
     Local $iDims = UBound($a_Array, 0)
     If $iDims > 2 Then Return SetError(4, 0, 0)
     ; determine last entry
     Local $last = UBound($a_Array) - 1
; <<< Changed $i_Ubound < 1 to $i_Ubound < 0 >>>
     If $i_UBound < 0 Or $i_UBound > $last Then $i_UBound = $last
     If $i_Base < 0 Or $i_Base > $last Then $i_Base = 0
     ; Open output file for overwrite by default, or use input file handle if passed
     Local $hFile
     If IsString($File) Then
          $hFile = FileOpen($File, $FO_OVERWRITE)
     Else
          $hFile = $File
     EndIf
     If $hFile = -1 Then Return SetError(1, 0, 0)
     ; Write array data to file
     Local $ErrorSav = 0
     Switch $iDims
          Case 1
               For $x = $i_Base To $i_UBound
                    If FileWrite($hFile, $a_Array[$x] & @CRLF) = 0 Then
                         $ErrorSav = 3
                         ExitLoop
                    EndIf
               Next
          Case 2
               Local $s_Temp
               For $x = $i_Base To $i_UBound
                    $s_Temp = $a_Array[$x][0]
                    For $y = 1 To $iDims - 1
                         $s_Temp &= $s_Delim & $a_Array[$x][$y]
                    Next
                    If FileWrite($hFile, $s_Temp & @CRLF) = 0 Then
                         $ErrorSav = 3
                         ExitLoop
                    EndIf
               Next
     EndSwitch
     ; Close file only if specified by a string path
     If IsString($File) Then FileClose($hFile)
     ; Return results
     If $ErrorSav Then Return SetError($ErrorSav, 0, 0)
     Return 1
EndFunc   ;==>__FileWriteFromArray

This would be a script breaking change for anyone using 0 for $i_UBound to get the whole array, but the default value of -1 will take care of this if you don't include the parameter in your scripts.

Edited August 2, 2012 by BrewManNH

[guinness]

I thought I had fixed this, oh well. I will have a look at your ticket in the next couple of days.

[BrandNewTester]

Thanks BNMH ....