Notify - New version 17 Mar 22

[mLipok]

It would be nice if the script were able to detect the primary screen, and show the notifications on the primary screen.

or on secondary, it should be possible to choose.

 

[legend]

or on secondary, it should be possible to choose.

 

Yes, that would be the best solution, where we could chose with maybe a flag, if it's the primary or secondary, or even a third screen maybe?

[Melba23]

legend,

Does the _Notify_Locate function (which lets you choose the right or left hand side of your monitor setup for the notifications) not suffice?

M23

[Deye]

hi Melba,
hope you are well

made a small bug report:

1. using _Notify_Locate(3) - left hand side of the monitor
The notify box leaves a print when exits

2. When using right click on desktop for selecting the screen resolution
And changing "make text and other items smaller or bigger"

Using largest or medium the notify boxes don't act or look well

I made it work and look better using this function
maybe you would like to test this or add something you have to make it play nicely
on note: using this with multiple Notify boxes displaying, it wont look well (spacing problem..).

Global $a1 = _GetDPI(), $iDPI = $a1[1], $iDPIRat = $a1[2]

  Local $iNotify_Width_max = 300 * $iDPIRat
  Local $iNotify_Width_min = 150 * $iDPIRat
  Local $iNotify_Height = 40* $iDPIRat
  
Func _GetDPI()
  Local $a1[3]
  Local $iDPI, $iDPIRat, $Logpixelsy = 90, $hWnd = 0
  Local $hDC = DllCall("user32.dll", "long", "GetDC", "long", $hWnd)
  Local $aRet = DllCall("gdi32.dll", "long", "GetDeviceCaps", "long", $hDC[0], "long", $Logpixelsy)
  $hDC = DllCall("user32.dll", "long", "ReleaseDC", "long", $hWnd, "long", $hDC)
  $iDPI = $aRet[0]
  Select
    Case $iDPI = 0
      $iDPI = 96
      $iDPIRat = 94
    Case $iDPI < 84
      $iDPIRat = $iDPI / 105
    Case $iDPI < 121
      $iDPIRat = $iDPI / 96
    Case $iDPI < 145
      $iDPIRat = $iDPI / 95
    Case Else
      $iDPIRat = $iDPI / 94
  EndSelect
  $a1[0] = 2
  $a1[1] = $iDPI
  $a1[2] = $iDPIRat
  Return $a1
EndFunc   ;==>_GetDPI

Thanks

[Melba23]

Deye,

You will hardly be surprised to learn that I cannot reproduce that "shadow" effect with _Notify_Locate(3) in my own example script. And as I have to ask you each time you report something, can you please post the exact code you used when this problem occurred so that I can see if there is anything I can spot which might give me a clue as to why it is happening for you.

And while I understand that changing the DPI settings mess with the GUI, I have no intention of making the UDF DPI aware. As you point out, it is not a trivial task to modify the entire UDF and as you are the first to report this difficulty I can only imagine that most people leave the setting at the standard 100% where the UDF works well.

M23

[Deye]

Melba,

thanks for taking an interest with the problem but I don't think its coming from your code
This happens only when running on Hebrew UI whether locate is right or left
Tested on vm on English UI there is no problem ..

As to dpi , its easy to reproduce and partly get it fixed using the steps I described
Its all OK

thanks again

Deye

[Deye]

Hi Melba,

aka request:

id like to make a box functional as a progress bar too
or a thin one matching to the length of the second line of text, and just under it.
  

aka reports:

as to

$iNotify_Width_max

i think it would be better to have something to override this value
so one can simply use (for the box\margins sizes)
"     short     " 
" shortness "
and so boxes stay equal in size too

_Notify_Show(64, "","    short    ", 0, 1, -500, -1000)

the reason I'm suggesting this..on some tests on large dpi the box wouldn't appear
i thought having this as a value may have caused the problem ..
but I have successfully managed the problem after all.

Thanks

Deye
 

[Melba23]

Deye,

Request: I am not interested in adding a progress bar, sorry. These are notifications of a specific event rather than marking an on-going process - my Toast UDF will let you do that.

Report: Overriding the max width should not be a problem, but I have no idea what you mean by:

Quote

"     short     " 
" shortness "

as a way of setting the width. Can you explain in more detail?

And I have no intention of dealing with different DPI settings - that is a user problem as far as I am concerned.

M23

 

[Deye]

Melba,

