Play a sound when I pass the cursor over the button

[TarwadaC4]

hello scripters

im just asking about how to play a sound when i pass my cursor over the button

and how to play the same or different sound when i press on that button

any one can paste a simple Code

[guinness]

Look at GUIGetCursorInfo and SoundPlay. Examples can be found either on the forum or in the Help file.

Edited December 10, 2011 by guinness

[Melba23]

TarwadaC4,

Take a look at MrCreatoR's GUICtrlOnHover UDF - it lets you run functions when over a control.

M23

Edit: Good evening guinness!

Edited December 10, 2011 by Melba23

[guinness]

Evening dear sir

I didn't think about MrCreatoR's UDF to be honest.

[TarwadaC4]

melba + guinness thanks alot

you are the best Members ever <3

[TarwadaC4]

i got the commands

but how to use it as i want

[Melba23]

TarwadaC4,

Post the code you have tried.

M23

P.S. Put [autoit] before and [/autoit] after your posted code.

[TarwadaC4]

i don't know how to use

i saw the command in the help file

but i don't know how to use

[water]

Did you try the example code that comes with the GUICtrlOnHover UDF?

[guinness]

My advice would be to start with the examples in the Help file and learn how to structure AutoIt code. It's great you have ideas but looking back through you previous questions, they could have been avoided by looking at the examples and searching the forum. Without knowing much about AutoIt your ideas will just stay as ideas.

Therefore I will provide a simple example to your question, in the hope that you will go away and study the help file. Good luck.

#include <GUIConstantsEx.au3>


_Main()

Func _Main()
    Local $aArray, $hGUI, $iLabel

    $hGUI = GUICreate("Press Esc to Get Pos")
    $iLabel = GUICtrlCreateLabel("Hover over me.", 10, 10, 100)
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        $aArray = GUIGetCursorInfo($hGUI)
        If Not @error Then
            If $aArray[4] = $iLabel Then
                Beep(500, 100) ; SoundPlay or Beep.
            EndIf
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

        EndSwitch
    WEnd
EndFunc   ;==>_Main

[Melba23]

TarwadaC4,

i don't know how to use

Perhaps like this:

expandcollapse popup

#include <guiconstantsex.au3>

; Create a flag which is set when the mouse if over the button
$fOver = False

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Noisy", 10, 10, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            ; Play this sound when the button is pressed
            SoundPlay("C:WindowsMediachimes.wav")
    EndSwitch

    $aCInfo = GUIGetCursorInfo()
    ; If we are over the button
    If $aCinfo[4] = $hButton Then
        ; And the mouse has just gone over the button
        If $fOver = False Then
            ; Play this sound
            SoundPlay("C:WindowsMediatada.wav")
            ; But set the flag to prevent the sound playing more than once
            $fOver = True
        EndIf
    Else
        ; We are no longer over teh button so clear the flag
        $fOver = False
    EndIf

WEnd

Now go and read the Help file about all the functions I used. You need to look at that Help file a lot more before posting - most of the answers are in there!

M23

Edit: End of the queue or what!

Edited December 10, 2011 by Melba23

[TarwadaC4]

WOW

Now i understand how that was work

Thanks ALOT GUYS !!!

[TarwadaC4]

and sorry again im noob here....... u know guys .... my language not the English, that's why when i read the codes i can understand

i find this better than when u say : go and search about that and that and that, luv u all <3