[Solved] - GUIRegisterMsg WM_SIZE run function after resize complete.

[Mikeman27294]

Hello everyone.

I want to run a function when a GUI window is resized. However, when I click to resize the GUI, before I actually drag the corner of the GUI it runs and prevents me from resizing the GUI. I was hoping that I would be able to make this message run once the GUI has finished running. Would this be possible?

Thanks

Edit

I have solved it. The answer:

GUISetOnEvent($GUI_EVENT_RESIZED, 'WM_SIZE', $hWnd)

Edited January 21, 2012 by Mikeman27294

[Melba23]

Mikeman27294,

There is almost certainly a "finished resizing" message you can intercept - but you can easily do it with WM_SIZE in this way:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; Clear the flag
Global $fResized = False

$hGUI = GUICreate("Test", 500, 500, Default, Default, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))

GUISetState()

GUIRegisterMsg($WM_SIZE, "_WM_SIZE")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; If the flag is set
    If $fResized Then
        MsgBox(0, "Hi", "Now you can run your function")
        ; Clear the flag again
        $fResized = False
    EndIf

WEnd

Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)

    ; Set the flag
    $fResized = True

    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_SIZE

Will that do?

M23

[Melba23]

Mikeman27294,

There is indeed a "finished resizing" message - and it is very easy to trap:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; Clear the flag
Global $fResized = False

$hGUI = GUICreate("Test", 500, 500, Default, Default, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_RESIZED ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            MsgBox(0, "Hi", "Now you can run your function")
    EndSwitch

WEnd

M23

[Mikeman27294]

Thanks.

How would I do this with Gui Event Mode though?

[Melba23]

Mikeman27294,

Are you serious?

If you are already coding in OnEvent mode you must know how to trap GUI events - and this is an event just like $GUI_EVENT_CLOSE. What do you do to trap that?

M23

[Mikeman27294]

GuiOnEvent($GUI_EVENT_CLOSE, "_Exit")

I am still learning to trap messages. I have already learned a fair bit and have impressed myself with what I have learned so far (thankyou help file hahaha) but I was just having that 1 trouble and couldnt find anything in the windows messages lookup in the help file for it.

EDIT

Well I have figured it out. Thanks.

The answer is in the first post.

Edited January 21, 2012 by Mikeman27294

[Melba23]

Mikeman27294,

Good for you!

M23

[Mikeman27294]

And thanks for the help. Without it I wouldn't have figured it out. I didn't now about the GUI Event GUI_EVENT_RESIZED.