AutoIt Snippets

[Exit]

poor error checking.

Try this:

Local $aArray[3] = ["x=1", "y==2", "z"] ; Declare the Array

 

[TheDcoder]

@guinness Name of the function?

@Exit It doesn't have an error checking system, all my snippets lack error checking system... I will add error checking system when I finish my project

[Exit]

@Exit It doesn't have an error checking system, all my snippets lack error checking system... I will add error checking system when I finish my project

Then please add your snippets to this tread after adding error checking at the end of your Project.

[TheDcoder]

@Exit I added an Error checking system, I think that snippets need error checking, TD

[guinness]

_ArrayAdd() maybe? I dunno, you're the power user of AutoIt, I am just some old user!

Edited July 5, 2015 by guinness

[iamtheky]

_ArrayAdd() maybe?   edit:  I dunno, you're the power user of AutoIt, I am just some old user!

You edited it to be additionally patronizing and are recommending a solution that involves redims as an improvement to a snippet that has none?  That is super.

Dcoder, there are older examples, and i think the speed can be improved on yours.  And apparently you have upset Guinness, so that part is at least right.

.https://www.autoitscript.com/forum/topic/120801-converting-array-1d-2d/

[Iczer]

function without arrays and dependences to calculate number of days in any month in any year

For $i = 1 to 12
    ConsoleWrite(_DaysInMonth($i,2000)&@CRLF)
Next


Func _DaysInMonth ($iMonth,$iYear)
    return 28 + Mod($iMonth + Floor($iMonth / 8), 2) + Mod(2, $iMonth) + Floor((2 - Mod(Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 2, (Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 1))) / $iMonth) + Floor(1/$iMonth) - Floor((1 - Mod((Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 2), (Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 1)))/$iMonth)
EndFunc

[Iczer]

if you double-click on some *.au3, script is opened in SciTE, but in same time collection of previously opened scripts  in this editor is lost.

to prevent this compile this script and make OS open *.au3 with this exe

 

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=C:\Program Files (x86)\AutoIt3\Icons\au3.ico
#AutoIt3Wrapper_Res_Comment=Prevent drop collection of previously opened scripts in case some single script is opened by double click
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <WinAPIProc.au3>
;
AutoItSetOption ("WinTitleMatchMode", 2)
If Not ProcessExists ( "SciTE.exe" ) Then
    Run(@ProgramFilesDir & "\AutoIt3\SciTE\SciTE.exe",@ProgramFilesDir & "\AutoIt3\SciTE")
    WinWaitActive("SciTE","",3)
    SystemMetrics_WaitTillProcessIdleEX2('SciTE.exe',1234)
EndIf
;ShellExecute($CmdLineRaw)
Run(@ProgramFilesDir & "\AutoIt3\SciTE\SciTE.exe " & $CmdLineRaw )
;
;======================================================================================================================================================================================================
Func SystemMetrics_WaitTillProcessIdleEX2($sProcessName = "", $iTimeoutInMilliSeconds = 8888)

    If $sProcessName == "" Then Return SetError(1)
    Local $iPID = ProcessExists($sProcessName)
    If $iPID = 0 Then Return SetError(2)
    Local $iPrecessTime_1 = 0, $iPrecessTime_2 = 0, $iTimeStamp = TimerInit(), $iTimeStampEX = TimerInit(), $aFT

    While 1
        Sleep(128)

        $aFT = _WinAPI_GetProcessTimes($iPID)
        If @error Then Return SetError(2)

        $iPrecessTime_2 = $aFT[1]+$aFT[2]

        If $iPrecessTime_1 <> $iPrecessTime_2 Then
            If TimerDiff($iTimeStamp) > 888 Then ExitLoop
        Else
            $iPrecessTime_1 = $iPrecessTime_2
            $iTimeStamp = TimerInit()
        EndIf
        If TimerDiff($iTimeStampEX) > (5*60*1000) Then Return SetError(21)
    WEnd

    $iTimeStamp = TimerInit()
    While 1
        Sleep(256)

        $aFT = _WinAPI_GetProcessTimes($iPID)
        If @error Then Return SetError(3)

        $iPrecessTime_2 = $aFT[1]+$aFT[2]

        If $iPrecessTime_1 = $iPrecessTime_2 Then
            If TimerDiff($iTimeStamp) > $iTimeoutInMilliSeconds Then Return 1
        Else
            $iPrecessTime_1 = $iPrecessTime_2
            $iTimeStamp = TimerInit()
        EndIf
        If TimerDiff($iTimeStampEX) > (5*60*1000) Then Return SetError(21)
    WEnd