Cool, will surly check out your Toast UDF didn't know that it had that option

38 minutes ago, Melba23 said:

as a way of setting the width

yes, to avoid the need for maximum or minimum sizes and so padding the text with spaces can parameter the final box's Width.

Thanks again

Deye

[Deye]

Hi Melba , 

I wanted to start notify in two or more single processes:

 

so when a newer pid (same process name) starts it will show above the previous notify window like in Notify_Example_3.au3

The idea is to automatically preset coords of each window by pid - the first\newer pid - (a new window) - above the previous  (also to possibly avoid racing condition when two or more processes start in the same time ..)

I don't really need the windows going downwards when where other previous windows exits (though it will still be cool) ,  as I'll be using one window coords per process

BTW, with each new process started:  which variable controls the coords that creates a new window but above the seemingly previous one ?   (in the UDF)

Any other advice to help simplify this idea is most welcome

Thanks In Advance

Deye

[Melba23]

Deye,

Why not use the _Notify_Locate function so that the processes use different locations for their notifications? Or create a helper script using the UDF which is informed when each of the other scripts requires it to produce a notification? I think that either of those solutions would be simpler that trying to adjust the UDF to deal with double inputs.

M23

[Deye]

Hey Melba,

I'm trying to adjust notify with this function to show up on the same screen as "My Window" is at .
Of course this isn't the correct way of getting this done, As it only works as long as monitor 1 is configured to be on the left but not the other way
when the extended monitor is on the left then the left coord is a - negative < 0 number, and when on the right the number grows from the right's main screen ..
If you don't mind helping mode this correctly ..(if you are not using dual monitors ..I Can test)

TIA

$iExtreme = _ScreenFromHWnd(WinGetHandle("My Title", "")) ; Furthest left/right edge found so far

....

Func _ScreenFromHWnd($hWnd)
    Local $hDisplay = _WinAPI_MonitorFromWindow($hWnd)
    Local $tRect = _WinAPI_GetMonitorInfo($hDisplay)
    Return DllStructGetData($tRect[1], 'Left').
EndFunc

 

[Melba23]

Deye,

The UDF already checks for the screen limits and should pick the edges automatically. Are you using _Notify_Locate at the top of your script to allow the UDF to determine where they are?

M23

[Deye]

My _Notify_Locate settings are set to default .. bottom\Right

You mean to say that _Notify_Locate options are bound to left and right top and bottom as if 2 screens are one (screen) ?
If not, can you give an example ..Because I really didn't find any options for choosing a dedicated screen 

with my example if my desktop is on monitor 2 and monitor 1 is on the left to it, when launched from monitor 1 the notification shows to the right\bottom of monitor 1 not 2 (by default) .. (in the middle of both on monitor 1)

[Melba23]

Deye,

Can you please run this and post the result:

expandcollapse popup

#include <WinAPISys.au3>
#include <WinAPIGdi.au3>

_Notify_Locate_Test(0)
_Notify_Locate_Test(1)
_Notify_Locate_Test(2)
_Notify_Locate_Test(3)

