MsgBox parameter checker?

[Beege]

Melba23, Thats an excellent little step by step for adding your own toys to Scite. Im saving that post for anyone in the future who asks.

emendelson, I came up with one other possible method for you. Here's a msgbox function that works the same as the built in one, only it will adjust the flag to the correct value if you make a mistake.

expandcollapse popup

$ret = _MsgBox(4095, 'Test', 'Always a Valid Flag')
ConsoleWrite($ret & @LF)

Func _MsgBox($iFlag, $sTitle, $sText, $iTimeout = Default, $Hwnd = Default)

     If Not _VerifyMsgBoxFlag($iFlag) Then
          ;check if off by 1 number in either direction
          $iFlag += 1
          If Not _VerifyMsgBoxFlag($iFlag) Then $iFlag -= 2
          ;if still no good then increase flag until we hit a valid one
          While Not _VerifyMsgBoxFlag($iFlag)
               $iFlag += 1
               ;safeguard to prevent a possible infinite loop (799669=all flags added)
               If $iFlag = 799669 Then $iFlag = 0
          WEnd
     EndIf

     Return MsgBox($iFlag, $sTitle, $sText, $iTimeout, $Hwnd)

EndFunc

Func _VerifyMsgBoxFlag($iFlag)

     Static Local $aValid = StringSplit('1,2,3,4,5,6,16,32,48,64,256,512,4096,8192,262144,524288', ',')
     Local $iBackup = $iFlag

     ;For each valid flag, subtract it from the original flag
     ;if its a combination of valid flags the end value should be 0
     For $i = 1 To $aValid[0]
          If BitAND($iFlag, $aValid[$i]) Then $iFlag -= $aValid[$i]
     Next

     If Not $iFlag Then
          ;but heres an exception, your flag includes 1+2+4. These are all valid flags, but conflict with each other
          If BitAND(1, $iBackup) And BitAND(2, $iBackup) And BitAND(4, $iBackup) Then Return False
          ;otherwise its ok
          Return True
     Else
          ;Flag is positive so its invalid
          Return False
     EndIf

EndFunc   ;==>_VerifyMsgBoxFlag

Edited January 31, 2012 by Beege

[guinness]

Guinness, I think that last part would need to an Else statement, otherwise it just gets written over.

Don't know how I missed that. Thanks. (Updated my post.)

Following on from what Melba posted I too created some code to automate the process of finding the latest command and adding to SciTE directly.

[Beege]

NICE!

[guinness]

I like your previous update of _MsgBox too.

[Beege]

Thanks. I'm certainly not going to ask, but I kinda wish the real msgbox function did something like this rather than do nothing.

[Melba23]

Beege,

I am almost certain of the answer you would get: "It is the user's responsibility to make sure that parameters are valid and in the correct order."

And I can sympathise with that point of view. Can you imagine the reduction in speed if every AutoIt function was checked at run-time for the validity of the parameters? It would hardly be worth installing. At least we have Au3Check to give the code a pretty good once-over - it has helped me more times than I care to remember.

M23

P.S. Glad you like the "adding to SciTE" post - I will add it as a Wiki tutorial.

Edited January 31, 2012 by Melba23
Added P.S.

[guinness]

I am almost certain of the answer you would get: "It is the user's responsibility to make sure that parameters are valid and in the correct order."

And how much "hand holding" should there be in AutoIt?

[Beege]

I am almost certain of the answer you would get: "It is the user's responsibility to make sure that parameters are valid and in the correct order."

Oh I'm certain your right! Thats why I added how I'm certainly not going to ask for it.

At least we have Au3Check to give the code a pretty good once-over - it has helped me more times than I care to remember.

Oh ya! For me its more like thank god for Au3Check. I shutter to even think about life with out it. I'm probably looking at 1/5 runs. Those parentheses. ;)

P.S. Glad you like the "adding to SciTE" post - I will add it as a Wiki tutorial.

Alright! Good idea

[Chimaera]

And how much "hand holding" should there be in AutoIt?

Lots because you have such warm hands ...

[emendelson]

Thank you again - this time for the tutorial on adding the code to SciTE, and also for the _MsgBox function.

One reason I asked for this is that most of my MsgBoxes have six-digit numbers for their first parameter, and errors aren't exactly obvious when I look at them. The only way I found the mistake was by going through thirty or forty backup versions saved by SciTE until I found a backup version that worked correctly, and then I used a word-processor to compare the two versions and that let me see where I had changed a number incorrectly. This will be a lot more effective!

[Melba23]

emendelson,

I always show the various style values added (i.e. 4 + 16 + 262144) rather than use a single value - at least when developing. Makes the odd wrong digit stand out a bit better.

M23

[Chimaera]

emendelson

If your using similar styles throught the code then make them into a variable

$MsgBoxStyle1 = 4 + 16 + 262144

then you set it once and let the code do the rest, and 5 msgbox styles will be easier to watch than lots of msgboxes

[BrewManNH]

Magic numbers are evil

You should be using variables if you're using the same number a lot, like Chimaera said above.

[emendelson]

You should be using variables if you're using the same number a lot, like Chimaera said above.

You're right <slap on forehead>. This should have been obvious to me, but it wasn't. This forum is like a free university. Thank you!

[emendelson]

A question for Melba23:

If I want to add Guinness's code (in message #14) to SciTE, I've got one problem I don't know how to solve. As you see from the code, it requires me to enter the name of a script in this line:

Global $aArray = _CheckMsgBox("Example.au3")

But of course if I compile it, I will only be able to check "Example.au3" with the compiled version.

Is there a parameter that I should use in place of "Example.au3" that will let SciTe use the code to test the currently-opened file?

Thanks again for your help on this, and I apologize for asking for more!

[Beege]

I think the command in Scite would need to be:

command.35.$(au3)="$(SciteDefaultHome)SciTE UtilsUtility.exe" "$(FilePath)"

Then in AutoIt:

Global $aArray = _CheckMsgBox($CMDLINE[1])

Edited February 1, 2012 by Beege

[emendelson]

Thanks again: with Beege's revision to Melba23's instructions, I was able to add a MsgBox Checker to my SciTE Tools menu. This is ideal.

One suggestion for any instructions posted on the wiki: When I opened the User Options File, it was completely blank - it didn't have the lines that Melba23 told me to look for. So I simply pasted in the commands that Melba23 said to paste in (with Beege's revision), and it worked perfectly. So it might be worth mentioning that it's OK if the file is completely blank.

This is very good to know. Many thanks!

Edited February 1, 2012 by emendelson

[guinness]

I'll update my previous code for those who follow in your footsteps & the file Melba was talking about is correct, mine is blank as well.

[Beege]

Thanks again: with Beege's revision to Melba23's instructions, I was able to add a MsgBox Checker to my SciTE Tools menu. This is ideal.

One suggestion for any instructions posted on the wiki: When I opened the User Options File, it was completely blank - it didn't have the lines that Melba23 told me to look for. So I simply pasted in the commands that Melba23 said to paste in (with Beege's revision), and it worked perfectly. So it might be worth mentioning that it's OK if the file is completely blank.

This is very good to know. Many thanks!

ohh its not User Options File, its au3.properties. Which is under the same Options menu.

[emendelson]

ohh its not User Options File, its au3.properties. Which is under the same Options menu.

I was following these instructions, which say to look in au3.properties for the line number (35 in this case), but then actually to add the new lines to User Options:

- Open <Options - Open au3.properties>. Look for the long series of "command" lines that begin about Line 64 (#x 00 Beta RUN) and go down to the last one - for me it is Line 277 (#~ # 34 Generate UDF header). You need to find the highest value used so far - 34 in my case.
- Open <Options - User Options File>. Then BETWEEN the following lines:
# END => DO NOT CHANGE ANYTHING BEFORE THIS LINE #-#-#-#-#-#
>>>>>>>>>>> in here!!!! <<<<<<<<<<<<<
#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
# START: DO NOT CHANGE ANYTHING AFTER THIS LINE #-#-#-#-#

Those instructions work. If I change au3.properties, won't it be overwritten by any new version of the software? Or am I completely wrong??

Edited February 1, 2012 by emendelson