Report Help File Issues Here

[czardas]

Bang goes that theory then.

[guinness]

It was the earliest mention I could find in the history for the UDFs.

[czardas]

So from what trancexx said, __ArrayQuickSort2D should probably be this >>

Func __ArrayQuickSort2D(ByRef $avArray, Const ByRef $iStep, Const ByRef $iStart, Const ByRef $iEnd, Const ByRef $iSubItem, Const ByRef $iSubMax)

Or since they are mostly integers, this >>

Func __ArrayQuickSort2D(ByRef $avArray, $iStep, $iStart, $iEnd, $iSubItem, $iSubMax)

Which would ideally be more appropriate?

I don't know which of the above alternatives is best, but I would be inclined to go with the second option (avoiding unecessary complication), unless speed tests were to indicate otherwise. In view of what has been revealed, I find it hard to justify passing parameters ByRef unless they are to be modified within the function. On the other hand, using the Const keyword makes things easy to understand. It may be necessary to run tests to get a clearer picture. Edited November 13, 2012 by czardas

[JohnOne]

_GUICtrlMenu_SetMenuStyle

After a recent topic in the GHS forum

I went to take a look at the function given for the solution in the help file.

The Particular style description says this

Menu is modeless

I had no Idea what that meant and went to MSDN where it said this

Menu is modeless; that is, there is no menu modal message loop while the menu is active.

My suggestion is obviously to add that.

Additionally the $tagMENUINFO also lacks the extended description.

[AZJIO]

_GUICtrlRichEdit_SetBkColor, _GUICtrlRichEdit_GetCharBkColor

_GUICtrlRichEdit_Deselect($hRichEdit)

_GUICtrlRichEdit_GetCharBkColor

Example changes the color of the text, but not the background.

_GUICtrlRichEdit_SetFont

Select the text before changing.

_GuiCtrlRichEdit_SetSel($hRichEdit, 0, -1)
_GUICtrlRichEdit_SetFont($hRichEdit, 18, "Times New Roman")

"Times Roman" > "Times New Roman"

I do not have the font "Times Roman"

SRandom

###Remarks###

When using SRandom sequence of random numbers will be repeated each time you run the script. For example, you can test the speed of the script and the random numbers will not affect the test results.

After each call to SRandom random number generator starts a new sequence. Use the SRandom(@SEC), for random sequences.

_GUICtrlRichEdit_...

ControlFocus($hRichEdit, "", "")

This function does not perform any useful action Edited November 15, 2012 by AZJIO

[kylomas]

water,

The Help file example for GUICTRLCREATELIST could be improved/expanded. Let me offer the following for review. It may be a bit overboard but I think that it addresses some common uses of this function.

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <string.au3>           ; needed for _stringrepeat in example2
#include <file.au3>             ; needed for _tempfile in example3

Example1() ; simple listbox of strings, one string per line
Example2() ; formatted listbox populated from a 2D array
Example3() ; listbox populated from a file

Func Example1()

    Local $MESSAGE = "The following buttons have been clicked:"
    Local $add, $clear, $mylist, $close, $msg

    GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

    $add = GUICtrlCreateButton("Add", 20, 20, 75, 25)
    $clear = GUICtrlCreateButton("Clear", 20, 50, 75, 25)
    $mylist = GUICtrlCreateList("", 100, 20, 250, 200)
    GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
    GUICtrlSetData(-1, $MESSAGE)
    $close = GUICtrlCreateButton("My Closing Button", 100, 300, 250, 25)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()

        Select
            Case $msg = $add
                GUICtrlSetData($mylist, "You clicked the 'ADD' button|") ; seperator char ('|') is required otherwise previous equal line is overwritten
            Case $msg = $clear
                GUICtrlSetData($mylist, "")
                GUICtrlSetData($mylist, $MESSAGE)
                GUICtrlSetData($mylist, "You clicked the 'CLEAR' button") ; seperator char ('|') not required as list is cleared and re-populated
            Case $msg = $close
                MsgBox(0, "", "the closing button has been clicked", 2)
                Return
        EndSelect
    WEnd
EndFunc   ;==>Example1

