Kill other running instances of same compiled script?

emendelson · January 3, 2012

Hello,

I'm writing a script that, in some circumstances, fails to exit properly, and continues to run as a subprocess of two or more separate instances of CMD.EXE. Until I figure out why that occurs, I want to add a function to the script that kills all other running instances of the same program.

Starting with the excellent and efficient code here:

I've put together this:

_ProcessCloseOtherEx(@ScriptName)

Func _ProcessCloseOtherEx($sPID)
If IsString($sPID) Then $sPID = ProcessExists($sPID)
If Not $sPID Then Return SetError(1, 0, 0)
If $sPID <> @AutoItPID Then
  Return Run(@ComSpec & " /c taskkill /F /PID " & $sPID & " /T", @SystemDir, @SW_HIDE)
Else
  Return
EndIf
EndFunc   ;==>_ProcessCloseOtherEx

As far as I can tell, this seems to work. But I can't figure out a way to make it close more than one other running instance, in case two or more other instances are already running when this one starts. I realize that it shouldn't happen that two instances can be running, but weird things can happen.

I can see that the function needs a While/Wend loop, but I haven't been able to write one that works.

I realize that this is a beginner's question, and I'll be very grateful for any help.

Edited January 3, 2012 by emendelson

jaberwacky · January 3, 2012

Let's try recursion:

_ProcessCloseOtherEx(@ScriptName)

Func _ProcessCloseOtherEx($sPID)
    If IsString($sPID) Then $sPID = ProcessExists($sPID)
    
    If Not $sPID Then Return SetError(1, 0, 0)
    
    If $sPID <> @AutoItPID Then
        Run(@ComSpec & " /c taskkill /F /PID " & $sPID & " /T", @SystemDir, @SW_HIDE)
        _ProcessCloseOtherEx($sPID)
    Else
        Return
    EndIf
EndFunc   ;==>_ProcessCloseOtherEx

Note: Untested. If you're CPU asplodes then I am absolved of all responsibility. I had my lawyer write that.

Edit: My lawyer can't spell.

Edited January 3, 2012 by LaCastiglione

guinness · January 3, 2012

It's highly unlikely but that could cause a recursion error. Why not use ProcessList instead?

jaberwacky · January 3, 2012

How can you have any fun if you don't take chances?

emendelson · January 3, 2012

Let's try recursion:
....
Note: Untested. If you're CPU asplodes then I am absolved of all responsibility. I had my lawyer write that.
Edit: My lawyer can't spell.

Thanks for trying to solve this. My CPU didn't explode when I used this function with another instance of the program already running, but I did need to do a hard reset to get out of the recursion. I couldn't even bring up the task manager - although I was able to save all open files.

Maybe that's what's meant by "asploding"? ;-)

Edited January 3, 2012 by emendelson

emendelson · January 3, 2012

Why not use ProcessList instead?

That sounds like what I would need to do, but unfortunately I'm too much of a beginner to figure it out. Maybe something like this, but clearly I've got this all wrong:

Local $list = ProcessList()
For $i = 1 To $list[0][0]
    If $list[$i][1] = @ScriptName Then
       If $list[$i][1]<> @AutoItPID Then
         ; Kill process
       EndIf
    EndIf
Next

Thanks again for any help.

BrewManNH · January 3, 2012

You'd want to use something like this:

If $list[$i][0] = @ScriptName Then

Rather than $list[$i][1].

Exit · January 3, 2012

I've writtten an #include file which kills all instances of the script (compiled or not compiled).

;===============================================================================
;
; UDF Name:   _SingleScript.au3
; Description::  close all running scripts with the same name.
; Usage:   #include "_SingleScript.au3"
; Parameter(s):  none
; Requirement(s): none
; Return Value(s): 0
; COPYLEFT:   © 25.05.2008 Freeware
;    ALL WRONGS RESERVED
;
;===============================================================================
;
__SingleScript()
Func __SingleScript()
Local $OI, $O = ObjGet("winmgmts:" & @ComputerName & "rootCIMV2"), $CI = $O.ExecQuery("SELECT * FROM Win32_Process", "WQL", 0x30)
For $OI In $CI
  If $OI.ProcessId = @AutoItPID Then ContinueLoop
  If $OI.Name = StringTrimRight(@ScriptName, 4) & ".EXE" Or ($OI.Name = "AutoIt3.exe" And StringInStr($OI.CommandLine, StringTrimRight(@ScriptName, 4) & ".au3")) Then ProcessClose($OI.ProcessId)
Next
EndFunc   ;==>__SingleScript

OK, there might be a faster way without WMI, but .... those microseconds for one script don't bother me. :-)

The trick is, that the code is called within the include file.

Just put the above code in a file called _singlescript.au3

and put the line

#include '_singlescript.au3'

in front of your script.

Edit: Typo

Edited January 3, 2012 by forumer100

guinness · January 3, 2012

Something along these lines >>

_ProcessCloseRunning()

Func _ProcessCloseRunning()
    Local $aArray = ProcessList(@ScriptName)
    For $i = 1 To $aArray[0][0]
        If $aArray[$i][1] = @AutoItPID Then
            ContinueLoop
        EndIf
        $aArray[$i][0] = ProcessClose($aArray[$i][1])
    Next
    Return $aArray
