Notify - New version 17 Mar 22

[Melba23]

ringerl,

Try this:  

M23

Edited September 27, 2017 by Melba23

[conmed]

Hello Melba23,

I used your UDF ( Notify, Notify_Mod ) , I look very good. I want to know what differences there are between them.

And how I can there to increase the height of the notifications.

Thank you very much Melba,

Ariel

[Melba23]

conmed,

The difference is that the _Mod code will truncate a Notification title/text if it is too long to fit in the max allowed width rather then throw an error and not display at all like the current release code.

As explained several times in the thread, I am not interested in increasing the height of the notifications - they are designed for quick messages, not large blocks of data. The idea is that you can fit several on-screen at once, so increasing the height would reduce this number as they all need to be the same size - or at least I am not recoding the UDF to cater for variable sizes!

If you cannot get the message into 2 lines I suggest you use one of my other UDFs (ExtMsgBox or Toast) which do allow larger texts to be displayed.

M23

[conmed]

Thank you for answer, now I understand , you're right in the use of these notifications and now I see your other UDF , all are very good and especially useful for any design.

Thank you very much Melba23 ,

Conmed

[mLipok]

In the end, I need to look at the UDF.
Quite pretty

But my question is, how would cause many different programs displayed the notifications one over the other.
Ie. depending on who was the first to do its job then this will display a notification at the bottom of the screen, then a program that finished as the second task will display a notification above the last displayed notification, if the third program to exit this display, its notification to the last displayed notification, etc .....

 

Any concept how to do that together with this UDF ?

 

Best regards,

mLipok

 

 

Edited June 19, 2015 by mLipok

[Melba23]

mLipok,

I am not sure I entirely understand the question - so here are 2 approaches that might be useful.

- 1. Here the notifications appear as the tasks complete:

expandcollapse popup

#include "Notify.au3"

HotKeySet("{ESC}", "_Exit")

$nTask1 = TimerInit()
$nTask2 = TimerInit()
$nTask3 = TimerInit()

$iDelay1 = 1000 * Random(5, 20, 1)
$iDelay2 = 1000 * Random(5, 20, 1)
$iDelay3 = 1000 * Random(5, 20, 1)

While 1

    If $nTask1 Then
        If TimerDiff($nTask1) > $iDelay1 Then
            $nTask1 = 0
            _Notify_Show(0, "Task 1", "Completed")
        EndIf

    EndIf



    If $nTask2 Then
        If TimerDiff($nTask2) > $iDelay2 Then
            $nTask2 = 0
            _Notify_Show(0, "Task 2", "Completed")
        EndIf

    EndIf



    If $nTask3 Then
        If TimerDiff($nTask3) > $iDelay3 Then
            $nTask3 = 0
            _Notify_Show(0, "Task 3", "Completed")
        EndIf

    EndIf



WEnd



Func _Exit()
    Exit
EndFunc

The notifications automatically appear in the order of completion - but I think that you might want them to appear in their original numerical order.

- 2. So here is a way to do that - by changing the text inside the notifications once the task completes:

expandcollapse popup

#include "Notify.au3"

HotKeySet("{ESC}", "_Exit")

$nTask1 = TimerInit()
$nTask2 = TimerInit()
$nTask3 = TimerInit()

$iDelay1 = 1000 * Random(5, 20, 1)
$iDelay2 = 1000 * Random(5, 20, 1)
$iDelay3 = 1000 * Random(5, 20, 1)

$hNotify1 = _Notify_Show(0, "Task 1", "Running")
$hNotify2 = _Notify_Show(0, "Task 2", "Running")
$hNotify3 = _Notify_Show(0, "Task 3", "Running")

While 1

    If $nTask1 Then
        If TimerDiff($nTask1) > $iDelay1 Then
            $nTask1 = 0
            ControlSetText($hNotify1, "", "[CLASS:Static;INSTANCE:2]", "Task Completed")
        EndIf

    EndIf



    If $nTask2 Then
        If TimerDiff($nTask2) > $iDelay2 Then
            $nTask2 = 0
            ControlSetText($hNotify2, "", "[CLASS:Static;INSTANCE:2]", "Task Completed")
        EndIf

    EndIf



    If $nTask3 Then
        If TimerDiff($nTask3) > $iDelay3 Then
            $nTask3 = 0
            ControlSetText($hNotify3, "", "[CLASS:Static;INSTANCE:2]", "Task Completed")
        EndIf

    EndIf



