_ReduceMemory UDF

[GEOSoft]

it is better to use GetCurrentProcess for the own Process and not OpenProcess

Func _ReduceMemory($ProcID = 0)
; Original version : w_Outer
; modified by Rajesh V R to include process ID
; modified by Prog@ndy to include process handle
    
    If $ProcID = 0 or ProcessExists($ProcID) = 0 Then ; No process id specified or process doesnt exist - use current process instead.
        Local $ai_GetCurrentProcess = DllCall('kernel32.dll', 'ptr', 'GetCurrentProcess')
        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'ptr', $ai_GetCurrentProcess[0])
        Return $ai_Return[0]
    EndIf
   
    Local $ai_Handle = DllCall("kernel32.dll", 'ptr', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $ProcID)
    Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'ptr', $ai_Handle[0])
    DllCall('kernel32.dll', 'int', 'CloseHandle', 'ptr', $ai_Handle[0])
    Return $ai_Return[0]

EndFunc

Good work.

Based on the link thet SmOke_N supplied, starting with Windows 7 psapi.dll is not used at all. It just uses kernel32.dll for everything so you may want to look into mods based on that.

[KaFu]

Based on the link thet SmOke_N supplied, starting with Windows 7 psapi.dll is not used at all. It just uses kernel32.dll for everything so you may want to look into mods based on that.

So I assume this should work for WIN7? Have no system at hand to test . Oh, and rereading the article, has anyone an "Windows Server 2008 R2" at hand to check the Fileversion of "WinVer.exe"?

Edit:

Removed code because it crashed on WIN7

Edited June 12, 2009 by KaFu

[SmOke_N]

I'm quite sure the psapi.dll calls are backwards compatible. Win7 does have psapi.dll, it's just stated that the functions are in kernel32 dll now. I guess it's safer to do it this way, but I seriously doubt they'll break all the 32bit apps out there by removing the dll and or it's compatibility.

[herewasplato]

Some error checking added by Prog@ndy for this thread:

http://www.autoitscript.com/forum/index.php?showtopic=103693

Func _ReduceMemory($ProcID = 0)
    ; Original version : w_Outer
    ; modified by Rajesh V R to include process ID
    ; modified by Prog@ndy
    Local $ai_Return, $ai_Handle
    If $ProcID <= 0 Then ; No process id specified - use current process instead.
        $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'ptr', -1)
        If @error Then Return SetError(1, 0, 0)
        Return $ai_Return[0]
    EndIf

    $ProcID = ProcessExists($ProcID)
    If $ProcID = 0 Then Return SetError(2, 0, 0)
    $ai_Handle = DllCall("kernel32.dll", 'ptr', 'OpenProcess', 'dword', 0x1f0fff, 'int', False, 'dword', $ProcID)
    If @error Or $ai_Handle[0] = 0 Then Return SetError(3, 0, 0)
    $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'ptr', $ai_Handle[0])
    If @error Then
        DllCall('kernel32.dll', 'int', 'CloseHandle', 'ptr', $ai_Handle[0])
        Return SetError(4, 0, 0)
    EndIf
    DllCall('kernel32.dll', 'int', 'CloseHandle', 'ptr', $ai_Handle[0])
    Return $ai_Return[0]

EndFunc   ;==>_ReduceMemory

Thanks Prog@ndy

[Gogeta70]

forgot to close the handle:

Func _ReduceMemory()
    Local $ai_GetCurrentProcessId = DllCall('kernel32.dll', 'int', 'GetCurrentProcessId')
    Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $ai_GetCurrentProcessId[0])
    Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])
    DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
    Return $ai_Return[0]
EndFunc

I'm a little confused. In the dllcall "OpenProcess" you have: 'int', 0x1f0fff

However, when i look at MSDN, it says that it should be a DWORD value. Also, 0x1f0fff is not listed as a process access flag HERE

So, what's with that? I'm just trying to understand.

[wraithdu]

Don't worry about things you don't understand. For all intents, int and dword are equivalent here. That value specifies PROCESS_ALL_ACCESS, which is unecessary overkill anyway. You only need PROCESS_QUERY_INFORMATION and PROCESS_SET_INFORMATION and PROCESS_SET_QUOTA. Change the parameter to 'dword' and 0x0700.

Edited October 26, 2009 by wraithdu

[rajeshontheweb]

quite interesting, few things got way beyond my depth in dll / process handling knowledge, thats why i had to remain silent :-)

one thing to comment is about win 7 - as mentioned, they have put them in kernel dll file and not have removed it yet but there is all chances it gets ignored anymore or in case of errors it may not be supported. probably we will wake this thread again when we face errors beyong win7 and also, we need to get it tested in all 6 editions of win7 (there should be no errors assuming current case) if some gets hold of them ...

