_ShellFile() - Create an entry in the shell contextmenu when selecting an assigned filetype, includes the program icon as well.

[guinness]

Nice work guinness!

very nice. you can even add a few more things like 'Position', 'HasLUAShield', .....

I will have a look. Thanks.

[telmob]

Because the first return is blocking the second return.

It was wrong, sorry.

But the paths are badly formated and it doesn't display all paths but one path only.

C:UsersTelmoDesktopSRPENF~1SRPEFI~1.EXE

I'm very surprised there's no clean solution to perform this task. Don't get me wrong, i really apreciate your help on this and your script is very good.

Edited December 30, 2012 by telmob

[guinness]

As I said a couple of posts before, I will work on a solution that uses the AutoIt Hidden window. In the mean time I suggest reading tutorials around the Forum.

Edit: Right now I'm working on a full-proof 'trial period' function and having some difficulty working out the best approach. Once complete I will probably upload to the Forum.

Edited December 30, 2012 by guinness

[telmob]

Thanks guinness, you're the man!

[guinness]

You will need _ShellAll, NOT _ShellFile and WM_COPYDATA. Look at the code and read the associated comments.

expandcollapse popup

#NoTrayIcon
#include <Array.au3>
#include <GUIConstantsEx.au3>

#include '_ShellAll.au3' ; Download From: http://www.autoitscript.com/forum/topic/133942-shellall-create-an-entry-in-the-shell-contextmenu-when-selecting-a-file-and-folder-includes-the-program-icon-as-well/#entry933527
#include 'WM_COPYDATA.au3' ; http://www.autoitscript.com/forum/topic/119502-solved-wm-copydata-x64-issue

If @Compiled Then
    Example()
EndIf

Func Example()
    Local $iFileSent = _WM_COPYDATA_Initial('UniqueIDString', Default) ; Start the communication process.
    If @error Then
        If Not _WM_COPYDATA_SendStart(StringReplace(StringStripWS($CmdLineRaw, 3), '"', '')) Then ; Send $CmdLineRaw if there is process already running.
            MsgBox(4096, '2nd Instance: ' & @error, 'Seems there was an @error, but more than likely $CmdLineRaw was blank.' & @CRLF & @CRLF & $CmdLineRaw)
        EndIf
        Exit
    EndIf

    Local $iPID = Run('notepad.exe', @ScriptDir, @SW_SHOW)
    Local $hWnd = WinWait('[CLASS:Notepad]', '', 5)
    If Not $hWnd Then
        Return False
    EndIf
    WinSetTitle($hWnd, '', 'Example by guinness ' & @YEAR)

    Local $aFileList = 0, $sFileList = ''
    If $CmdLine[0] Then
        For $i = 1 To $CmdLine[0]
            $sFileList &= $CmdLine[$i] & @CRLF
        Next
        ControlSetText($hWnd, '', 'Edit1', $sFileList)
        $sFileList = ''
    EndIf

    _ShellAll_Install('Start Example') ; Add the running EXE to the Shell ContextMenu. This will only display when selecting a file and folder.

    While ProcessExists($iPID)
        Switch GUIGetMsg()
            Case $iFileSent ; If the WM_COPYDATA message is interecepted then add the data sent to notepad.
                $aFileList = _WM_COPYDATA_SendShutdown(True)
                If Not @error Then
                    For $i = 1 To $aFileList[0]
                        $sFileList &= $aFileList[$i] & @CRLF
                    Next
                    ControlSetText($hWnd, '', 'Edit1', ControlGetText($hWnd, '', 'Edit1') & $sFileList)
                    _ArrayDisplay($aFileList)
                EndIf
                $aFileList = 0
                $sFileList = ''

        EndSwitch
    WEnd

    _ShellAll_Uninstall() ; Remove the running EXE from the Shell ContextMenu.
    _WM_COPYDATA_Shutdown()

    Return True
EndFunc   ;==>Example

