Converting user input colors

[kw_rock]

Hey guys! I have been doing tons of searching and I have come up with bits and pieces but nothing very useful!

I want something to convert colors for me in AutoIT. Pixel searchs and such either return Hex or Decimal values.. so I want it to convert RGB to decimal.

Basically, I want an input box that pops up with 3 slots, one for red, green and blue.

Then, I want the script to convert the string as a whole into decimal and/or hex.

I've found a lot of functions for different color related things, but none of them for decimal

Any help would be appreciated guys!

[funkey]

#include <COLOR.AU3>
_ColorGetRed
_ColorGetBlue
_ColorGetGreen

Just use Int() or Hex() to show values as wanted.

Edited January 12, 2012 by funkey

[GEOSoft]

_ColorGetRGB() returns an array of the values. It's in the help file.

[kw_rock]

I understand that, i've looked over the help file.

However, i'm still not having luck. Everything is related to converting Hex to things not converting things to hex. I've tired multiple functions and still haven't gotten anywhere CLOSE to my objective.

If _ColorGetRGB() returns an array of the values... I want the user to enter in an RGB value and have the Hex/Dec returned, not convert a Hex to RGB

I found this somewhere, but once again it's the opposite of what I want.

$nColor = 0xAABB0A
$Blue = BitAND($nColor, 0xFF)
$Green = BitAND(BitShift($nColor, 8), 0xFF)
$Red = BitAND(BitShift($nColor, 16), 0xFF)

ConsoleWrite("Red: " & $Red & " Green: " & $Green & " Blue: " & $Blue & @CRLF)

Report

Honestly, all I want is something like:

$RGB = InputBox("RGB to Hex/Dec", "Enter RGB", "")

$RGB = Hex($RGB)

I am not asking for someone to type out the whole code.. just give me a little more than a function to use because I generally don't understand the descriptions they give in the help file

Edited January 12, 2012 by kw_rock

[BrewManNH]

Look at _ColorSetRGB, that will convert the 3 color values Red, Green, and Blue to a Decimal number. You can use either Hex representations of the 3 numbers or decimal or any combination of the 2 when you send it to that function.

This script was modified from the example script in the help file for _ColorSetRGB that shows what I mean. If you run it in SciTe you can see the value returned by the function in the console output pane of the editor.

#include <Color.au3>

Dim $aColor[3] = [0x80, 0x90, 255] ; I changed the last value from 0xff to the decimal equivalent to show that it works with both.

$nColor = _ColorSetRGB($aColor)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $nColor = ' & $nColor & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
MsgBox(4096, "AutoIt", " Red=" & Hex($aColor[0], 2) & " Blue=" & Hex($aColor[1], 2) & " Green=" & Hex($aColor[2], 2) & @CRLF & _
        "Color=" & Hex($nColor))

[kw_rock]

Amazing!!

Thank you very much!

[Malkey]

Here are another three methods of converting the three colour values to a RGB colour.

Note the ease of of identifying RGB colours in 0xRRGGBB hexadecimal format.

e.g. 0x0000FF if blue (blue color channel is full); 0xFF0000 is red (red color channel is full); 0x000000 if black (no color in any of the color channels); 0xFFFFFF is white (all color channels are full).

Local $red = 0x80
Local $green = 0x90
Local $blue = 255

ConsoleWrite("The three color channels are:-" & @LF)
ConsoleWrite("red   = 0x" & Hex($red, 2) & " or " & $red & "; " & @LF)
ConsoleWrite("green = 0x" & Hex($green, 2) & " or " & $green & "; " & @LF)
ConsoleWrite("blue  = 0x" & Hex($blue, 2) & " or " & $blue & "; " & @LF)

;---  Using String to number - color channels to color --------------
Local $color = Execute("0x" & Hex($red, 2) & Hex($green, 2) & Hex($blue, 2)) ; Use either Execute(), Int(), or Number() function.
ConsoleWrite("RGB Color Execute String" & @TAB & "0x" & Hex($color, 6) & " or " & $color & @LF)

;--- Multiply & Add color channels together to get color ------------
Local $colorAddMulti = ($red * 0x10000 + $green * 0x100 + $blue)
ConsoleWrite("RGB Color Add/Multiply  " & @TAB & "0x" & Hex($colorAddMulti, 6) & " or " & $colorAddMulti & @LF)

; --- Using Bit operators - color channels to color ----------------
Local $colorBitWise = BitOR(BitShift(($red), -16), BitShift(($green), -8), ($blue))
ConsoleWrite("RGB Color Bit operations" & @TAB & "0x" & Hex($colorBitWise, 6) & " or " & $colorBitWise & @LF)

#cs
    Output:-
    The three color channels are:-
    red   = 0x80 or 128;
    green = 0x90 or 144;
    blue  = 0xFF or 255;
    RGB Color Execute String    0x8090FF or 8425727
    RGB Color Add/Multiply      0x8090FF or 8425727
    RGB Color Bit operations    0x8090FF or 8425727
#ce