WEnd



Func _Exit()
    Exit
EndFunc

Are either of those approaches what you require?

M23

[Melba23]

mLipok,

Any of the above of any use? If the second example is close to what you want I have also looked into how to change the content/colour of the notifications post-appearence and produced a Beta UDF which makes it very easy. Let me know if you are interested in testing.

M23

[mLipok]

Your examples are interesting, but not consistent with my idea.
So I will try to present this question again in a different way.

 

I have serveral script running as several separate windows processs.
I want to get possibility to show notyfication one above other , regardless of which process at any given time will show its notification.
If some process want to show notification , this notyfication message should open above all other allready opened/visible notification .

I hope now it is clear what I'm asking for.

Cheers,

mLipok

[Melba23]

mLipok,

You will need some form of inter-script communication to get these separate processes talking to the script producing the notifications. Once the notifications are triggered they will automatically appear one above the other in order as shown in the first example I posted above.

M23

[mLipok]

I see you are using:

  ControlSetText($hNotify1, "", "[CLASS:Static;INSTANCE:2]", "Task Completed")

 

after some more thinking about I think I can do it with ControlGetPos

But I must be sure That I know what Title and Text will be part of each message.

And then I will be able to us WinList ( ["title" [, "text"]] ) + ControlGetPos

 

What you think ?

[Melba23]

mLipok,

The handle for the notification is returned by _Notify_Show, so referencing the GUI is easy - no need for the title/text.

M23

[mLipok]

Yes but the handle is know only inside one script (exactly this which make notification).

For my need I must make interoperational communication or.....

Feature Request: please add GUID to your UDF and add this GUID to all windows as a hidden Label.

Then it be possible to enumerate (WinList) all window containing this GUID.

 

What you think now about this feature request ?

Edited July 12, 2015 by mLipok

[Melba23]

mLipok,

You can easily do this yourself by modifying the UDF to add a suitable title to the notification when it is created:

; Create Notify slice with $WS_POPUPWINDOW style and $WS_EX_TOOLWINDOW, $WS_EX_TOPMOST and $WS_EX_STATICEDGE extended style
Local $hNotify_Handle = GUICreate("Your_Special_String", $iNotify_Width, $iNotify_Height, $iNotify_X, $iNotify_Y, 0x80880000, BitOR(0x00020000, 0x00000080, 0x00000008))

Now you can use WinList to get the handles of every visible notification.

M23

[mLipok]

I conducted some tests.
It seems that it will work, as I imagined it myself.
I'll do a little modification, can you like them, maybe not, we'll see.
For now, I only had a project in mind, now I have another task, as I return to the subject of notification in my projects, and I adopt your UDFa to my needs, I will share the results of work here.

Meanwhile, I have a plan, one hour of work, and go to sleep.
Greetings

mLipok

[Melba23]

mLipok,

Try this Beta and associated example and see if it does what you want:  

expandcollapse popup

#include <Array.au3>

#include "Notify_Mod_GUID.au3"

HotKeySet("{ESC}", "_Exit")


; Set a GUID to use as the "title" of each notification (default is "")
$sGUID = "mLipok"

_Notify_Set(1, Default, Default, Default, Default, Default, Default, Default, $sGUID)

$nTask1 = TimerInit()
$nTask2 = TimerInit()
$nTask3 = TimerInit()

$iDelay1 = 1000 * Random(5, 10, 1)
$iDelay2 = 1000 * Random(5, 10, 1)
$iDelay3 = 1000 * Random(5, 10, 1)

While 1

    If $nTask1 Then
        If TimerDiff($nTask1) > $iDelay1 Then
            $nTask1 = 0
            _Notify_Show(0, "Task 1", "Completed")

            $aList = WinList($sGUID)
            _ArrayDisplay($aList, "Notifications", Default, 8)


        EndIf



    EndIf



    If $nTask2 Then
        If TimerDiff($nTask2) > $iDelay2 Then
            $nTask2 = 0
            _Notify_Show(0, "Task 2", "Completed")

            $aList = WinList($sGUID)
            _ArrayDisplay($aList, "Notifications", Default, 8)

        EndIf

    EndIf



    If $nTask3 Then
        If TimerDiff($nTask3) > $iDelay3 Then
            $nTask3 = 0
            _Notify_Show(0, "Task 3", "Completed")

            $aList = WinList($sGUID)
            _ArrayDisplay($aList, "Notifications", Default, 8)

        EndIf



    EndIf