EndFunc   ;==>_ProcessCloseRunning

emendelson · January 3, 2012

You'd want to use something like this:

If $list[$i][0] = @ScriptName Then

Rather than $list[$i][1].

Aha! Thank you!

emendelson · January 3, 2012

I've writtten an #include file which kills all instances of the script (compiled or not compiled).
...

That's elegant and complete - and perfect for testing purposes, so I don't have to compile, then test, compile then test, etc.

Thank you!!

Edited January 3, 2012 by emendelson

masvil · December 10, 2012

It works great, thank you!

BattleVena · November 6, 2013

Hello

When I try to run the _SingleScript.au3 I get an error creating object.

I included this statement to identify an error

Func __SingleScript()
Local $OI, $O = ObjGet("winmgmts:" & @ComputerName & "rootCIMV2")
If @error Then
MsgBox(0, "Object Test", "Error Getting an Active Object. Error code: " & Hex(@error, 8))
Exit
EndIf
$CI = $O.ExecQuery("SELECT * FROM Win32_Process", "WQL", 0x30)

the error number is 80041002

I am not sure what is means and why it is failing on my machine. I have updated autoit and scite to the latest version. Running under win7 x64.

Is there some type of service that needs to be enabled? Any help is appreciated.

Carlo84 · November 7, 2013

Use that handy hidden window every script has :-) your script cannot exist without it.

Func _KillOtherScript()
    Local $i = Opt('WinTitleMatchMode', 3)
    If WinExists(@ScriptFullPath) Then
        Local $hWnd = WinGetHandle(@ScriptFullPath)
        WinClose($hWnd)
    EndIf
    AutoItWinSetTitle(@ScriptFullPath)
    Opt('WinTitleMatchMode', $i)
EndFunc   ;==>_KillOtherScript





















;

Edited November 7, 2013 by Djarlo

BattleVena · November 7, 2013

Doesn't seem to work, I can create as many instances of the process as I want

#include <Date.au3>
$t = _NowTime(3)

_KillOtherScript()

MsgBox(0,"Testing Run Once",$t,60)
sleep(1000)

Func _KillOtherScript()

    Local $i = Opt('WinTitleMatchMode', 3)

    If WinExists(@ScriptFullPath) Then
        MsgBox(0,"Killing Previous Instance",$t,60)
        Local $hWnd = WinGetHandle(@ScriptFullPath)

        WinClose($hWnd)

    EndIf

    AutoItWinSetTitle(@ScriptFullPath)

    Opt('WinTitleMatchMode', $i)

EndFunc   ;==>_KillOtherScript

Edited November 7, 2013 by BattleVena

Carlo84 · November 7, 2013

msgboxes pause script execution, use a proper loop

_KillOtherScript()
 Func _KillOtherScript()
    Local $i = Opt('WinTitleMatchMode', 3)
    If WinExists(@ScriptFullPath) Then
        Local $hWnd = WinGetHandle(@ScriptFullPath)
        WinClose($hWnd)
    EndIf
    AutoItWinSetTitle(@ScriptFullPath)
    Opt('WinTitleMatchMode', $i)
EndFunc   ;==>_KillOtherScript
While 1
    Sleep(100)
WEnd

Edited November 7, 2013 by Djarlo

BattleVena · November 7, 2013

The script I am killing has build in pause. This one works although needs to be compiled.

#include <Date.au3>
$t = _NowTime(3)

_KillOtherScript()

MsgBox(0,"Testing Run Once",$t & " " & @AutoItPID  ,60)

func _KillOtherScript()
    Local $list = ProcessList()
    For $i = 1 To $list[0][0]
        If $list[$i][0] = @ScriptName Then
           If $list[$i][1]<> @AutoItPID Then
                ; Kill process
                $r=ProcessClose($list[$i][1])
           EndIf
        EndIf
    Next
EndFunc

Edited November 7, 2013 by BattleVena

Exit · November 7, 2013

Hello

When I try to run the   _SingleScript.au3 I get an error creating object.

I included this statement to identify an error

Func __SingleScript()
Local $OI, $O = ObjGet("winmgmts:" & @ComputerName & "rootCIMV2")
If @error Then
    MsgBox(0, "Object Test", "Error Getting an Active Object. Error code: " & Hex(@error, 8))
    Exit
EndIf
$CI = $O.ExecQuery("SELECT * FROM Win32_Process", "WQL", 0x30)

the error number is 80041002

I am not sure what is means and why it is failing on my machine. I have updated autoit and scite to the latest version. Running under win7 x64.

Is there some type of service that needs to be enabled? Any help is appreciated.

Error Code 80041002 - Object Not Found

Try to start WMI in command prompt:

net start Winmgmt

Please check if WMI is enabled. For more info see:

http://computerstepbystep.com/windows_management_instrumentation_service.html

Edited November 7, 2013 by Exit

Sign In

Kill other running instances of same compiled script?

Recommended Posts

emendelson

jaberwacky

guinness

jaberwacky

emendelson

emendelson

BrewManNH

Exit

guinness

emendelson

emendelson

masvil

BattleVena

Carlo84

BattleVena

Carlo84

BattleVena

Exit

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta