_AlwaysRun() - Monitor a program and restart if it closed.

guinness · April 29, 2012

The following function will start a batch file to monitor when a program closes and restart if necessary. If you need more explanation than that, then this function isn't for you.

Note: You can close the batch file using either the PID returned by _AlwaysRun() (which you'll have to store somewhere e.g. INI file) OR using the Task Manager to manually close the process.

Function: Using a Batch file. Save as _AlwaysRun.au3

#include-once
#include <Constants.au3>

; #FUNCTION# ====================================================================================================================
; Name ..........: _AlwaysRun
; Description ...: Monitor when a program closes and then restart it.
; Syntax ........: _AlwaysRun($sFilePath[, $sCommandline = ''])
; Parameters ....: $sFilePath           - FilePath of the program to monitor and restart.
;                  $sCommandline        - [optional] A commandline string to pass to the program on restart. Default is ''.
; Return values .: Success - Returns the PID of the batch file.
;                   Failure - Returns 0 & sets @error to non-zero
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _AlwaysRun($sFilePath, $sCommandline = '')
    If $sFilePath = @ScriptFullPath And @Compiled = 0 Then
        Return SetError(1, 0, 0)
    EndIf

    Local Const $STR_NOCASESENSEBASIC = 2
    Local Const $sAppName = StringTrimLeft($sFilePath, StringInStr($sFilePath, '\', $STR_NOCASESENSEBASIC, -1))
    Local $sFileName = StringReplace(@ScriptName, StringTrimLeft(@ScriptName, StringInStr(@ScriptName, '.', $STR_NOCASESENSEBASIC, -1) - 1), '')
    While FileExists(@TempDir & '\' & $sFileName & '.bat')
        $sFileName &= Chr(Random(65, 122, 1))
    WEnd
    If $sCommandline Then
        $sCommandline = ' ' & $sCommandline
    EndIf
    Local Const $sData = ':START' & @CRLF _
             & 'PING -n 2 127.0.0.1 > nul' & @CRLF _
             & @CRLF _
             & 'TASKLIST /NH /FI "IMAGENAME EQ ' & $sAppName & '" | FIND /I "' & $sAppName & '" >nul && GOTO START' & @CRLF _
             & 'GOTO END' & @CRLF _
             & ':END' & @CRLF _
             & 'START "_AlwaysRun" "' & $sFilePath & '"' & $sCommandline & @CRLF _
             & 'GOTO START' & @CRLF

    Local Const $hFileOpen = FileOpen(@TempDir & '\' & $sFileName & '.bat', $FO_OVERWRITE)
    If $hFileOpen = -1 Then
        Return SetError(2, 0, 0)
    EndIf
    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return Run(@TempDir & '\' & $sFileName & '.bat', @TempDir, @SW_HIDE)
EndFunc   ;==>_AlwaysRun

Function: Using a VBScript file. Save as _AlwaysRun.au3

; Discontinued for now.

Example_1:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
#include <Constants.au3>

#include '_AlwaysRun.au3'

; Compile the following script before running.
If @Compiled Then
    Example()
EndIf

Func Example()
    Local $iPID = IniRead(@ScriptDir & '\_AlwaysRunPID.ini', 'Monitor', 'PID', 0)

    ; Check if the monitoring process is running. If not then call the function _AlwaysRun. (This is the reason why the PID was saved to an INI file.)
    If ProcessExists($iPID) = 0 Then
        ; Start monitoring the current script path for when it closes and restart if necessary. No commandline parameters are passed.
        $iPID = _AlwaysRun(@ScriptFullPath, '')

        If @error Then
            Exit MsgBox($MB_SYSTEMMODAL, '_AlwaysRun()', 'The running script must be a compiled exe to work correctly.')
        EndIf

        ; Save the PID returned by _AlwaysRun to an INI file in case we need to close the monitoring process in the future.
        IniWrite(@ScriptDir & '\_AlwaysRunPID.ini', 'Monitor', 'PID', $iPID)
    Else
        Local Const $aArray[2] = ['No', 'Yes']
        If MsgBox(BitOR($MB_YESNO, $MB_SYSTEMMODAL), '_AlwaysRun Running: ' & $aArray[Number(ProcessExists($iPID) > 0)], 'Would you like to continue running the _AlwaysRun Example?') = 7 Then
            FileDelete(@ScriptDir & '\_AlwaysRunPID.ini')
            Exit ProcessClose($iPID)
        EndIf
    EndIf
    Exit 0
EndFunc   ;==>Example

Edited April 4, 2013 by guinness

acidman · April 29, 2012

Nice work, I browsed a bit and you truelly live up to your nick

Guinness

Edited April 29, 2012 by ac1dm4n

guinness · April 29, 2012

Live up to what?

Beege · April 29, 2012

Nice function. Clever!

guinness · April 29, 2012

Nice function. Clever!

Thanks. If I have time I will create a VBScript version too.

guinness · April 29, 2012

Seems I found time. Updated with a VBScript version too.

guinness · October 3, 2012

Updated the syntax of _AlwaysRun. See the original post for more details.

FireFox · October 4, 2012

I'm going to use it for a virus, mouhahaha.

Good idea btw.

Edited October 4, 2012 by FireFox

DavidLago · October 11, 2012

I'd like to monitor an application despite of the PID its assigned to. Is there any possibility to Monitor it by its Name?

guinness · October 11, 2012

Yes, I could add this functionality to the UDF. Give me a couple of days or you could try yourself and report back.

guinness · October 11, 2012

Actually on second thought you caught me off guard earlier on. This is what it does, you pass the fullpath e.g. C:SomethingExample.exe, the UDF strips the path and monitors Example.exe. So what's the issue?

MrCreatoR · December 24, 2012

Nice, but why use bat or vbs, this can be done with autoit as well:

#include-once
#include <WinAPIEx.au3>

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

;#include "_AlwaysRun.au3"

; Compile the following script before running.
If Not @Compiled Then
    MsgBox(48, 'Attention', 'This script must be compiled to work properly.')
    Exit
EndIf

Example()

Func Example()
    Local $iPID = _AlwaysRun(@AutoItPID)
    
    MsgBox(64, Default, '_AlwaysRun Example, it will close itself in 10 seconds after you press OK.')
    
    Sleep(10000)
    ProcessClose($iPID)
EndFunc

; #FUNCTION# ====================================================================================================================
; Name ..........: _AlwaysRun
; Description ...: Monitor when a program closes and then restart it.
; Syntax ........: _AlwaysRun($iPID [, $sCommandline = ''])
; Parameters ....: $iPID           - Process ID of the program to monitor and restart.
;                  $sCommandLine        - [optional] A commandline string to pass to the program on restart. Default is ''.
; Return values .: Success - Returns the PID of the monitor process.
;                  Failure - Returns 0 & sets @error to non-zero
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _AlwaysRun($iPID, $sCommandLine = '')
    Local $sTmpFile = @TempDir & '\~Au3Mon.au3'
    Local $sFilePath = _WinAPI_GetProcessFileName($iPID)
    
    If Not $sFilePath Or ($sFilePath = @ScriptFullPath And @Compiled = 0) Then
        Return SetError(1, 0, 0)
    EndIf
    
    Local $aProcList = ProcessList(StringTrimLeft($sFilePath, StringInStr($sFilePath, '\', 2, -1)))
    
    For $i = 1 To UBound($aProcList)-1
        If StringInStr(_WinAPI_GetProcessCommandLine($aProcList[$i][1]), $sTmpFile, 2) Then
            Return $aProcList[$i][1]
        EndIf
    Next
    
    If $sCommandLine <> '' Then
        $sCommandLine = ' ' & $sCommandLine
    EndIf
    
    Local $sData = _
        '#NoTrayIcon' & @CRLF & _
        '$iPID = ' & $iPID & @CRLF & _
        'While 1' & @CRLF & _
        '   If Not ProcessExists($iPID) Then' & @CRLF & _
        '       $iPID = Run("' & $sFilePath & '"' & $sCommandLine & ')' & @CRLF & _
        '   EndIf' & @CRLF & _
        '   Sleep(10)' & @CRLF & _
        'WEnd'
    
    Local $hFileOpen = FileOpen($sTmpFile, 2)
    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    
    Return Run('"' & @AutoItExe & '" /AutoIt3ExecuteScript "' & $sTmpFile & '"')
EndFunc   ;==>_AlwaysRun

And few more things, ShellExecute does not return PID, and directory macros does not have ending slash .

P.S.

These methods does not protect from process tree closing.

guinness · December 24, 2012

And few more things, ShellExecute does not return PID, and directory macros does not have ending slash .

Good catch with the header, that was because I took the batch script version and forgot to ammend it. The backslash is the Forum!

I like your idea (no need for #include-once) and I suppose I adopted the batch script/VBScript as I took this from other examples I created in the series, it also means the executable isn't locked either.

Edited December 24, 2012 by guinness

ricky · April 3, 2013

Hello,

thanks for this script, but there is a problem, in the vbs script, the command line is not used, why?

guinness · April 3, 2013

Because I didn't implement it by the looks of things. I will fix it tonight. Thanks.

guinness · April 3, 2013

Updated the original post. Please tell me if this works for you. Thanks.

ricky · April 4, 2013

No, there is more one problem :

WARNING: $STR_NOCASESENSEBASIC: possibly used before declaration.

guinness · April 4, 2013

Fixed. I keep forgetting that this is in the beta version.

ricky · April 4, 2013

Thanks, but I don't understand a little thing, why did you write :

& 'GOTO END' & @CRLF _

& ':END' & @CRLF _

It does not make sense it does not matter at all. Or i'm wrong?

guinness · April 4, 2013

Just to break the script into sections.

Sign In

_AlwaysRun() - Monitor a program and restart if it closed.

Recommended Posts

guinness

acidman

guinness

Beege

guinness

guinness

guinness

FireFox

DavidLago

guinness

guinness

MrCreatoR

guinness

ricky

guinness

guinness

ricky

guinness

ricky

guinness

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta