String is Int or Float [solved]

[icu]

Dear AutoIt Community,

I'm trying to take a string number and check if it is an Integer or a Float. I couldn't find anything in the Help file so I wrote the following:

Func StringIsIntOrFloat($s_Number)
    Select
        Case StringIsInt($s_Number)
            Return 1
        Case StringIsFloat($s_Number)
            Return 1
        Case Else
            Return 0
    EndSelect
EndFunc

#cs Return Value
Success: Returns 1. 
Failure: Returns 0 if string cannot be an integer or a float. 
#ce

; Proof of concept

$s_Number = "1"

If StringIsIntOrFloat($s_Number) <> 1 Then MsgBox(0, "Error", "String is NOT an Integer or a Float: " & $s_Number)

$s_Number = "1.1"

If StringIsIntOrFloat($s_Number) <> 1 Then MsgBox(0, "Error", "String is NOT an Integer or a Float: " & $s_Number)

$s_Number = "1a"

If StringIsIntOrFloat($s_Number) <> 1 Then MsgBox(0, "Error", "String is NOT an Integer or a Float: " & $s_Number)

Is there a better way of checking?

Thanks,

-icu

Edited July 1, 2011 by icu

[monoscout999]

your code is good... another way to do it.

If NOT StringIsInt($s_Number) and NOT StringIsFloat($s_Number) then msgbox(0, "Error", "String is NOT an Integer or a Float: " & $s_Number)

Edited July 1, 2011 by monoscout999

[icu]

@Monoscout999: Thanks for the quick reply. I came to that that solution too ;-) I was really wondering if there was something I was missing somewhere.

[omikron48]

OR

If Not (StringIsInt($s_Number) OR StringIsFloat($s_Number)) Then msgbox(0, "Error", "String is not an Integer nor a Float: " & $s_Number)

[BrewManNH]

As far as I can tell, there's no in-built StringIsNumber function which would seem to be the only way of checking if it's either a float or an integer in one test. Short of a RegEx you've pretty much hit on the way to check it.

[JohnOne]

I suppose you could check with StringRegExp(), but I'm not the one to ask how.

Except to say you could test for any none numeric char, excluding a single decimal place.

[JohnOne]

There is a stringisnum, but it returns false on a ".".

[BrewManNH]

There's a StringIsDigit, but no StringIsNum, and as you stated, won't work for a float.

[smartee]

Hi,

Try this:

MsgBox(64, "_StringIsNum Demo", _StringIsNum("46"))

Func _StringIsNum($sInput)
    Return StringRegExp($sInput, "^([0-9]*(\.[0-9]+){1}|[0-9]+(\.[0-9]*){0,1})$") = 1
EndFunc   ;==>_StringIsNum

Hope this helps

-smartee

EDIT: Addressed some cases and made a function

Edited July 1, 2011 by smartee

[icu]

To all: Thanks everyone for the replies. I think I've got the answer I was was looking for. My personal preference is for shorter lines of code and avoiding Regex so the function StringIsIntOrFloat($s_Number) I wrote suits my needs perfectly.

JohnOne hit the nail on the head about StringIsNum getting caught on the dot ".". At first I thought I was messing something up so I looked twice at the help file and figured I needed to write something myself. At the very least this page will get indexed in Google so the next person that has the same problem can copy and paste the above code examples :-)

Edited July 1, 2011 by icu

[JohnOne]

Actually, looking at it again, its StringIsAlNum.

Old peepers are not as they once were.

[GEOSoft]

@smartee

Whats the problem with the simple expression?

Return StringRegExp($sInput, "^[\d.]+$")

Edit:

Actually the simple expression would fail (in certain cases) as shown above.

Return StringRegExp($sInput, "^\d*\.?\d+$")

Should work better but I don't have the energy to be bothered testing any of them right now.

Edited July 1, 2011 by GEOSoft

[Exit]

just my 2 cents

MsgBox(0, "_StringIsNum Demo", _StringIsNum("99")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9+9")) ; false
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9.9")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9 9")) ; false

Func _StringIsNum($s_Number)
    Return StringIsInt($s_Number) +  StringIsFloat($s_Number)
EndFunc   ;==>_StringIsNum

regards Forumer100

[JohnOne]

just my 2 cents

MsgBox(0, "_StringIsNum Demo", _StringIsNum("99")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9+9")) ; false
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9.9")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9 9")) ; false

Func _StringIsNum($s_Number)
    Return StringIsInt($s_Number) +  StringIsFloat($s_Number)
EndFunc   ;==>_StringIsNum

regards Forumer100

That's quite an ace way that.

Brilliant in its simplicity.

[BrewManNH]

Can someone explain what the difference is between StringIsDigit and StringIsInt? They both seem to do the exact same comparisons and I don't see what the use of one over the other would be for. If anyone has any insight on it, I'd appreciate it.

[BrewManNH]

just my 2 cents

MsgBox(0, "_StringIsNum Demo", _StringIsNum("99")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9+9")) ; false
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9.9")) ; true
MsgBox(0, "_StringIsNum Demo", _StringIsNum("9 9")) ; false

Func _StringIsNum($s_Number)
    Return StringIsInt($s_Number) +  StringIsFloat($s_Number)
EndFunc   ;==>_StringIsNum

regards Forumer100

Very slick by the way.

[trancexx]

Can someone explain what the difference is between StringIsDigit and StringIsInt? They both seem to do the exact same comparisons and I don't see what the use of one over the other would be for. If anyone has any insight on it, I'd appreciate it.

StringIsDigit checks for digits and StringIsInt checks if a string is integer representation.

"-12" is int but "-" is not a digit, i.e. StringIsDigit will be 0.

[JohnOne]

How correct is the helpfile in this case

StringIsInt

--------------------------------------------------------------------------------

Checks if a string is an integer.

If tested with "9999999999999999999999999999999999999999999999999999999999999999999999999999999999999999999" will return true.

[BrewManNH]

It's an integer in regards to that it's a number without a decimal point, it may not be an INT as defined by a programmer, but it's an integer as defined by a mathematician.

[BrewManNH]

StringIsDigit checks for digits and StringIsInt checks if a string is integer representation.

"-12" is int but "-" is not a digit, i.e. StringIsDigit will be 0.

I see that now.