Factorials and Permutations

[MSLx Fanboy]

I intend on doing more probability functions later this year (maybe in August or September), I would do them now, if only I still remembered Geometric and Arithmetic sequences and such and so forth...

Here is the UDF for doing factorials (6! = 6*5*4*3*2*1 = 720) and permutations (6 items taken 3 at a time will offer 6P3 ways, or 120 ways).

For those curious, there are roughly 53400 different ways to unlock a standard rotary lock.

Factorial.au3

Factorial_Test.au3

[FuryCell]

Good Job.

Now we can do factorials and permutations in AutoIt. These funcs are useful when trying to calculate probabilty. You should see if they can get put in Math.au3 to be preinstalled with AutoIt. These should be useful to many people.

[MSLx Fanboy]

Grrr....Any number in the permutations function greater than 20 returns a strange result (i.e. 20P3 etc). Actually its in probability too. Could it be possible that it is a string limitation or something, its returning negative numbers and decimal points...

I'm about to start pulling hair here

[millisys]

Hi MLSx Fanboy,

I am looking for a permutation factorial solution and saw your post. I noticed as well that using a number larger than 20 is returning decimal points. I was wondering if perhaps you had found a solution and wouldn't mind posting it. Thank you.

[BrewManNH]

This post is 9 years old and the user hasn't been on here in 6 years, don't expect an answer any time in the near (or distant) future.

[MikahS]

This post is 9 years old, and the OP has not been on in 6 years. I doubt you will get a response from them..

[JLogan3o13]

millisys, the post is 9 years old, and the OP hasn't even been on the forum in 6 years. Do you really expect a response??

[Melba23]

Hi,

I think he got the message!

M23

[ValeryVal]

Nevertheless the example of Factorial for Long number exists:

expandcollapse popup

For $i = 40 To 50
  $vInt = String($i)
    MsgBox(0,"", $vInt & "! = " & _LongFactorial($i))
Next

;===========================
func _LongFactorial ($vInt)
  If $vInt == "0" then
   Return "1"
  else
   Return _LongProduct($vInt,_LongFactorial ( String (Number($vInt)-1) ))
  endif
endfunc

; #FUNCTION# ==============================
;From http://www.autoitscript.com/forum/topic/157301-longproduct/?hl=%2Bbignum#entry1139178
; Name...........: _LongProduct
; Description ...: Multiplies two large positive integers together using old school long multiplication method
; Syntax.........: _LongProduct($vInt1, $vInt2)
; Parameters ....: $vInt1  - First integer - can be a number or a string of digits
;                  $vInt2  - Second integer - as above
; Return values .: Success - Returns the product of the two numbers
;                  Failure - Sets @error to 1 if either parameter contains non digit characters
; Author ........: czardas
; Comments ......; A separate function must be created if you want to preprocess floating point numbers
; =========================================

Func _LongProduct($vInt1, $vInt2)
    If Not (StringIsDigit($vInt1) And StringIsDigit($vInt2)) Then Return SetError(1)

    Local $vTemp ; Reuseable placeholder
    If StringLen($vInt2) > StringLen($vInt1) Then
        ; Set $vInt2 to be the shortest numeric string to reduce array size later
        $vTemp = $vInt1
        $vInt1 = $vInt2
        $vInt2 = $vTemp
    EndIf

    Local $iBound = StringLen($vInt2), $sZeros = "0" ; Zero padding for the method of long multiplication

    While StringLen($sZeros) < $iBound
        $sZeros &= $sZeros ; Tens, hundreds, thousands etc...
    WEnd
    $sZeros = StringRight($sZeros, $iBound -1) ; Highest order of magnitude needed

    Local $aPartProduct[$iBound], $iCarryForward ; Placeholder for tens of units, hundreds, thousands etc...

    For $i = 1 To $iBound ; Starting with the most significant digit in $vInt2
        $aPartProduct[$i -1] = ""
        $iCarryForward = 0 ; Maximum possible value in this code section is 8 ==> 89 = 9*9+8

        For $j = StringLen($vInt1) To 1 Step -1
            ; Multiply every digit in $vInt2 by every digit in $vInt1
            $vTemp = StringMid($vInt2, $i, 1) * StringMid($vInt1, $j, 1)

            ; Add the tens of units left over from the previous calculation
            $vTemp += $iCarryForward
            $iCarryForward = Number(StringTrimRight($vTemp, 1)) ; This will be added on the next run

            ; Append the units
            $aPartProduct[$i -1] &= StringRight($vTemp, 1) ; Digits appear in reverse sequence
        Next
        $aPartProduct[$i -1] &= $iCarryForward

        ; Pad with the correct number of zeros
        $aPartProduct[$i -1] = StringRight($sZeros, $iBound - $i) & $aPartProduct[$i -1] & StringTrimRight($sZeros, $iBound - $i)
    Next
    $iCarryForward = 0 ; Reset this variable for the following process

    ; Take the sum of all the part products in the array
    Local $sProduct = ""
    For $i = 1 To StringLen($aPartProduct[0]) ; Starting with the least significant digit
        $vTemp = 0 ; Sum value
        For $j = 0 To UBound($aPartProduct) -1
            ; Add the digits from the units, tens of units, hundreds, thousands etc...
            $vTemp += StringMid($aPartProduct[$j], $i, 1)
        Next

        ; Add the value left over from the previous calculation
        $vTemp += $iCarryForward
        $iCarryForward = Number(StringTrimRight($vTemp, 1)) ; This will be added on the next run

        $sProduct = StringRight($vTemp, 1) & $sProduct ; Returns the digits in the correct order
    Next
    If $iCarryForward Then $sProduct = $iCarryForward & $sProduct

    If StringLeft($sProduct, 1) = "0" Then $sProduct = StringTrimLeft($sProduct, 1)
    Return $sProduct
EndFunc ;==> _LongProduct