Func Example2()

    ; Style $WS_Vscroll overrides the default styles which include $LBS_SORT.  $LBS_SORT prevents blank columns from being displayed in the correct order

    Local $gui010 = GUICreate('Populate Listbox From Array', 900) ; set width to 900 pixels
    Local $lbx010 = GUICtrlCreateList('', 10, 10, 800, 380, $ws_vscroll)
    Local $btn010 = GUICtrlCreateButton('Populate', 813, 10, 80, 25)
    Local $btn020 = GUICtrlCreateButton('Clear', 813, 45, 80, 25)
    GUICtrlSetFont($btn010, 8.5, 600)
    GUICtrlSetFont($btn020, 8.5, 600)
    GUICtrlSetColor($btn010, 0x00aa00)
    GUICtrlSetColor($btn020, 0xaa0000)
    GUICtrlSetFont($lbx010, 8.5, 600, Default, 'courier new') ; use mono spaced font for consistent spacing
    GUISetState()

    ; 2D array of data to load to the list control in formatted columns

    Local $aLBstr[10][4] = [ _
            ['John', 'A.', 'Smith', 'shoes, ships and candlewax'], _
            ['Alex', '', 'Garfunkel', 'shipping'], _
            ['', '', 'Madona', 'slut'], _
            ['Alexandra', '', '', 'HotBody'], _
            ['', '', '', ''], _
            ['The', 'previous', 'row is', 'blank'] _
            ]
    Local $msg, $str, $dflt
    While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $GUI_EVENT_CLOSE
                GUIDelete($gui010)
                Return
            Case $btn010
                For $i = 0 To UBound($aLBstr, 1) - 1
                    For $k = 0 To UBound($aLBstr, 2) - 1
                        $str &= stringformat('%-20s', $aLBstr[$i][$k])
                    Next
                    if $i = 0 then $dflt = $str
                    $str &= '|'
                Next
                GUICtrlSetData($lbx010, $str, $dflt)
            Case $btn020
                GUICtrlSetData($lbx010, '')
                $str = ''
        EndSwitch
    WEnd

EndFunc   ;==>Example2

Func Example3()

    ; create a test file

    Local $file_name = _TempFile(@ScriptDir)
    Local $hfl = FileOpen($file_name, 2)
    If $hfl = -1 Then
        MsgBox(0, 'FILE OPEN ERROR', $file_name)
        Exit
    Else
        ConsoleWrite('> Using file = ' & $file_name & @LF)
    EndIf

    ; write some test data to it

    FileWrite($hfl, 'line 1' & @LF & 'this is the second line' & @LF & 'third line' & @LF & 'another line....' & @LF & 'LastLine')
    FileClose($hfl)
    $hfl = 0

    Local $gui010 = GUICreate("Populate Listbox From File") ; will create a dialog box that when displayed is centered
    Local $add = GUICtrlCreateButton("Add", 20, 20, 75, 25)
    Local $clear = GUICtrlCreateButton("Clear", 20, 50, 75, 25)
    Local $mylist = GUICtrlCreateList("", 100, 20, 250, 200, $ws_vscroll) ; overrides $LBS_SORT to maintain records in file order
    Local $close = GUICtrlCreateButton("My Closing Button", 100, 300, 250, 25)
    GUISetState()

    Local $hfl = FileOpen($file_name)

    Local $msg = 0, $line
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()
        Select
            Case $msg = $add
                While 1
                    $line = FileReadLine($hfl)
                    If @error = -1 Then ExitLoop
                    GUICtrlSetData($mylist, $line)
                WEnd
            Case $msg = $clear
                GUICtrlSetData($mylist, "")
                FileClose($hfl) ; close file to reset file pointer
                $hfl = FileOpen($file_name) ; reopen file for read if add button is actioned again
            Case $msg = $close
                MsgBox(0, "", "the closing button has been clicked", 2)
                ExitLoop
        EndSelect
    WEnd
    If FileDelete($file_name) Then
        ConsoleWrite('> File ' & $file_name & ' deleted' & @LF)
        Exit
    Else
        MsgBox(0, 'FILE DELETE FAILED', $file_name)
        Exit
    EndIf

EndFunc   ;==>Example3

kylomas

[guinness]

water?

[AZJIO]

kylomas

Here is an example that I made for the Russian version of the help file

expandcollapse popup

#include <ListBoxConstants.au3>
#include <GUIConstantsEx.au3>

Local $Message = "The following buttons are pressed"
Local $hGUI, $add, $clear, $mylist, $msg, $index, $read, $setsel, $count, $select, $find_string, $del_item, $insert, $color, $tmp

$hGUI = GUICreate("GUI с элементом списка - list") ; Создаёт окно в центре экрана

$read = GUICtrlCreateButton("Item", 40, 30, 121, 25)
$index = GUICtrlCreateButton("Index of the selected", 40, 60, 121, 25)
$setsel = GUICtrlCreateButton("Select item 4", 40, 90, 121, 25)
$select = GUICtrlCreateButton("Select ""Item1""", 40, 120, 121, 25)
$find_string = GUICtrlCreateButton("Find the string Item 3", 40, 150, 121, 25)
$del_item = GUICtrlCreateButton("Delete row 3", 40, 180, 121, 25)
$count = GUICtrlCreateButton("The number of items", 40, 210, 121, 25)
$add = GUICtrlCreateButton("Add item", 40, 240, 121, 25)
$insert = GUICtrlCreateButton("Insert in position", 40, 270, 121, 25)
$color = GUICtrlCreateButton("Change the color", 40, 300, 121, 25)
$clear = GUICtrlCreateButton("Clear list", 40, 330, 121, 25)