EndFunc   ;==>SystemMetrics_WaitTillProcessIdle
;======================================================================================================================================================================================================

 

[Jos]

if you double-click on some *.au3, script is opened in SciTE, but in same time collection of previously opened scripts  in this editor is lost.

to prevent this compile this script and make OS open *.au3 with this exe

 

-or- just add this in your properties file assuming you have the full version:

save.session.advanced=1

Jos

Edited July 5, 2015 by Jos

[UEZ]

I think this thread is now in a status which is not usable anymore. A lot of posts but who knows what were posted so far.

No index, no hints.

[jchd]

function without arrays and dependences to calculate number of days in any month in any year

For $i = 1 to 12
    ConsoleWrite(_DaysInMonth($i,2000)&@CRLF)
Next


Func _DaysInMonth ($iMonth,$iYear)
    return 28 + Mod($iMonth + Floor($iMonth / 8), 2) + Mod(2, $iMonth) + Floor((2 - Mod(Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 2, (Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 1))) / $iMonth) + Floor(1/$iMonth) - Floor((1 - Mod((Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 2), (Mod($iYear, 4) * (Mod($iYear, 100) + Mod($iYear, 400)) + 1)))/$iMonth)
EndFunc

This code is not correct. It considers years Y such as Y = 0 (mod 100) and Y ≠ 0 (mod 400) as leap, while they are not.

[TheDcoder]

@guinness Sorry if I made you feel like that ... I tried but I can't understand how its done using _ArrayAdd

@boththose I am confused , Do you want me to use Dim instead of Local?

[water]

I think this thread is now in a status which is not usable anymore. A lot of posts but who knows what were posted so far.

No index, no hints.

I second that.
In my opinion the wiki is the perfect place for code snippets - we already have a section for snippets (the header problem should be solved though).
I do not think it is a good idea to have the same information spread all over the place.

So: Snippets in the wiki, discussion about them in the forum. Just my $ 0.02.

[TheDcoder]

A new squeal to StringTrimUntil collection

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: StringLeftUntil
; Description ...: Extract the text before the delimiter (or inculding the delimiter)
; Syntax ........: StringLeftUntil($sDelimiter, $sString[, $iOccurrence = 1[, $bIncludeDelimiter = False]])
; Parameters ....: $sDelimiter          - Delimiter.
;                  $sString             - String to process.
;                  $iOccurrence         - [optional] Ouccurence to extract until. Default is 1st ouccurence.
;                  $bIncludeDelimiter   - [optional] Do you want to include the delimiter?. Default is False.
; Return values .: Extracted String
; Author ........: TheDcoder
; Modified ......: N/A
; Remarks .......: None.
; Related .......: StringLeft
; Link ..........: bit.ly/StringUntilForAutoIt
; Example .......: No
; ===============================================================================================================================
Func StringLeftUntil($sDelimiter, $sString, $iOccurrence = 1, $bIncludeDelimiter = False)
    $iDelimiterPos = StringInStr($sString, $sDelimiter, 2, $iOccurrence) ; We need delimiter's position
    $sReturn = StringLeft($sString, $iDelimiterPos - 1) ; Extract the string before the delimiter
    If $bIncludeDelimiter = True Then $sReturn &= $sDelimiter ; Check if the delimiter needs to be attached again
    Return $sReturn ; Return the string
