Removing a dimension from an array

[Mechaflash]

In my case, I'm only using a 2D array to hold a number field in d1 and a filename in d2. I want to just strip d1 out of the array. Is there another way of doing this besides having to output d2 into another array and clearing out the old array?

[guinness]

Not that I'm aware of.

[water]

Use ReDim. You can strip of the rightmost column of an array. So if you can just swap the two columns then you can ReDim the array and get rid of the column.

Be aware that it is still a 2D array, but with just one column.

#include <array.au3>
Global $array[3][2] = [[11,12],[21,22],[31,32]]
_ArrayDisplay($array)
ReDim $array[3][1]
_ArrayDisplay($array)
MsgBox(0, "", "# of dimensions: " & UBound($Array, 0))

Edited June 26, 2012 by water

[JohnOne]

Or you can just stop using d1.

[guinness]

Why do you want to strip 'd1'? If you do decide to swap the columns then personally I would just create a new array instead, but from what I can gather this is what you're doing already.

#include <Array.au3>
Global $aArray_1[3][2] = [[11, 12],[21, 22],[31, 32]]
_ArrayDisplay($aArray_1)

Local $aArray_2[UBound($aArray_1)]
For $i = 0 To UBound($aArray_1) - 1
    $aArray_2[$i] = $aArray_1[$i][1]
Next
_ArrayDisplay($aArray_2)

Edited June 26, 2012 by guinness

[czardas]

If you use ReDim you don't actually need to swap the columns. That would be slower than simply transfering the data from column 1 to column 0 before using ReDim.

[water]

Hi czardas,

I understand the OP that he has two columns (C0 and C1) in his array and wants to get rid of C0. Using ReDim you can only get rid of the rightmost column therefore he needs to swap them.

[czardas]

Not true.

#include <Array.au3>

Dim $aArray[5][2] = [[0,1],[2,3],[4,5],[6,7],[8,9]]

_ArrayDisplay($aArray)

For $i = 0 To 4
    $aArray[$i][0] = $aArray[$i][1]
Next
ReDim $aArray[5][1]

_ArrayDisplay($aArray)

[water]

Using ReDim you can only get rid of the rightmost column therefore he needs to swap them.

Still true

[czardas]

How so? Please explain.

[guinness]

czardas,

water is correct. Your code is like mine but without creating a new array, which I did to create a 'true' 1D array.

[czardas]

Yes I still have a 2D array - which is interesting in itself. But I ignored all the data from column 0. It was never swapped, but simply overwritten. So where does the swapping come into it?

Edited June 26, 2012 by czardas

[water]

How so? Please explain.

Using ReDim you can't change the number of dimensions but you can change the number of elements in a dimension. I changed the number of columns from 2 to 1 but it remained a 2D array.

The title of the tread is "Removing a dimension from an array" which can't be done using ReDim.

I suggested ReDim because of speed.

[czardas]

Using ReDim you can't change the number of dimensions but you can change the number of elements in a dimension. I changed the number of columns from 2 to 1 but it remained a 2D array.

The title of the tread is "Removing a dimension from an array" which can't be done using ReDim.

On this I agree.

Edited June 26, 2012 by czardas

[water]

So let's see what mechaflash213 thinks and which solution he prefers

[czardas]

I suggest he should use the example guiness gave, [Edit] with the option of adding the line.

$aArray_1 = $aArray_2

Edited June 26, 2012 by czardas

[Mechaflash]

Not true.

#include <Array.au3>
For $i = 0 To 4
$aArray[$i][0] = $aArray[$i][1]
Next

lol ... its the same idea as swapping. Either way you're getting the contents of column 1 into column 0 .

Ran a test...

$aArray = IniReadSection("C:test.ini", "test")

_ArrayDisplay($aArray)
$hTimer = TimerInit()
For $i = 1 To 3497
$aArray[$i][0] = $aArray[$i][1]
Next

ReDim $aArray[$aArray[0][0]]
ConsoleWrite(TimerDiff($hTimer) / 1000) ; Returns 0.012046 seconds

$aArray = IniReadSection("C:test.ini", "test")
$hTimer = TimerInit()
Local $aOut[$aArray[0][0]]
For $i = 1 to 3497
$aOut[$i - 1] = $aArray[$i][1]
Next
ConsoleWrite(TimerDIff($hTimer) / 1000) ; Returns 0.010761 seconds
_ArrayDisplay($aOut)

3497 values set in an ini file, read them to an array (creates a 2D array), and tried both methods.

Moving it to a new array is faster. If I didn't have to ReDim the first example, it would've been half the time of the second method (cause my first test I forgot to ReDim the variable in the first example XD)

EDIT:

OH WAIT!

$aArray = IniReadSection("C:test.ini", "test")
_ArrayDisplay($aArray)

#region ; Overwrite first column and ReDim
$hTimer = TimerInit()
For $i = 1 To 3497
    $aArray[$i][0] = $aArray[$i][1]
Next
ReDim $aArray[$aArray[0][0]]
ConsoleWrite(TimerDiff($hTimer) / 1000) ; Returns 0.011719 seconds
#endregion


$aArray = IniReadSection("C:test.ini", "test")

#region ; Dump to a second array
$hTimer = TimerInit()
Local $aOut[$aArray[0][0]]
For $i = 1 to 3497
    $aOut[$i - 1] = $aArray[$i][1]
Next
$aArray = 0
ConsoleWrite(TimerDIff($hTimer) / 1000) ; Returns 0.018022 seconds
#endregion

If I have to clear the old array the first method is faster XD

Edited June 26, 2012 by mechaflash213

[czardas]

I think this is just a question of semantics. From my understanding, swapping columns would involve an extra step using a funtion such as _ArraySwap(). That would slow things down.

#include <Array.au3>

Dim $aArray[5][2] = [[0,1],[2,3],[4,5],[6,7],[8,9]]
_ArrayDisplay($aArray, "Before _ArraySwap")

For $i = 0 To 4
_ArraySwap($aArray[$i][0], $aArray[$i][1])
Next
_ArrayDisplay($aArray, "After _ArraySwap")

ReDim $aArray[5][1]
_ArrayDisplay($aArray, "After ReDim")

Edited June 26, 2012 by czardas

[water]

Unfortunately

ReDim $aArray[5]

doesn't work. As soon as you change the number of dimensions the complete content of the array is dropped.

According to the help file: "The number of dimensions must remain the same, or the old array will be forgotten during the ReDim."

[BrewManNH]

Is .007 seconds really that much of a difference?