IPv4 Validator function

[BrewManNH]

I have created a function that I hope will validate an IP address sent to it. I have searched the site for one but I wasn't able to find one that was bullet-proof from all the ones I have run up against here. This one will not only validate that the values are in the right range, but will also tell you what Class the IP address falls under. It will check for the invalid number ranges, 0.xx.xx.xx or 127.xx.xx.xx for example, as well as for the reserved ranges above 239.xxx. I've seen a lot of attempts with RegEx but I didn't find one that would correctly validate that all 4 octets are within the valid IPv4 range, most will check to see if the values are above 255 or below 0 or contain anything that isn't a number, but that doesn't validate an IP address it just validates whether the numbers look right.

This will spit back an error if there are any non-numeric characters in the string, or you send it an IP address with less than all 4 octets. Or if your IP address is outside the valid class A-D ranges.

Please beat this function up as much as you can so that I can tell if I missed something, and if there's anyone out there that understands the IPv4 standards that this function misses, please let me know so I can fix it. Thanks for looking.

expandcollapse popup

Global $IPAddress = "192.168.0.122"
$Return = _ValidIP($IPAddress)
If $Return < 0 Then
    Switch @error
        Case 1
            MsgBox(64, "", "Error in IP address." & @LF & "Error code is: 1 - IP address starts with an invalid number = 0, 127 , 169 or is > 239")
        Case 2
            MsgBox(64, "", "Error in IP address." & @LF & "Error code is: 2 - one of the octets of the IP address is out of the range 0-255 or contains invalid characters")
        Case 3
            MsgBox(64, "", "Error in IP address." & @LF & "Error code is: 3 - IP Address is not a valid dotted IP address (ex. valid address 190.40.100.20)")
    EndSwitch
Else
    MsgBox(48, "", $IPAddress & " is a valid Class " & Chr(@error) & " IP address")
EndIf
; #FUNCTION# ====================================================================================================================
; Name...........: _ValidIP
; Description ...: Verifies that an IP address is a valid IPv4 address or not
; Syntax.........: _ValidIP($sIP)
; Parameters ....: $sIP - IP address to validate
;
; Return values .: Success - String containing IP Address in Hex, @error is ASC value of the Class of the IP address
;                 Failure - -1, sets @error
;                 |1 - IP address starts with an invalid number = 0, 127 , 169 or is > 239
;                 |2 - one of the octets of the IP address is out of the range 0-255 or contains invalid characters
;                 |3 - IP Address is not a valid dotted IP address (ex. valid address 190.40.100.20)
; Author ........: BrewManNH
; Modified.......:
; Remarks .......: Class A networks can't start with 0.xx.xx.xx. 127.xx.xx.xx isn't a valid IP address range. 169.xx.xx.xx is reserved and is invalid
;                 and any address that starts above 239, ex. 240.xx.xx.xx is reserved and should never be used or seen out in "the wild".
;                 The address range 224-239 1s reserved as well for Multicast  groups but can be a valid IP address range if you're
;                 using it as such.
;                 This will validate an IP address that is 4 octets long, and contains only numbers and falls within valid IP address values.
;                 Anything else sent to it should fail the test and return -1.
; Related .......:
; Link ..........: _GetIP
; Example .......: No
; ===============================================================================================================================
Func _ValidIP($sIP)
    $Array = StringSplit($sIP, ".", 2)
    If Not IsArray($Array) Or UBound($Array) <> 4 Then Return SetError(3, 0, -1)
    $String = "0x"
    If $Array[0] <= 0 Or $Array[0] > 239 Or $Array[0] = 127 Or $Array[0] = 169 Then
        Return SetError(1, 0, -1)
    EndIf
    For $I = 0 To 3
        If $Array[$I] < 0 Or $Array[$I] > 255 Or Not StringIsDigit($Array[$I]) Then
            Return SetError(2, 0, -1)
        EndIf
        $String &= StringRight(Hex($Array[$I]), 2)
    Next
    Switch $Array[0]
        Case 1 To 126
            SetError(65)
            Return $String
        Case 128 To 191
            SetError(66)
            Return $String
        Case 192 To 223
            SetError(67)
            Return $String
        Case 224 To 239
           SetError(68)
           Return $String
    EndSwitch
EndFunc   ;==>_ValidIP

Edited October 20, 2011 by BrewManNH

[guinness]

This has always had a good results >>

[BrewManNH]

This has always had a good results >>

That RegEx returns 255.1.1.1 as a valid IP address, it's not because any number over 239 is a reserved IP address and is almost never seen. It might work as a netmask validator, but not as an IP address validator. To be totally correct, any IP address that starts with the first octet being over 223 is also not a valid IP address, but in special cases 224-239 are reserved for multicast groups and can be valid if used for that.

I should have also excluded any IP address that ends in .0 or .255 as they aren't usually valid for an IP address either.

[jchd]

Try I won't pretend it's perfect but I tried to make it work for most "standard" ranges