EndFunc   ;==>StringLeftUntil

; #FUNCTION# ====================================================================================================================
; Name ..........: StringRightUntil
; Description ...: Extract the text after the delimiter (or inculding the delimiter)
; Syntax ........: StringRightUntil($sDelimiter, $sString[, $iOccurrence = 1[, $bIncludeDelimiter = False]])
; Parameters ....: $sDelimiter          - Delimiter.
;                  $sString             - String to process
;                  $iOccurrence         - [optional] Ouccurence to extract until. Default is 1st ouccurence.
;                  $bIncludeDelimiter   - [optional] Do you want to include the delimiter?. Default is False.
; Return values .: Extracted String
; Author ........: TheDcoder
; Modified ......: N/A
; Remarks .......: None.
; Related .......: StringRight
; Link ..........: bit.ly/StringUntilForAutoIt
; Example .......: No
; ===============================================================================================================================
Func StringRightUntil($sDelimiter, $sString, $iOccurrence = 1, $bIncludeDelimiter = False)
    $sString = StringReverse($sString) ; Reverse the string
    $sDelimiter = StringReverse($sDelimiter) ; Reverse the delimiter
    ; Just the whole process of StringLeftUntil is reversed :D
    $iDelimiterPos = StringInStr($sString, $sDelimiter, 2, $iOccurrence)
    $sReturn = StringLeft($sString, $iDelimiterPos - 1)
    If $bIncludeDelimiter = True Then $sReturn &= $sDelimiter
    Return StringReverse($sReturn) ; Return the reversed string
EndFunc   ;==>StringRightUntil

Hope you may find it useful, TD

[TheDcoder]

I am continuing my posting combo , RunCommand! Get both the output & the exitcode of a command with a single line of code, TD

There is a better RunCommand function in the Process UDF with many more options & functions

However if you still wish to use the old one, here is the code:

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: RunCommand
; Description ...: Runs a command or executes a executable & return the STDOUT & STDERR output along with the exit code
; Syntax ........: RunCommand($sCommand[, $sWorkingDir = ""[, $sPath = @ComSpec & " /c "]])
; Parameters ....: $sCommand            - The command to execute
;                  $sWorkingDir         - [optional] The working directory. Default is "".
;                  $sPath               - [optional] This is the path if you want to run a exe, MUST CONTAIN THE TRAILING BACKSLASH!!!. Default is @ComSpec & " /c ".
; Return values .: Success: Will return the STDOUT & STDERR output, @extended will contain the exit code
;                  Failure: Will set @error to 1 & returns 0
; Author ........: TheDcoder
; Modified ......: N/A
; Remarks .......: The code for capturing the exit code: https://www.autoitscript.com/forum/topic/98602-run-not-runwait-with-dos-exit-code/?do=findComment&comment=720326 Thanks!
; Related .......: Run, RunWait
; Link ..........: bit.ly/RunCommandForAutoIt
; Example .......: Yes, See below
; ===============================================================================================================================
Func RunCommand($sCommand, $sWorkingDir = "", $sPath = @ComSpec & " /c ")
    Local $sData = "", $iPID, $iExitCode ; $sData contains the output, $iPID contains the PID & $iExitCode contains the exit code
    $iPID = Run($sPath & $sCommand, $sWorkingDir, @SW_HIDE, 0x8) ; Get the PID of the process, The opt flag is $STDERR_MERGED
    If @error Then Return SetError(1, 0, 0) ; Return with error code 1 if its an error
    $avRET = DllCall("kernel32.dll", "ptr", "OpenProcess", "int", 0x0400, "int", 0, "int", $iPID) ; Get the handle of the process
    $hHandle = $avRET[0] ; Assign the handle of the process
    ; ProcessWaitClose($iPID) ; Wait until the command finishes its work
    While ProcessExists($iPID)
        $sData &= StdoutRead($iPID) ; Capture the output
        Sleep(10) ; Don't kill the CPU
    WEnd
    $t_ExitCode = DllStructCreate("int") ; I don't know what it does, but I think its the container which is used to store the exit code
    $avRET = DllCall("kernel32.dll", "int", "GetExitCodeProcess", "ptr", $hHandle, "ptr", DllStructGetPtr($t_ExitCode)) ; I think this one puts the exit code in the container
    $iExitCode = DllStructGetData($t_ExitCode, 1) ; Peek inside the container & note the exit code 
    DllCall("kernel32.dll", "int", "CloseHandle", "ptr", $hHandle) ; Close the process handle
    Return SetExtended($iExitCode, $sData) ; Return the data & the exit code in @extended 
