Place text in image and save

[telmob]

Hello again guys. Hope you're all having a nice weekend.

Ok, so... i have a question i hope you can help me with.

I have a program (almost finished) to make reports for my company, and at the end of the report, the program places an image of a digitalized signature of the guy that makes the report, but.... i'm trying to add some security to it, so our clients, don't just steal that digital signature and place it in another report.

So, i thought about adding the date to that picture (signature), and save the picture after so the picture and the date in it are all the same and not distinct objects. Is there a way to do that?

Ofcourse this is just my idea in how to add extra security to the signatures, but i'm open to suggestions

[wakillon]

May be something like this

expandcollapse popup

#include <GDIPlus.au3>


_AddTextToPic ( @DesktopDir & 'Image.jpg', @MyDocumentsDir & 'Image2.jpg', "Signature", 20, 450 )
_DisplayPic ( @MyDocumentsDir & 'Image2.jpg' )
Exit

Func _AddTextToPic ( $_ImagePath, $_Outputpath, $sString, $_X=0, $_Y=0 )
    Local $hBitmap, $hImage, $hGraphic, $hFamily, $hFont, $tLayout, $hFormat, $aInfo, $hBrush1, $hBrush2, $iWidth, $iHeight, $hPen
    ; Initialize GDI+ library
    _GDIPlus_StartUp ( )
    ; Load image and emboss text
    $hImage   = _GDIPlus_ImageLoadFromFile ( $_ImagePath )
    $hGraphic = _GDIPlus_ImageGetGraphicsContext ( $hImage )
    $hFamily  = _GDIPlus_FontFamilyCreate ( "Arial" )
    $hFont    = _GDIPlus_FontCreate ( $hFamily, 38, 1 )
    $hFormat  = _GDIPlus_StringFormatCreate ( 0x4000 )
    $hBrush2  = _GDIPlus_BrushCreateSolid ( 0xff000000 )
    $hPen     = _GDIPlus_PenCreate ( 0xC4000000, 1 )
    ; Set Text Pos
    $tLayout  = _GDIPlus_RectFCreate ( $_X, $_Y )
    $aInfo    = _GDIPlus_GraphicsMeasureString ( $hGraphic, $sString, $hFont, $tLayout, $hFormat )
    _GDIPlus_GraphicsDrawStringEx ( $hGraphic, $sString, $hFont, $aInfo[0], $hFormat, $hBrush2 )
    ; Save image
    _GDIPlus_ImageSaveToFile ( $hImage, $_Outputpath )
    ; Free resources
    _GDIPlus_PenDispose ( $hPen )
    _GDIPlus_BrushDispose ( $hBrush1 )
    _GDIPlus_BrushDispose ( $hBrush2 )
    _GDIPlus_StringFormatDispose ( $hFormat )
    _GDIPlus_FontDispose ( $hFont )
    _GDIPlus_FontFamilyDispose ( $hFamily )
    _GDIPlus_GraphicsDispose ( $hGraphic )
    _GDIPlus_ImageDispose ( $hImage )
    _GDIPlus_ShutDown ( )
EndFunc ;==> _AddTextToPic ( )

Func _DisplayPic ( $_ImagePath )
    Run ( 'rundll32 shimgvw.dll,ImageView_Fullscreen ' & $_ImagePath )
EndFunc ;==> _DisplayPic ( )

[UEZ]

I wrote some time ago a function to write a text to an image: Write Text on Bitmap()

Maybe it is useful for you.

Link points to the German Autoit site.

Br,

UEZ

Edited March 3, 2012 by UEZ

[telmob]

Thanks guys.

I'm trying wakillon code first but... i'm getting this error:

_DisplayPic - Undefined function

[guinness]

The error is telling you that you didn't copy _DisplayPic from wakillon's example.

[wakillon]

Thanks guys.

I'm trying wakillon code first but... i'm getting this error:

_DisplayPic - Undefined function

It's just for display directly the result in Microsoft viewer.

Remove the line in cause.

[telmob]

Geezzzz... I forgot to copy the whole thing... how very lame of me

Thanks again guys. My problem is solved

[wakillon]

Geezzzz... I forgot to copy the whole thing... how very lame of me

Thanks again guys. My problem is solved

If you have some time take a look at UEZ advanced scripts in post#3

[telmob]

Will do it now!

Thank you so much!