$mylist = GUICtrlCreateList("Zero based index of the item", 180, 30, 190, 100, $GUI_SS_DEFAULT_LIST + $LBS_NOINTEGRALHEIGHT)
; style LBS_NOINTEGRALHEIGHT
; style $WS_BORDER+$WS_VSCROLL+$LBS_NOINTEGRALHEIGHT
; GUICtrlSetLimit(-1, 200)
GUICtrlSetData(-1, $Message)
GUICtrlSetData(-1, 'Item 1|Item 2|Item 3|Item', 'Item 2')

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $add
            GUICtrlSetData($mylist, "Clicked ""add""|")
        Case $clear
            GUICtrlSetData($mylist, "")
        Case $index
            $tmp = GUICtrlSendMsg($mylist, $LB_GETCURSEL, 0, 0)
            MsgBox(4096, 'The text of the selected item', $tmp, 0, $hGUI)
        Case $read
            $tmp = GUICtrlRead($mylist)
            MsgBox(4096, 'The text of the selected item in the list', $tmp, 0, $hGUI)
        Case $setsel
            GUICtrlSendMsg($mylist, $LB_SETCURSEL, 4, 0)
        Case $count
            $tmp = GUICtrlSendMsg($mylist, $LB_GETCOUNT, 0, 0)
            MsgBox(4096, 'The number of items in the list', $tmp, 0, $hGUI)
        Case $select
            GUICtrlSendMsg($mylist, $LB_SELECTSTRING, 0, 'Item 1')
        Case $find_string
            $tmp = GUICtrlSendMsg($mylist, $LB_FINDSTRINGEXACT, 0, 'Item 3')
            MsgBox(4096, 'Found the exact string in the list: Item 3', 'Index = ' & $tmp, 0, $hGUI)
        Case $del_item
            $tmp = GUICtrlSendMsg($mylist, $LB_DELETESTRING, 3, 0)
        Case $insert
            GUICtrlSendMsg($mylist, $LB_INSERTSTRING, 3, 'Inserted at position 3')
        Case $color
            GUICtrlSetBkColor($mylist, 0xCCCC99)
    EndSwitch
WEnd

[kylomas]

guinness,

Ooops!, Sorry!

kylomas

[kylomas]

AZJIO,

Your list management is much more complete. I was focused more on various ways to populate the list. Perhaps guinness can use some of both!

kylomas

[MvGulik]

DllCallAddress: (No results found for 'dllcalladdress'.)

Warning: ... Before using this function make sure DllCall() doesn't do what you need.

???

[JohnOne]

I think that means, you are best using DllCall where you can, before using DllCallAddress.

[trancexx]

That line is written by bright, English speaking person. I have no doubt it means exactly what it should mean. Overthinking is a bitch.

[MvGulik]

... Good to know you have no doubt's about that. ...

[AZJIO]

_GUICtrlRichEdit_GetCharPosFromXY

Gets inter-character position closest to a specified point in the client area

$iX - horizontal screen coordinate relative to left side of control

$iY - vertical screen coordinate relative to top of control

one-based character index of the character nearest the specified point

zero

(index of last character in the control if the specified point is beyond text)

index of the character at the edge

_GUICtrlRichEdit_SetTabStops

The example does not contain @TAB. Does not demonstrate an effect

_GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1" & @TAB & "Paragraph 2" & @TAB & "Paragraph 3")

_GUICtrlRichEdit_SetSpaceUnit

"in", "cm", "mm", "pt" (points), or "tw" (twips, 1/1440 inches, 1/567 centimeters)

_GUICtrlRichEdit_GetSelAA

an array in the format [, ]

an array in the format [ < anchor > , < active > ]

& lt;.....& gt;

_GUICtrlRichEdit_GetCharWordBreakInfo

GetWord - ???

_GUICtrlRichEdit_GetRECT

Success: an array consisting of x and y coordinates - [;;;]

[ < left > ; < top > ; < right > ; < bottom > ]

& lt;.....& gt;

_WinAPI_GetSysColorBrush

retrieves a handle

FileFindFirstFile

filename | File search string. (* and ? wildcards accepted)

The path and file name

FileSelectFolder

4 = Show Edit Control (to type a foldername)

to type the path

FileGetAttrib

filename | Filename (or directory) to check.

The path to the file or directory

etc.

Edited November 22, 2012 by AZJIO

[czardas]

I think the following information needs updating in accordance with current practices.

You can also assign a variable without declaring it first, but many prefer explicit declarations.

Related topic:

[trancexx]

That line is fine.

[czardas]

Now I'm really confused. If that's true then what was all the fuss is in the linked to topic? Maybe I just need to reengage brain. I thought it was fine too, but it seems to be at odds with the syntax check advanced parameters. Don't worry, I can be a bit slow on the uptake sometimes.

[guinness]

What people do in their own code is their business. But when posting code to the wiki and/or help file sections, good coding practice should be used. It also states in the first post (of the snippets wiki thread) that all submissions should pass Au3Check with advanced parameters.

[czardas]

Okay, but I still think it is worth a mention that the above method of allowing variables to be declared automatically is either not recommended or that it will fail the syntax check. Maybe it states that elsewhere in the help file, but without that information, it is lacking IMO: stating only that it is a matter of personal preference.

Edit

Last statement added.

Edited November 23, 2012 by czardas