Func _Notify_Locate_Test($iLocation = 0)

    ; Look for monitors
    Local $aEDM = _WinAPI_EnumDisplayMonitors()
    If @error Then Return SetError(3, 0, 0)
    Local $aCoords[$aEDM[0][0] + 1][4], $hDisplay, $tRect, $iIndex
    ; Get get coords for each monitor
    For $i = 1 To $aEDM[0][0]
        $hDisplay = $aEDM[$i][0] ; 1 for first handle, 2 for second
        $tRect = _WinAPI_GetMonitorInfo($hDisplay)
        If @error Then Return SetError(3, 0, 0)
        $aCoords[$i][0] = DllStructGetData($tRect[1], 'Left')
        $aCoords[$i][1] = DllStructGetData($tRect[1], 'Top')
        $aCoords[$i][2] = DllStructGetData($tRect[1], 'Right')
        $aCoords[$i][3] = DllStructGetData($tRect[1], 'Bottom')
    Next

    ; Determine which monitor will display notifications
    Local $iExtreme = (($iLocation > 1) ? (1000) : (0)) ; Set initial value to be adjusted as necessary

    For $i = 1 To UBound($aCoords) - 1
        ; Depending on location, look for leftest/rightest monitor edge
        Switch $iLocation
            Case 0, 1
                If $aCoords[$i][2] > $iExtreme Then
                    $iExtreme = $aCoords[$i][2] ; Furthest left/right edge found so far
                    $iIndex = $i ; Index of associated monitor
                EndIf
            Case 2, 3
                If $aCoords[$i][0] < $iExtreme Then
                    $iExtreme = $aCoords[$i][0]
                    $iIndex = $i
                EndIf
        EndSwitch
    Next

    ; Adjust data array depending on required location
    Switch $iLocation
        Case 0
            ConsoleWrite("0 ; From bottom right:" & @CRLF & _
                    $aCoords[$iIndex][3] - 10 & " ; bottom Y" & @CRLF & _
                    $aCoords[$iIndex][2] - 10 & " ; right X" & @CRLF)
        Case 1
            ConsoleWrite("1 ; From top right" & @CRLF & _
                    $aCoords[$iIndex][1] + 10 & " ; top Y" & @CRLF & _
                    $aCoords[$iIndex][2] - 10 & " ; right X" & @CRLF)
        Case 2
            ConsoleWrite("2 ; From top left" & @CRLF & _
                    $aCoords[$iIndex][1] + 10 & " ; top Y" & @CRLF & _
                    $aCoords[$iIndex][0] + 10 & " ; left X" & @CRLF)
        Case 3
            ConsoleWrite("3 ; From bottom left" & @CRLF & _
                    $aCoords[$iIndex][3] - 10 & " ; bottom Y" & @CRLF & _
                    $aCoords[$iIndex][0] + 10 & " ; left X" & @CRLF)

    EndSwitch

    ConsoleWrite(@CRLF)

EndFunc   ;==>_Notify_Locate_Test

M23

[Deye]

main desktop on  monitor 2 / monitor 1 to the left
---------------------------------------------------------------------------
0 ; From bottom right:
1030 ; bottom Y
1910 ; right X

1 ; From top right
10 ; top Y
1910 ; right X

2 ; From top left
190 ; top Y
-1430 ; left X

3 ; From bottom left
1070 ; bottom Y
-1430 ; left X

main desktop on  monitor 2 / monitor 1 to the right
----------------------------------------------------------------------------
0 ; From bottom right:
1070 ; bottom Y
3350 ; right X

1 ; From top right
190 ; top Y
3350 ; right X

2 ; From top left
10 ; top Y
10 ; left X

3 ; From bottom left
1030 ; bottom Y
10 ; left X
 

Edited June 1, 2017 by Deye

[Melba23]

Deye,

Those values are about what I would have expected - the UDF searches for the edges of the available display area. Try this code which allows you to define a monitor rather than the UDF looking at the whole area:

expandcollapse popup

#include <WinAPISys.au3>
#include <WinAPIGdi.au3>

_Notify_Locate_Test(0, 1)
_Notify_Locate_Test(1, 1)
_Notify_Locate_Test(2, 1)
_Notify_Locate_Test(3, 1)

_Notify_Locate_Test(0, 2)
_Notify_Locate_Test(1, 2)
_Notify_Locate_Test(2, 2)
_Notify_Locate_Test(3, 2)

