implicit variable value does not work when func is called via GUI??

[LoWang]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
 
loadhosts()  ;this works and a file browse dialog is displayed
 
;#cs
Opt("GUIOnEventMode",1)
#Region ### START Koda GUI section ### Form=Form1.kxf
$Form1_1 = GUICreate("test", 605, 801, 202, 120)
$Button2 = GUICtrlCreateButton("load hosts", 312, 16, 75, 25, $WS_GROUP)
GUICtrlSetOnEvent(-1, "loadhosts")   ;this does not work!
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
 
$jed=1
 While $jed
 Sleep(20)
wend
;#ce
 
Func loadhosts($filename="")
if not $filename then
 $filename=FileOpenDialog("vyber soubor s IP nebo hostnamy",@scriptdir,"(*.*)",1)
endif
 ;filereading commands here...
endfunc

Run this and you will see a file browse dialog - the function works when called directly. Then click a button to call the same function - and you will get an error saying that variable is not declared! WTH? If I add a statement

local $filename in the function body then it says ERROR: $filename already declared as parameter, but obviously the declaration is being ignored when the function is called via a GUI control. I find this behaviour strange. Somebody please explain. I just want to be able to use this kind of function to repeatedly load files, but I don't want $filename to be global, because then I would have to reset it to "" everytime the function runs so it opens the browse dialog.

[KaFu]

As there is no functionallity to pass parameters to a function with GUICtrlSetOnEvent() or GUISetOnEvent(), you may only call functions not expecting any parameters. Here's a work-around:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
loadhosts() ;this works and a file browse dialog is displayed
;#cs
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=Form1.kxf
$Form1_1 = GUICreate("test", 605, 801, 202, 120)
$Button2 = GUICtrlCreateButton("load hosts", 312, 16, 75, 25, $WS_GROUP)
GUICtrlSetOnEvent(-1, "loadhosts_wrapper") ;this does not work!
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$jed = 1
While $jed
 Sleep(20)
WEnd
;#ce
Func loadhosts_wrapper()
 loadhosts()
EndFunc
Func loadhosts($filename = "")
 If Not $filename Then
  $filename = FileOpenDialog("vyber soubor s IP nebo hostnamy", @ScriptDir, "(*.*)", 1)
 EndIf
 ;filereading commands here...
EndFunc   ;==>loadhosts

[Mat]

Alternatively use IsDeclared to see if the function was called and parameter set or not:

Func loadhosts($filename="")
if not IsDeclared("filename") then $filename = ""

if not $filename then
 $filename=FileOpenDialog("vyber soubor s IP nebo hostnamy",@scriptdir,"(*.*)",1)
endif
 ;filereading commands here...
endfunc

Just be warned that obfuscater breaks this.

[LoWang]

Another not very nice surprise: this problem occurs when I call such function via AdlibRegister also. So it is not only a GUI issue.

I think this should rather be mentioned in the helpfile...

Edited February 1, 2012 by LoWang

[jchd]

This is very clearly mentionned in the help file under the two functions you cite: You can not call a function using parameters.

[LoWang]

really? Not in my helpfile. Maybe it was added in autoit 3.3.8.0 which I did not install yet...

It is not mentioned on the page about GUICtrlSetOnEvent either, so what do you mean please?

Edited February 2, 2012 by LoWang

[Melba23]

LoWang,

"You can not call a function using parameters" is indeed now mentioned on the v3.3.8.0 Help file pages for AdlibRegister, GUISetOnEvent and GUICtrlSetOnEvent. Remember that the Help file, just like AutoIt itself, is a living thing that constantly changes - best to update when a new version comes out.

And there has never been a "parameters" parameter (if you see what I mean) in any of those commands - so there has never been any indication that you could use parameters with function to be called by them.

M23

[LoWang]

aha so my suspicion was true. So I will upgrade. But it should have been specifically mentioned a long time ago IMO ;-) You know I use implicit parameters quite often and the obvious reason is to be able to call my funcs in certain parts of the code without parameters One might think that since AdlibRegister does not take parameters then it would work. But it is the same problem as with GuictrlSetonEvent... When you first see it, you may try to fix it by adding "local $var" declaration in the func body, but this way you get an error saying that $var is already declared as an implicit parameter which can be confusing, because it says exactly the opposite when you try to run the program and call the func by Adlib. I just think it is really not that clear for everybody so I wanted some more comments to it and I am glad it is in the help file now. Thanks

Edited February 2, 2012 by LoWang