EndFunc

; Example

$sData = RunCommand("This will not work b/c its not an command, but this will be executed by CMD so it will return the exit code: 1")
$iExitCode = @extended ; Store the exit code

MsgBox(0, "RunCommand Example", $sData & @CRLF & @CRLF & "Exit Code: " & $iExitCode) ; Display the results

 

Edited August 14, 2015 by TheDcoder

[Jos]

Nice UDF.

I would add 2 things to it:

1. Put a short sleep(10) in your While ProcessExists($iPID) close loop to eat less CPU
2. Make an optional parameter in which you can select to ConsoleWrite() all Output as it is received.

Jos

[TheDcoder]

@Jos Thanks! I will put a small sleep in there, I was thinking of returning the pid & the process handle, PID for capturing the output & Process handle for capturing the exit code, I will implement it tomorrow as it is mid-night here, Goodnight, TD

[TheDcoder]

Its me again, This is a dedicated snippet, Checks if the system is a terminal:

; #FUNCTION# ====================================================================================================================
; Name ..........: IsTerminal
; Description ...: Checks if its a terminal machine
; Syntax ........: IsTerminal()
; Parameters ....: None.
; Return values .: Success: True, @extended will contain: 
;                           1 - Citrix session
;                           2 - RDP session
;                  Failure: False
; Author ........: TheDcoder
; Modified ......: N/A
; Remarks .......: None.
; Related .......: None.
; Link ..........: https://www.autoitscript.com/forum/topic/139260-autoit-snippets/?do=findComment&comment=1264752
; Example .......: No
; ===============================================================================================================================
Func IsTerminal()
    $sOutput = EnvGet("SESSIONNAME") ; Get the SESSIONNAME variable's value
    If StringRight($sOutput, 3) = "ICA" Then Return SetExtended(1, True) ; Check if its a Citrix session
    If StringRight($sOutput, 3) = "RDP" Then Return SetExtended(2, True) ; Check if its a RDP session
    Return False ; Return False if none of the above
EndFunc

TD

Edited August 13, 2015 by TheDcoder
updated link, TD :)

[iamtheky]

If your application relies on these variables, remove the folder option "Launch folder windows in a separate process".

https://support.microsoft.com/en-us/kb/2509192

 

There are plenty of fun ways to check for that, if you want to be foolproof.  Finding a way to run this from the parent explorer.exe without regard to being launched from a separate process, that would be killer.

[nitekram]

I second that.
In my opinion the wiki is the perfect place for code snippets - we already have a section for snippets (the header problem should be solved though).
I do not think it is a good idea to have the same information spread all over the place.

So: Snippets in the wiki, discussion about them in the forum. Just my $ 0.02.

i thnk that maybe this should have a section in the example scripts, under snippets, and each one have its own post, otherwise this post will be like the great software thread, cannot remeber name. - a lot of great stuff lost in a 100 pages. 

But I will give my 4 cents this time, as this is the exact definition of examples. Besides the other issue with search for it in our search engine, would be nearly impossible. 

 

Please excuse any spelling mistakes, I am on a cell.