_FileWriteFromArray from 2D Array [BUG]

[BrewManNH]

You should check to see if $Time is an array using IsArray($Time) before doing anything with it that requires it to be an array. If it's not an array you need to put in some code that deals with that issue.

[johnmcloud]

BrewManNH i have make this for now, work for me:

If IsArray($DeleteList) Then
  If $DeleteList[0] = "1" Then
   MsgBox(0,0,"No Files")
   Return
  EndIf
EndIf

Hope is a good solution

[guinness]

Correct me if I'm wrong, but surely the function should write a 2D array with more than 2 columns? Because at present if I pass it an Array with 3 rows and 5 columns it only writes 2 of them. If I'm wrong then let me know, otherwise I'll re-write the function and discuss with a Dev about it.

[BrewManNH]

The function _FIleWriteFromArray is indeed written wrong. It's using the number of dimensions "Local $iDims = UBound($a_Array, 0)" instead of the number of subitems (Ubound($a_Array, 2)) to write the array.

[guinness]

So here is my improved version >>

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _FileWriteFromArray
; Description ...: Writes an array to a specified file.
; Syntax ........: _FileWriteFromArray($sFilePath, $aArray[, $iBase = 0[, $iUBound = 0[, $sDelimeter = "|"]]])
; Parameters ....: $sFilePath - Path of the file to write to, or a file handle returned from FileOpen().
;                  $aArray - The array to be written to the file.
;                  $iBase - [optional] Start array index to read, normally set to 0 or 1. Default is 0.
;                  $iUBound - [optional] Set to the last record you want to write to the File. Default is 0 (whole array.)
;                  $sDelimeter - [optional] Delimiter character(s) for 2-dimension arrays. Default is "|".
; Return values .: Success - Returns a 1
;                  Failure - Returns a 0
;                  @Error  - 0 = No error.
;                  |1 = Error opening specified file
;                  |2 = Input is not an Array
;                  |3 = Error writing to file
;                  |4 = Array dimensions > 2
; Author ........: Jos van der Zande <jdeb at autoitscript dot com>
; Modified.......: Updated for file handles by PsaltyDS, @error = 4 msg and 2-dimension capability added by Spiff59 and fixed by guinness.
; Remarks .......: If a string path is provided, the file is overwritten and closed.
;                  To use other write modes, like append or Unicode formats, open the file with FileOpen() first and pass the file handle instead.
;                  If a file handle is passed, the file will still be open after writing.
; Related .......: _FileReadToArray
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _FileWriteFromArray($sFilePath, $aArray, $iBase = 0, $iUBound = 0, $sDelimeter = "|")
    ; Check if we have a valid array as input
    If Not IsArray($aArray) Then Return SetError(2, 0, 0)

    ; Check the number of dimensions
    Local $iDims = UBound($aArray, 0)
    If $iDims > 2 Then Return SetError(4, 0, 0)

    ; Determine last entry of the array
    Local $iLast = UBound($aArray) - 1
    If $iUBound < 1 Or $iUBound > $iLast Then $iUBound = $iLast
    If $iBase < 0 Or $iBase > $iLast Then $iBase = 0

    ; Open output file for overwrite by default, or use input file handle if passed
    Local $hFileOpen
    If IsString($sFilePath) Then
        $hFileOpen = FileOpen($sFilePath, $FO_OVERWRITE)
    Else
        $hFileOpen = $sFilePath
    EndIf
    If $hFileOpen = -1 Then Return SetError(1, 0, 0)

    ; Write array data to file
    Local $iError = 0
    Switch $iDims
        Case 1
            For $i = $iBase To $iUBound
                If FileWrite($hFileOpen, $aArray[$i] & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
        Case 2
            Local $sTemp
            Local $iCols = UBound($aArray, 2)
            For $i = $iBase To $iUBound
                $sTemp = $aArray[$i][0]
                For $j = 1 To $iCols - 1
                    $sTemp &= $sDelimeter & $aArray[$i][$j]
                Next
                If FileWrite($hFileOpen, $sTemp & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
    EndSwitch

    ; Close file only if specified by a string path
    If IsString($sFilePath) Then FileClose($hFileOpen)

    ; Return results
    If $iError Then Return SetError($iError, 0, 0)
    Return 1
EndFunc   ;==>_FileWriteFromArray

[johnmcloud]

I'm a little confused. What should i need to use? The edit version of File.au3 or the improved version of _FileWriteFromArray? The result is the same?

[water]

Use the improved version written by guinness. The edited version only works correctly for 2D arrays with exactly 2 columns. It returns the wrong results for arrays > 2 columns.

You can take the improved version and replace the respective function in file.au3.

[guinness]

Thanks water for clarifying.

Sorry for confusing you johnmcloud, but it seemed like a good time as ever to discuss about the function.

[johnmcloud]

No problem guinness, hope your version will be integrate soon in a new autoit version

Edited February 7, 2012 by johnmcloud

[Xerix]

Thanks Guinness,

 

It works very well.

 

I also hope that it will soon replace the current version of _FileWriteFromArray

[guinness]

It's available in the AutoIt beta.

Please refrain from bumping old topics in the future please. Thanks.

[Xerix]

Strange, i have Autoit 3.3.9.17 and i have only  the old _FileWriteFromArray

And sorry for old topic

[guinness]

It might not look the same as above, but it's the new version for sure. How did you check?

[Xerix]

Exact, it's not the same version in 3.3.8.1 and 3.3.9.17 and it's not the same version than above

 

But if i use an another of your great script >_GUICtrlListView_CreateArray() for to export a listview and then i export the array with _FileWriteFromArray it doesn't works with beta version. (no file is created)

 

But if i use the script above it works.

 

Example :

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include "GUICtrlListView_CreateArray.au3"
#include <File.au3>
#include <Array.au3>


$gui = GUICreate("title", 750, 630, 20, 20, $WS_THICKFRAME + $WS_MAXIMIZEBOX + $WS_MINIMIZEBOX)
$listview = GUICtrlCreateListView("text1|text2|text3|text4|text5|text6", 10, 10, 730, 450, $LVS_SINGLESEL, $LVS_EX_REGIONAL + $LVS_EX_FULLROWSELECT + $LVS_EX_GRIDLINES)
GUICtrlCreateListViewItem ( "1|2|3|4|5|6", $listview )
GUICtrlCreateListViewItem ( "7|8|9|10|11|12", $listview )
GUISetState(@SW_SHOW, $gui)


$arrayexport = _GUICtrlListView_CreateArray($listview)
_FileWriteFromArray(@ScriptDir & "\test.csv",$arrayexport,1,0,";")


While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
Exit
EndSelect
WEnd

Why ?

Perhaps i should create another post.

Edited August 18, 2013 by Xerix

[guinness]

Could you just create an array instead and provide what you expect the output to be. Thanks.

Edit: PM if you want to.

Edited August 18, 2013 by guinness

[Xerix]

If i made an array it doesn't works if $i_Ubound is egal to 0

example

#include <File.au3>
dim $Array[4]
$array [0] = "a"
$array [1] = "b"
$array [2] = "c"
$array [3] = "d"
_FileWriteFromArray(@ScriptDir & "\test.txt",$array,1,0)

doesn't work with beta (no file)

but 

#include <File.au3>
dim $Array[4]
$array [0] = "a"
$array [1] = "b"
$array [2] = "c"
$array [3] = "d"
_FileWriteFromArray(@ScriptDir & "\test.txt",$array,1)

works

and

#include <File.au3>
dim $Array[4]
$array [0] = "a"
$array [1] = "b"
$array [2] = "c"
$array [3] = "d"
_FileWriteFromArray(@ScriptDir & "\test.txt",$array,0,0)

return only "a"

 

[guinness]

OK, I will have a look as right now I'm not in a position to run AutoIt. Unless a DevMVPMod comes in with a workaround.

[Melba23]

Xerix,

Your 3 examples are working exactly as intended:

 

- 1. You ask for the array elements 1 to 0 - you get @error = 5 returned ("Start index is greater than the $iUbound parameter") as expected.

- 2. You ask for elements 1 to Default (as that is the default value of $iUBound) - you get the elements you require.

- 3. You ask for elements 0 to 0 - you get element 0.

No bug - you need to learn how to set the parameters correctly.

M23

[guinness]

Thanks Melba23 for testing.

[Xerix]

Thanks Melba,

 

For me 0 for $iUBound is not the element 0 but whole array as explained in the help file.

 

So 1 and 0 should start at line 1 and continue until the end of the array

 

I'm not English, so I may be poorly understood the sentence of help.

Edited August 18, 2013 by Xerix