[Merrik]

I ran into a situation where I needed to make sure the Dlls were opened and closed in the function,

Func _ReduceMemory($ProcID = 0)
    ; Original version : w_Outer
    ; modified by Rajesh V R to include process ID
    ; modified by Prog@ndy
    ; Modified by Merrik
    Local $ai_Return, $ai_Handle
    Local $DllK = DllOpen("kernel32.dll")
    Local $DllP = DllOpen("psapi.dll")

    If $ProcID <= 0 Then ; No process id specified - use current process instead.
        $ai_Return = DllCall($DllP, 'int', 'EmptyWorkingSet', 'ptr', -1)
        If @error Then Return SetError(1, 0, 0)
        Return $ai_Return[0]
    EndIf

    $ProcID = ProcessExists($ProcID)
    If $ProcID = 0 Then Return SetError(2, 0, 0)
    $ai_Handle = DllCall($DllK, 'ptr', 'OpenProcess', 'dword', 0x1f0fff, 'int', False, 'dword', $ProcID)
    If @error Or $ai_Handle[0] = 0 Then Return SetError(3, 0, 0)
    $ai_Return = DllCall($DllP, 'int', 'EmptyWorkingSet', 'ptr', $ai_Handle[0])
    If @error Then
        DllCall($DllK, 'int', 'CloseHandle', 'ptr', $ai_Handle[0])
        Return SetError(4, 0, 0)
    EndIf
    DllCall($DllK, 'int', 'CloseHandle', 'ptr', $ai_Handle[0])
    Return $ai_Return[0]
    DllClose($DllK)
    DllClose($DllP)


EndFunc   ;==>_ReduceMemory so I thought I would add this part in.

Edited May 30, 2011 by Merrik

[guinness]

I don't this is a problem or required about closing the DLL, why not use _WinAPI_EmptyWorkingSet() in WinAPIEx.au3 by Yashied.

[Merrik]

Do you have an example you would like to share using _WinAPI_EmptyWorkingSet? :-)

[guinness]

An Example is in the Help File provided by Yashied. All you do is call the Function by using _WinAPI_EmptyWorkingSet() if you want to use the running EXE.

[Merrik]

Do you have an example you would like to share using _WinAPI_EmptyWorkingSet? :-)

Cool! This was the first time I've seen this. Looks good. I will test. Do you know it works on Windows 7?

[guinness]

Cool! This was the first time I've seen this. Looks good. I will test. Do you know it works on Windows 7?

Yeh it does, x32 & x64.

[Unsigned]

All this does is force Windows to page out working memory to the pagefile. It doesn't "free" any memory, and may in fact have performance hits for a running application, because it forces a hard drive access twice (once when you call it, once again when that page is needed again.)

Windows will automatically do this for you if your free memory drops to critical. That's one reason why your machine is so much slower in those situations, because of all those page faults.

The only situation this would be useful is in a long-running, little-executing process, such as a background service, that spends most of it's time sleeping. In those cases, this call acts as something of a "OK I'm idle, you can put my memory away to the hard drive until I want it again." Using this in a foreground application as a means to artificially keep the physical memory size down is just

[Yashied]

Typically, after calling this function, memory usage does not exceed 30-40% of the size that initialized by AutoIt. For example:

#Include <WinAPIEx.au3>

_WinAPI_EmptyWorkingSet()

While 1
    Sleep(1000)
WEnd

664 KB vs. 10.184 MB (without _WinAPI_EmptyWorkingSet())

Anyway, this function should be used wisely.

Edited October 3, 2011 by Yashied

[money]

Use it only at the very beginning and then let windows do the rest.

_WinAPI_GetCurrentProcessID() and @AutoItPID works the same yes?

[Unsigned]

The point was that it doesn't actually lower memory usage, just change the location at which those memory pages are stored. Windows will automatically page out as necessary if your physical memory approaches critical. Why cut your performance at all, for 10MB that you don't need anyway? If you did, it would already be paged out.

[money]

@Unsign: Force thrashing? It makes my HD purr like a kitten.

@Yashied '0x001F0FFF' VS '0x00000700' as wraithdu said.

Also

DllCall('kernel32.dll', 'ptr', 'OpenProcess',...

vs.

_WinAPI_OpenProcess(...

Just late night copypasta or reasoning behind this?

[money]

I use this function in loop so my memory would stay low. LOL.

[Yashied]

I use this function in loop so my memory would stay low. LOL.

Delusion...