WEnd



Func _Exit()
    Exit
EndFunc

M23

Edited September 27, 2017 by Melba23

[mLipok]

I could not resist, and I checked right away.
It works like a dream

Thanks.

I'll make some additional functions, I hope in next week, and I'll share it here.

[Melba23]

[NEW VERSION] - 13 Jul 15

Added:

• A new function _Notify_Modify which allows you to change the colour, text and/or click setting of an existing notification.
• A new $sGUID parameter for _Notify_Set to set the "title" of the notification GUI - this allows WinList to list all current notifications

New Example 2 shows these 2 additions working

New UDF in the zip in the first post.

M23

[User751139]

I'm basically looking to Modify the "Notify_Example_2"

I would like it to have the following behavior:

- The 3 Task should not just auto complete after 10 - 20 sec or so. Rather it should wait for me to click it. 

- Once clicked it dissepears and re-appears on a set time which I give each of the Task (for example after an hour it'll come back again until i click it)

And I would like this to loop forever until I close the script of course.

Thank you so much if anyone can step in and help

Edited August 12, 2015 by User751139

[Melba23]

User751139,

This seems to do what you want:

expandcollapse popup

#include <Array.au3>

#include "Notify.au3"

_Notify_RegMsg()

; Initialise task timers
Global $nTask1 = TimerInit()
Global $nTask2 = TimerInit()

; Set task delays
Global $iDelay1 = 1000 * Random(5, 20, 1)
Global $iDelay2 = 1000 * Random(5, 20, 1)

; Display notifications
Global $sGUID = "Notify_UDF"
_Notify_Set(1, Default, 0xFFCCCC, Default, Default, Default, Default, Default, $sGUID)
Global $hNotify1 = _Notify_Show(0, "Task 1", "Running")
Global $hNotify2 = _Notify_Show(0, "Task 2", "Running")

_Notify_Set(1, Default, 0xCCCCFF)
Global $hNotify3 = _Notify_Show(0, "Task 3", "Awaiting click")
; Declare the timestamp holder
Global $nNotify3Clicked = 0
; And the delay time
Global $iNotify3Delay = 5000

While 1

    If $nTask1 Then
        If TimerDiff($nTask1) > $iDelay1 Then
            $nTask1 = 0
            ; Recolour notification, change message text and set as "clickable"
            _Notify_Modify($hNotify1, Default, 0xCCFFCC, Default, "Completed", 1)
        EndIf



    EndIf



    If $nTask2 Then
        If TimerDiff($nTask2) > $iDelay2 Then
            $nTask2 = 0
            ; Recolour, change message text and set as "clickable"
            _Notify_Modify($hNotify2, Default, 0xCCFFCC, Default, "Completed", 1)
        EndIf



    EndIf



    ; If Notify3 has been clicked and no longer exists - and the timestamp has not already been set
    If Not WinExists($hNotify3) And $nNotify3Clicked = 0 Then
        ; Set the time stamp
        $nNotify3Clicked = TimerInit()
    EndIf

    ; If the time stamp is set
    If $nNotify3Clicked Then
        ; if the delay is passed
        If TimerDiff($nNotify3Clicked) > $iNotify3Delay Then
            ; Redisplay the notification
            $hNotify3 = _Notify_Show(0, "Task 3", "Awaiting click")
            ; And clear the timestamp
            $nNotify3Clicked = 0
        EndIf

    EndIf



WEnd

Please ask if you have any questions.

M23

[User751139]

Perfect! I love you!!

Just one small request but I can live with out it - I'm using the Image tabs. Is it possible to make them smaller as I can only fit about 12 or so on my screen and i need to fit a few more.

 

Or even better if it was possible to have a 2nd row of the notifications! 

 

Thanks again and Awesome script! I'll be using this every day

Edited August 12, 2015 by User751139