RegWrite function wont write even if I am admin[solved]

[Akarillon]

Hello again

I an trying to make a script that changes the screensaver settings through registry on a domain useraccount.

This setting is located behind a string with the SID of that user.

My problem is when I try to write this information into the string it wont apply the changes.

expandcollapse popup

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile_x64=C:\Installationwizard\Remove_Screensaver.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Process.au3>
#Region ### START Koda GUI section ### Form=
$Form1_1 = GUICreate("Form1_1", 221, 174, 281, 190)
$TimeoutInput = GUICtrlCreateInput("TimeoutInput", 72, 40, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_NUMBER))
$UsernameInput = GUICtrlCreateInput("Username", 72, 80, 121, 21)
$Label = GUICtrlCreateLabel("How many second timeout?", 72, 16, 135, 17)
$ON = GUICtrlCreateRadio("ON", 16, 16, 41, 17)
$OFF = GUICtrlCreateRadio("OFF", 16, 40, 41, 17)
$Start_button = GUICtrlCreateButton("Start", 24, 120, 75, 25)
$Exit_button = GUICtrlCreateButton("Exit", 112, 120, 75, 25)
$Label2 = GUICtrlCreateLabel("Username:", 16, 80, 55, 17)
GUISetState(@SW_SHOW)
$Form1 = GUICreate("Form1", 600, 175, 526, 192)
$Label1 = GUICtrlCreateLabel("Label1", 24, 8, 180, 17)
$Label2 = GUICtrlCreateLabel("Label2", 24, 40, 180, 17)
$Label3 = GUICtrlCreateLabel("Label3", 24, 72, 180, 17)
$Label4 = GUICtrlCreateLabel("Label4", 24, 104, 180, 17)
$Label5 = GUICtrlCreateLabel("Label5", 24, 136, 400, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Global $var[5]
$var[0] = 0 ;OFF
$var[1] = 0 ;ON
$var[2] = 0 ;Timeout
$var[3] = 0 ;Username
$var[4] = 0 ;SID
While 1
GUICtrlSetData( $Label1, $var[0])
GUICtrlSetData( $Label2, $var[1])
GUICtrlSetData( $Label3, $var[2])
GUICtrlSetData( $Label4, $var[3])
GUICtrlSetData( $Label5, $var[4])
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $OFF
   $var[0] = 1
   $var[1] = 0
  Case $ON
   $var[1] = 1
   $var[0] = 0
  Case $Start_button
   $var[2] = GUICtrlRead($TimeoutInput)
   $var[3] = GUICtrlRead($UsernameInput)
    _RunDOS('if not exist C:\temp\ mkdir C:\temp\ && wmic path win32_useraccount where name="' & $var[3] & '" get sid > C:\temp\sid.txt')
    FileOpen("C:\temp\sid.txt", 0)
    Sleep(200)
    $var[4] = FileReadLine("C:\temp\sid.txt", 2)
    $var[4] = StringStripWS($var[4], 8)
    Sleep(500)
    If $var[0] = 1 Then
     RegWrite("HKEY_USERS\" & $var[4] & "\Software\Policies\Microsoft\Windows\Control Panel\Desktop", "ScreenSaveActive", "REG_SZ", "0")
    EndIf
    If $var[1] = 1 Then
     RegWrite("HKEY_USERS\" & $var[4] & "\Software\Policies\Microsoft\Windows\Control Panel\Desktop", "ScreenSaveActive", "REG_SZ", "1")
     RegWrite('HKEY_USERS\"' & $var[4] & '"\Software\Policies\Microsoft\Windows\Control Panel\Desktop', "ScreenSaveTimeOut", "REG_SZ", $var[2])
     if @error Then msgbox(0, "Error", @error)
     ;msgbox(0, "Done", "Settings are changed")
    EndIf
  Case $Exit_button
   Exit
 
EndSwitch
WEnd

I tried to debug the script by putting in another GUI that shows all variables, but the variables are correct, it just wont apply.

And 1 more question: is the @error working so that it gives the error message of the last RegWrite?

PS! The RegWrite function works if I just put this simple script:

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile_x64=C:\installationwizard\Regtest.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
global $var[2]
$var[0] = 60
$var[1] = "S-1-5-21-1927809936-1189766144-1318725885-362183"
RegWrite("HKEY_USERS\" & $var[1] & "\Software\Policies\Microsoft\Windows\Control Panel\Desktop", "ScreenSaveTimeOut", "REG_SZ", $var[0])

Kind Regards,

Akarillon

Edited September 8, 2011 by Akarillon

[water]

I would suggest to do more error checking in your script. When RegWrite fails @error can have different values (according to the help file).

You check for "if @error then .." which is resolved to "if @error = True then ..." and because @error is numeric means "if @error = 1 then ...". So you only get the msgBox if @error = 1. But @error can be in the range from -2 to 3.

To put it short: Change "if @error then .." to "if @error <> 0 then .."

[rcmaehl]

Also, there is a UDF for getting the SID of a user: http://www.autoitscript.com/autoit3/docs/libfunctions/_Security__SidToStringSid.htm

[Akarillon]

Tried both, and I only get error message 1, which in RegWrite indicates as "1 if unable to open requested key"

This narrows it down to 1 error, and that must be an error somewhere that prevents RegWrite from finding the correct path.

Even tried to remove 2 spaces that appears behind the SID that I get from the notepad.

[Jos]

this line:

RegWrite('HKEY_USERS\"' & $var[4] & '"\Software\Policies\Microsoft\Windows\Control Panel\Desktop', "ScreenSaveTimeOut", "REG_SZ", $var[2])

Should be:

RegWrite('HKEY_USERS\' & $var[4] & '\Software\Policies\Microsoft\Windows\Control Panel\Desktop', "ScreenSaveTimeOut", "REG_SZ", $var[2])

What is the exact content of $var[2] and $var[4]?

Edited September 8, 2011 by Jos

[water]

Do you run on a 64-bit Windows?

According to the RegWrite help file: "When running on 64-bit Windows if you want to write a key or value specific to the 64-bit environment you have to suffix the HK... with 64 i.e. HKLM64."

[Akarillon]

String is successfully written

Think it was both Jos' and water's suggestions cominated that fixed it

Now just to make it smaller and more robust ^^

[rcmaehl]

Here's an improved version of your script that SHOULD work:

expandcollapse popup

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile_x64=C:\Installationwizard\Remove_Screensaver.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Process.au3>
#Include <Security.au3>
#Region ### START Koda GUI section ### Form=
$Form1_1 = GUICreate("Form1_1", 221, 174, 281, 190)
$TimeoutInput = GUICtrlCreateInput("TimeoutInput", 72, 40, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_NUMBER))
$UsernameInput = GUICtrlCreateInput("Username", 72, 80, 121, 21)
$Label = GUICtrlCreateLabel("How many second timeout?", 72, 16, 135, 17)
$ON = GUICtrlCreateRadio("ON", 16, 16, 41, 17)
$OFF = GUICtrlCreateRadio("OFF", 16, 40, 41, 17)
$Start_button = GUICtrlCreateButton("Start", 24, 120, 75, 25)
$Exit_button = GUICtrlCreateButton("Exit", 112, 120, 75, 25)
$Label2 = GUICtrlCreateLabel("Username:", 16, 80, 55, 17)
GUISetState(@SW_SHOW)
$Form1 = GUICreate("Form1", 600, 175, 526, 192)
$Label1 = GUICtrlCreateLabel("Label1", 24, 8, 180, 17)
$Label2 = GUICtrlCreateLabel("Label2", 24, 40, 180, 17)
$Label3 = GUICtrlCreateLabel("Label3", 24, 72, 180, 17)
$Label4 = GUICtrlCreateLabel("Label4", 24, 104, 180, 17)
$Label5 = GUICtrlCreateLabel("Label5", 24, 136, 400, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Global $var[5]
$var[0] = 0 ;OFF
$var[1] = 0 ;ON
$var[2] = 0 ;Timeout
$var[3] = 0 ;Username
$var[4] = 0 ;SID
While 1
GUICtrlSetData( $Label1, $var[0])
GUICtrlSetData( $Label2, $var[1])
GUICtrlSetData( $Label3, $var[2])
GUICtrlSetData( $Label4, $var[3])
GUICtrlSetData( $Label5, $var[4])
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $OFF
   $var[0] = 1
   $var[1] = 0
  Case $ON
   $var[1] = 1
   $var[0] = 0
  Case $Start_button
   $var[2] = GUICtrlRead($TimeoutInput)
   $var[3] = GUICtrlRead($UsernameInput)
   $sid =_Security__GetAccountSid($var[3])
   $var[4] = _Security__SidToStringSid(DllStructGetPtr($sid,1))
    Sleep(500)
    If $var[0] = 1 Then
     RegWrite("HKEY_USERS\" & $var[4] & "\Software\Policies\Microsoft\Windows\Control Panel\Desktop", "ScreenSaveActive", "REG_SZ", "0")
    EndIf
    If $var[1] = 1 Then
     RegWrite("HKEY_USERS\" & $var[4] & "\Software\Policies\Microsoft\Windows\Control Panel\Desktop", "ScreenSaveActive", "REG_SZ", "1")
     RegWrite('HKEY_USERS\' & $var[4] & '\Software\Policies\Microsoft\Windows\Control Panel\Desktop', "ScreenSaveTimeOut", "REG_SZ", $var[2])
     If @error <> 0 Then MsgBox(0, "Error", @error)
     ;MsgBox(0, "Done", "Settings are changed")
    EndIf
  Case $Exit_button
   Exit
EndSwitch
WEnd

[BrewManNH]

I would suggest to do more error checking in your script. When RegWrite fails @error can have different values (according to the help file).

You check for "if @error then .." which is resolved to "if @error = True then ..." and because @error is numeric means "if @error = 1 then ...". So you only get the msgBox if @error = 1. But @error can be in the range from -2 to 3.

To put it short: Change "if @error then .." to "if @error <> 0 then .."

Actually isn't it read as TRUE for any value other than zero?

[water]

Actually isn't it read as TRUE for any value other than zero?

You are right. I've learned something new today

[GEOSoft]

@Water

Add this one to the list.

The suffix isn't required. If you want an explaination you can PM me.