Func _Notify_Locate_Test($iLocation = 0, $iForceMonitor = 0)

    ; Look for monitors
    Local $aEDM = _WinAPI_EnumDisplayMonitors()
    If @error Then Return SetError(3, 0, 0)
    Local $aCoords[$aEDM[0][0] + 1][4], $hDisplay, $tRect, $iIndex = $iForceMonitor
    ; Get get coords for each monitor
    For $i = 1 To $aEDM[0][0]
        $hDisplay = $aEDM[$i][0] ; 1 for first handle, 2 for second
        $tRect = _WinAPI_GetMonitorInfo($hDisplay)
        If @error Then Return SetError(3, 0, 0)
        $aCoords[$i][0] = DllStructGetData($tRect[1], 'Left')
        $aCoords[$i][1] = DllStructGetData($tRect[1], 'Top')
        $aCoords[$i][2] = DllStructGetData($tRect[1], 'Right')
        $aCoords[$i][3] = DllStructGetData($tRect[1], 'Bottom')
    Next

    Switch $iForceMonitor
        Case 1 To $aEDM[0][0]
            ; Force monitor choice

        Case 0
            ; Determine which monitor will display notifications
            Local $iExtreme = (($iLocation > 1) ? (1000) : (0)) ; Set initial value to be adjusted as necessary

            For $i = 1 To UBound($aCoords) - 1
                ; Depending on location, look for leftest/rightest monitor edge
                Switch $iLocation
                    Case 0, 1
                        If $aCoords[$i][2] > $iExtreme Then
                            $iExtreme = $aCoords[$i][2] ; Furthest left/right edge found so far
                            $iIndex = $i ; Index of associated monitor
                        EndIf
                    Case 2, 3
                        If $aCoords[$i][0] < $iExtreme Then
                            $iExtreme = $aCoords[$i][0]
                            $iIndex = $i
                        EndIf
                EndSwitch
            Next

        Case Else
            ; Invalid monitor value
            Return SetError(1, 0, 0)
    EndSwitch

    ; Adjust data array depending on required location
    If $iForceMonitor Then
        ConsoleWrite("Monitor " & $iForceMonitor & " forced" & @CRLF)
    EndIf

    Switch $iLocation
        Case 0
            ConsoleWrite("0 ; From bottom right:" & @CRLF & _
                    $aCoords[$iIndex][3] - 10 & " ; bottom Y" & @CRLF & _
                    $aCoords[$iIndex][2] - 10 & " ; right X" & @CRLF)
        Case 1
            ConsoleWrite("1 ; From top right" & @CRLF & _
                    $aCoords[$iIndex][1] + 10 & " ; top Y" & @CRLF & _
                    $aCoords[$iIndex][2] - 10 & " ; right X" & @CRLF)
        Case 2
            ConsoleWrite("2 ; From top left" & @CRLF & _
                    $aCoords[$iIndex][1] + 10 & " ; top Y" & @CRLF & _
                    $aCoords[$iIndex][0] + 10 & " ; left X" & @CRLF)
        Case 3
            ConsoleWrite("3 ; From bottom left" & @CRLF & _
                    $aCoords[$iIndex][3] - 10 & " ; bottom Y" & @CRLF & _
                    $aCoords[$iIndex][0] + 10 & " ; left X" & @CRLF)

    EndSwitch

    ConsoleWrite(@CRLF)

EndFunc   ;==>_Notify_Locate_Test

That should allow you to get the values for a specific monitor. Please run it and post the results - I think it might solve your problem (and the request made by some other users a while back).

M23

[Deye]

expandcollapse popup

main desktop on  monitor 2 / monitor 1 to the left
---------------------------------------------------------------------------
Monitor 1 forced
0 ; From bottom right:
1030 ; bottom Y
1910 ; right X


Monitor 1 forced
1 ; From top right
10 ; top Y
1910 ; right X

Monitor 1 forced
2 ; From top left
10 ; top Y
10 ; left X

Monitor 1 forced
3 ; From bottom left
1030 ; bottom Y
10 ; left X

Monitor 2 forced
0 ; From bottom right:
1070 ; bottom Y
-10 ; right X

Monitor 2 forced
1 ; From top right
190 ; top Y
-10 ; right X

Monitor 2 forced
2 ; From top left
190 ; top Y
-1430 ; left X

Monitor 2 forced
3 ; From bottom left
1070 ; bottom Y
-1430 ; left X

main desktop on  monitor 2 / monitor 1 to the right
----------------------------------------------------------------------------
Monitor 1 forced
0 ; From bottom right:
1030 ; bottom Y
1910 ; right X

Monitor 1 forced
1 ; From top right
10 ; top Y
1910 ; right X

Monitor 1 forced
2 ; From top left
10 ; top Y
10 ; left X

Monitor 1 forced
3 ; From bottom left
1030 ; bottom Y
10 ; left X

Monitor 2 forced
0 ; From bottom right:
1070 ; bottom Y
3350 ; right X

Monitor 2 forced
1 ; From top right
190 ; top Y
3350 ; right X

Monitor 2 forced
2 ; From top left
190 ; top Y
1930 ; left X

Monitor 2 forced
3 ; From bottom left
1070 ; bottom Y
1930 ; left X

 

Edited June 2, 2017 by Melba23
Added code tags

[Melba23]

Deye,

That looks as if it worked - let me redesign the _Notify_Locate function and then we can try with the UDF.

M23

[Melba23]

Deye,

Try this Beta and specify the monitor on which you want to have the notifications displayed - you will need to use _Notify_Locate_Mod and not _Notify_Locate to do this: <snip>

 

M23

Edited June 4, 2017 by Melba23
Beta code removed