I'm obviously missing something..

[Clark]

Hi all

For the life of me I can't figure out why this doesn't work.

The idea is to exit the for/next loop and then use the value of $Stat outside the function.

Obviously my understanding of something is deeply flawed, as this does not work as I think it should.

global $Stat,$var=3
 
_Test_Stat()
msgbox(0,"Test","The value of $Stat is " & $Stat)
 
Func _Test_Stat()
    for $Stat = 0 to 5
        if $Stat = $var Then
                ExitLoop
        EndIf
    Next
EndFunc

[water]

You never assign a value to $Stat.

Why do you want to check the value of $Stat in a loop? You could check $Stat directly.

[Clark]

It is just code to demonstrate the issue, not the real code.

If you run this code in the debugger, you will see that $Stat does indeed have a value as it goes through the loop (incrementing each time). It even has a value (in the debuggers watch list) once it exits the loop. The only time the value disappears is if you use $Stat for anything.

By implication, the "For" statement is assigning a value to $Stat. Read it out aloud. For $Stat equals 0 to 5. If $Stat equals something then it must have a value, right?

[water]

I see.

Solution: Please check the help file (For...To...Step...Next):

The Variable will be created automatically with a LOCAL scope, even when MustDeclareVars is on.

So you have a Global plus a Local variable named $Stat.

What you need is something like:

Global $Stat, $Var = 3
$Stat = _Test_Stat($Var)
MsgBox(0, "Test", "The value of $Stat is " & $Stat)
Func _Test_Stat($Param1)
For $iIndex = 0 To 5
  If $iIndex = $Var Then
   ExitLoop
  EndIf
Next
Return $iIndex
EndFunc   ;==>_Test_Stat

Edited October 14, 2011 by water

[Clark]

Well, there you go. My understanding was definitely flawed. I would not have thought for a second that the For Next loop would create a temporary variable.

Thanks for your help.

[Melba23]

Clark,

The variable in a For...Next loop is automatically created in Local scope (as stated in the Help file) and will be used in place of a Global variable of the same name if it exists (which it does in this case). So you get the correct check inside the loop (as the modified script below shows) but when you return from the function you revert to the Global variable which has no value:

Global $Stat, $var = 3
 
_Test_Stat()
MsgBox(0, "Test", "The value of $Stat is " & $Stat)
 
Func _Test_Stat()
    For $Stat = 0 To 5
        ConsoleWrite($Stat & " - " & $var & @CRLF)
        If $Stat = $var Then
            ExitLoop
        EndIf
    Next
EndFunc   ;==>_Test_Stat

I hope that explains the lack of a value in $Stat.

If you want a value, then you could either use a different variable name for the loop and then set $Stat to that value within the function:

Global $Stat, $var = 3
 
_Test_Stat()
MsgBox(0, "Test", "The value of $Stat is " & $Stat)
 
Func _Test_Stat()
    For $i = 0 To 5
        ConsoleWrite($i & " - " & $var & @CRLF)
        If $i = $var Then
            $Stat = $i
            ExitLoop
        EndIf
    Next
EndFunc   ;==>_Test_Stat

Or return the value from the function like this:

Global $Stat, $var = 3
 
$Stat = _Test_Stat()
MsgBox(0, "Test", "The value of $Stat is " & $Stat)
 
Func _Test_Stat()
    For $i = 0 To 5
        ConsoleWrite($i & " - " & $var & @CRLF)
        If $i = $var Then
            ExitLoop
        EndIf
    Next
    Return $i
EndFunc   ;==>_Test_Stat

All clear?

M23

Edit:

Good morning water!

Edited October 14, 2011 by Melba23

[jchd]

Hi, fellows!

Now the cleanest way is to follow Melba last example and return the variable from the function. Procedures with such undue side effects are a plague and lead to another form of spaghetti code (or rather, spaghetti vars).

EDIT: BS removed!

Edited October 14, 2011 by jchd