Func _WM_COPYDATA_Initial($sIDString, $hGUI, $fCheckOnly = Default)
    _WM_COPYDATA_SetID($sIDString)
    Local Const $vReturn = _WM_COPYDATA_Start($hGUI, $fCheckOnly)
    Local Const $iError = @error
    Local $hWnd = WinGetHandle('[REGEXPTITLE:(?m)^' & _WM_COPYDATA_GetID() & '$]')
    $hWnd = HWnd(ControlGetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1')))
    _WM_COPYDATA_SetGUI($hWnd)
    WinSetTitle($hWnd, '', 'START_PROCESS')
    Return SetError($iError, 0, $vReturn)
EndFunc   ;==>_WM_COPYDATA_Initial

Func _WM_COPYDATA_SendShutdown($fReturnArray = Default)
    If StringStripWS(_WM_COPYDATA_GetData(), 8) <> 'START_PROCESS' Then
        Return SetError(1, 0, '')
    EndIf

    Local $aReturn[1] = [0], $aWinList = 0, $sData = '', $sReturn = ''
    Do
        Sleep(50)
        $aWinList = WinList('[REGEXPTITLE:' & _WM_COPYDATA_GetID() & '__CHILD__' & '\d+]')
        If @error Then
            ExitLoop
        EndIf
        If $aWinList[0][0] Then
            ReDim $aReturn[($aReturn[0] + 1) + $aWinList[0][0]]
            For $i = 1 To $aWinList[0][0]
                $sData = StringStripWS(ControlGetText($aWinList[$i][1], '', ControlGetHandle($aWinList[$i][1], '', 'Edit1')), 3)
                If $sData Then
                    $aReturn[0] += 1
                    $aReturn[$aReturn[0]] = $sData
                    $sReturn &= $sData & @CRLF
                EndIf
                ControlSetText($aWinList[$i][1], '', ControlGetHandle($aWinList[$i][1], '', 'Edit1'), '')
            Next
        EndIf
    Until $aWinList[0][0] == 0

    WinSetTitle(_WM_COPYDATA_GetGUI(), '', 'START_PROCESS')
    If $fReturnArray Then
        ReDim $aReturn[($aReturn[0] + 1)]
        Return SetError($sReturn == '', 0, $aReturn)
    EndIf
    $aReturn = 0
    Return SetError($sReturn == '', 0, $sReturn)
EndFunc   ;==>_WM_COPYDATA_SendShutdown

Func _WM_COPYDATA_SendStart($sData)
    Local Const $sTitle = _WM_COPYDATA_GetID() & '__CHILD__' & @AutoItPID
    AutoItWinSetTitle($sTitle)
    Local Const $hWait = WinGetHandle($sTitle)
    If @error Then
        Return SetError(1, 0, False)
    EndIf
    ControlSetText($hWait, '', ControlGetHandle($hWait, '', 'Edit1'), $sData)

    If WinGetTitle(_WM_COPYDATA_GetGUI()) = 'START_PROCESS' Then
        If _WM_COPYDATA_Send('START_PROCESS') Then
            WinSetTitle(_WM_COPYDATA_GetGUI(), '', 'IN_PROCESS')
        EndIf
    EndIf

    While 1
        If StringStripWS(ControlGetText($hWait, '', ControlGetHandle($hWait, '', 'Edit1')), 8) == '' Then
            ExitLoop
        EndIf
        Sleep(250)
    WEnd
    Return True
EndFunc   ;==>_WM_COPYDATA_SendStart

Edited January 2, 2013 by guinness

[telmob]

Thank you for your help guinness. But unfortunately the problem remains.

Sometimes not everything selected goes into the notepad.

[guinness]

Thank you for your help guinness. But unfortunately the problem remains.

Sometimes not everything selected goes into the notepad.

OK, I will have a look. In the mean time if you could play around with the code that would help you a lot.

[telmob]

Thank you so much guinness. I have made a topic just for this in general help and support.

I think this is a problem that should have been addressed and solved. I find it really strange that there is no easy way to do this.

After all, this is a pretty common windows task.

Meanwhile, i'll play around with your script

Btw... your wm_copydata still has the same issues:

D:DownloadsOutpostProInstall64.exe

D:DownloadssXeInjectedSetup.13.1.Fix.2.exe

D:DOWNLO~1COUNTE~1.EXE

D:Downloadssoftwarepolicy03setup.exe

and not all files/folders appear.

This problem is getting way too complicated

Edited December 31, 2012 by telmob

[guinness]

Thank you so much guinness. I have made a topic just for this in general help and support.

I think this is a problem that should have been addressed and solved. I find it really strange that there is no easy way to do this.

After all, this is a pretty common windows task.

Meanwhile, i'll play around with your script

What research have you done exactly? As I get the impression you're just relying on others.

There is no problem/issue with using the registry key(s) in the first post, this is by design that a single file is passed to the application. I suggest reading this as it states the functionality you want is successful by writing a shell extension.

[telmob]

Well, i've researched this extensively.

I have read all that article too.

this is by design that a single file is passed to the application

Well, maybe to autoit, but not other applications. If it was, the context menu selection wouldn't appear when you select multiple files/folders, but only one.

Have you tried zipping multiple files/folders? All of them get zipped, not just a few. Or even selecting multiple music files and playing them, all of them play, not just one or a few.

So it seems there's something missing here that nobody figured it out yet. Because the normal behaviour is to simply work with all files/folders you select. The problem is in getting their full paths into the script.

There's a discussion here about this, but i don't understand nothing about c++...

http://stackoverflow.com/questions/9355/programatically-select-multiple-files-in-windows-explorer

Edited December 31, 2012 by telmob

[guinness]

Well, i've researched this extensively.

I have read all that article too.

Well, maybe to autoit, but not other applications. If it was, the context menu selection wouldn't appear when you select multiple files/folders, but only one.

Have you tried zipping multiple files/folders? All of them get zipped, not just a few. Or even selecting multiple music files and playing them, all of them play, not just one or a few.

So it seems there's something missing here that nobody figured it out yet. Because the normal behaviour is to simply work with all files/folders you select. The problem is in getting their full paths into the script.

There's a discussion here about this, but i don't understand nothing about c++...

http://stackoverflow.com/questions/9355/programatically-select-multiple-files-in-windows-explorer

It's by design, I believe you when you said you read the article, but did you understand it? The whole part about multiple files etc... is achieved by creating a shell extension, something you as the developer have to create. It uses COM, which AutoIt can easily access, so AutoIt isn't at fault nor is it the UDF.

[telmob]

Well... my problem is understanding. Sometimes i 'drift' by some texts because english is not my main language

Regarding COM.... i guess i'm screwed! lol

[SmOke_N]

Hey guiness, sorry for responding to this... but from the links provided, and the little bit I could stand to read through.. is this the type of outcome we're looking for?

expandcollapse popup

#include-once

Global $gs_MainDir = "C:\"
Global $ga_Select[2] = ["C:\Program Files", "C:\Windows"]

_shell_OpenFolderAndSelectItems($gs_MainDir, $ga_Select)

Func _shell_OpenFolderAndSelectItems($s_dir, $v_items = "")
    ; $v_items can be single item string or zero based array of files to select

    If Not IsArray($v_items) And StringLen($v_items) = 0 Then
        Return ShellExecute($s_dir)
    EndIf

    Local $p_pidl_dir = _WinAPI_ILCreateFromPath($s_dir)
    If @error Then Return SetError(1, @error, 0)

    Local $v_tmp[1] = [$v_items]
    If Not IsArray($v_items) Then $v_items = $v_tmp
    Local $i_ub = UBound($v_items)
    Local $a_pidl[$i_ub]

    Local $t_children = 0, $p_children = 0
    If StringLen($v_items[0]) > 0 Then
        $t_children = DllStructCreate("ptr[" & $i_ub & "]")
        For $i = 0 To $i_ub - 1
            $a_pidl[$i] = _WinAPI_ILCreateFromPath($v_items[$i])
            DllStructSetData($t_children, 1, $a_pidl[$i], $i + 1)
        Next
        $p_children = DllStructGetPtr($t_children)
    EndIf

    DllCall("Ole32.dll", "int", "CoInitialize", "ptr", 0)

    Local $a_hresult = _WinAPI_SHOpenFolderAndSelectItems($p_pidl_dir, $i_ub, $p_children)
    Local $i_err = @error, $i_ext
    If $i_err Then
        If IsArray($a_hresult) Then $i_ext = $a_hresult[0]
    EndIf

    DllCall("Ole32.dll", "int", "CoUninitialize")

    _WinAPI_ILFree($p_pidl_dir)
    For $i = 0 To $i_ub - 1
        _WinAPI_ILFree($a_pidl[$i])
    Next

    If $i_err Then Return SetError(2, $i_ext, 0)

    Return 1
EndFunc

Func _WinAPI_ILCreateFromPath($w_str)

    Local $a_pidl = DllCall("Shell32.dll", "ptr", _
        "ILCreateFromPathW", "wstr", $w_str)
    If @error Then
        Return SetError(1, 0, 0)
    EndIf

    Return $a_pidl[0]
EndFunc

Func _WinAPI_ILFree($p_pidl)
    DllCall("Shell32.dll", "none", "ILFree", "ptr", $p_pidl)
    Return SetError(@error, @extended)
EndFunc

Func _WinAPI_SHOpenFolderAndSelectItems($p_pidl, $i_count, $p_children)

    Local $a_hresult = DllCall("Shell32.dll", "long", _
        "SHOpenFolderAndSelectItems", "ptr", $p_pidl, "uint", $i_count, _
        "ptr", $p_children, "dword", 0)
    If @error Or $a_hresult[0] Then Return SetError(@error, $a_hresult[0], 0)

    Return 1
EndFunc

Edit:

Ignore the include once, I was going to make this a little udf type, but I'm too lazy (hiccup) at the moment... happy new year!

Edited January 1, 2013 by SmOke_N

[guinness]

Thanks SmOke_N. Though the code matches the article telmob posted above, from what I understand they want to add an option to the right-click shell menu for when selecting a specific file type (_ShellFile UDF) but to support multiple files being passed to the program instead of just the one. Which is by design.

[guinness]

See post #25, I have spent a lot of time on this and it now works everytime.

[telmob]

guinness......... i don't know how to thank you.

Really, i can't thank you enough. This will be perfect in my little app.

Amazing work!

Thank you! Thank you! Thank you!

Hope your humour has returned. Its a whole new year!!

Have the greatest 2013!

[guinness]

So there are no issues? I would appreciate your honesty as I have gotten this far with it.

[telmob]

No issues so far.

I see that some spaces appear randomly in the notepad sometimes, but i don't think thats going to be an issue.

I'm trying to set it up with another working example to see if i can find some glitches.

I will post findings in a few minutes

[guinness]

No issues so far.

I see that some spaces appear randomly in the notepad sometimes, but i don't think thats going to be an issue.

I'm trying to set it up with another working example to see if i can find some glitches.

I will post findings in a few minutes

That can easily be fixed by using StringStripWS.

[telmob]

It really doesn't bother me.

My example writes the selected paths to registry. If it writes correctly, fine. If not, i'll try using StringStripWS.